- PSDADJN ;B'ham ISC/LTL,JPW - Adjustments for NAOU ; 16 Feb 94
- ;;3.0; CONTROLLED SUBSTANCES ;**66**;13 Feb 97;Build 3
- I '$D(PSDSITE) D ^PSDSET G:'$D(PSDSITE) QUIT
- ;I '$D(^XUSEC("PSD ERROR",DUZ)) W !!,"Sorry, you need the PSD ERROR Security key to do adjustments.",!! G QUIT
- N DIC,DIE,DINUM,D0,D1,DLAYGO,DR,DIR,DIRUT,DTOUT,DUOUT,PSDAT,PSDB,PSDEX,PSDLOC,PSDLOCN,DA,PSDOUT,PSDRUG,PSDRUGN,PSDS,PSAQ,PSDR,PSDREC,PSDT,X,Y,%,%H,%I
- G LOOK
- REV S DIR(0)="Y",DIR("A")="Review",DIR("B")="No",DIR("?")="If you answer yes, I'll show you all adjustments performed within a selected time range." D ^DIR K DIR G:$D(DIRUT) QUIT G:Y=1 ^PSDADJN1
- Q
- LOOK S DIC="^PSD(58.8,",DIC(0)="AEMQ",DIC("A")="Select NAOU: ",DIC("S")="I $P($G(^(0)),U,3)=+PSDSITE,$P($G(^(0)),U,2)[""N"",'$P(^(0),""^"",7),$S('$D(^(""I"")):1,+^(""I"")>DT:1,'^(""I""):1,1:0)"
- D ^DIC K DIC G:$D(DTOUT)!($D(DUOUT))!(Y<1) QUIT S PSDLOC=+Y,PSDLOCN=$P(Y,U,2)
- I '+$P($G(^PSD(58.8,PSDLOC,2)),"^",5) W !!,"This NAOU does not maintain a perpetual inventory balance to be adjusted.",!! K PSDLOC,PSDLOCN G LOOK
- CHKD I '$O(^PSD(58.8,PSDLOC,1,0)) W !!,"There are no drugs in ",PSDLOCN G QUIT
- S PSDOUT=0
- F S DIC="^PSD(58.8,PSDLOC,1,",DIC(0)="AEMQZ",DIC("A")="Select "_PSDLOCN_" drug: ",DA(1)=PSDLOC D G:$D(DTOUT)!($D(DUOUT))!(PSDOUT) QUIT
- .W ! D ^DIC K DIC I $D(DTOUT)!($D(DUOUT))!(Y<1) S PSDOUT=1 Q
- .S PSDRUG=+Y,PSDRUGN=$P($G(^PSDRUG(+Y,0)),U)
- .S PSAQ=$P($G(^PSD(58.8,+PSDLOC,1,+PSDRUG,0)),U,4)
- .W !!,"Current Balance: ",PSAQ,?40
- .W "Breakdown Unit: ",$P($G(^PSD(58.8,+PSDLOC,1,+PSDRUG,0)),U,8),!
- .S DIR(0)="NOA^"_-PSAQ_":999999:2" S DIR("A")="Enter adjustment quantity (with '-' if negative):" D ^DIR K DIR
- .I $D(DTOUT)!($D(DUOUT)) S PSDOUT=1 Q
- .Q:$D(DIRUT)
- .S PSDREC=Y
- .S DIR(0)="F^1:45",DIR("A")="Please enter reason for adjustment" W ! D ^DIR K DIR Q:$D(DIRUT) S PSDR=Y
- POST .S DIR(0)="Y",DIR("A")="OK to post",DIR("B")="Yes" W ! D ^DIR K DIR D:Y=1 K PSDRUG Q
- ..W !!,"There were ",$S($P($G(^PSD(58.8,+PSDLOC,1,+PSDRUG,0)),U,4):$P($G(^(0)),U,4),1:0)," on hand.",?40,"There are now ",$P($G(^(0)),U,4)+PSDREC," on hand.",!
- ..F L +^PSD(58.8,+PSDLOC,1,+PSDRUG,0):$S($G(DILOCKTM)>0:DILOCKTM,1:3) I Q
- ..D NOW^%DTC S PSDAT=+%
- ..S PSAQ=$P($G(^PSD(58.8,+PSDLOC,1,+PSDRUG,0)),U,4)
- ..S $P(^PSD(58.8,+PSDLOC,1,+PSDRUG,0),U,4)=PSDREC+PSAQ
- ..L -^PSD(58.8,+PSDLOC,1,+PSDRUG,0)
- MON ..S:'$D(^PSD(58.8,+PSDLOC,1,+PSDRUG,5,0)) ^(0)="^58.801A^^"
- ..I '$D(^PSD(58.8,+PSDLOC,1,+PSDRUG,5,$E(DT,1,5)*100,0)) S DIC="^PSD(58.8,+PSDLOC,1,+PSDRUG,5,",DIC(0)="LM",DLAYGO=58.8,(X,DINUM)=$E(DT,1,5)*100,DA(2)=PSDLOC,DA(1)=PSDRUG D ^DIC K DIC,DLAYGO
- ..S DIE="^PSD(58.8,+PSDLOC,1,+PSDRUG,5,",DA(2)=PSDLOC,DA(1)=PSDRUG,DA=$E(DT,1,5)*100,DR="7////^S X=$P($G(^(0)),U,5)+PSDREC" D ^DIE
- ..W !,"Updating monthly adjustments and transaction history.",!
- TR ..F L +^PSD(58.81,0):$S($G(DILOCKTM)>0:DILOCKTM,1:3) I Q
- FIND ..S PSDT=$P(^PSD(58.81,0),U,3)+1 I $D(^PSD(58.81,PSDT)) S $P(^PSD(58.81,0),U,3)=$P(^PSD(58.81,0),U,3)+1 G FIND
- ..S DIC="^PSD(58.81,",DIC(0)="L",DLAYGO=58.81,(DINUM,X)=PSDT D ^DIC K DIC,DLAYGO L -^PSD(58.81,0)
- ..S DIE="^PSD(58.81,",DA=PSDT,DR="1////9;2////^S X=PSDLOC;3////^S X=PSDAT;4////^S X=PSDRUG;5////^S X=PSDREC;6////^S X=DUZ;9////^S X=PSAQ;15////^S X=PSDR;17////^S X=PSDLOC;100////1" D ^DIE K DIE
- ..S:'$D(^PSD(58.8,+PSDLOC,1,+PSDRUG,4,0)) ^(0)="^58.800119PA^^"
- ..S DIC="^PSD(58.8,+PSDLOC,1,+PSDRUG,4,",DIC(0)="L",DLAYGO=58.8
- ..S (X,DINUM)=PSDT
- ..S DA(2)=PSDLOC,DA(1)=PSDRUG D ^DIC K DIC,DA,DLAYGO,PSDRUG S Y=1
- QUIT D:'$G(PSDOUT)!('$D(DIRUT)) REV Q
- PSDADJN ;B'ham ISC/LTL,JPW - Adjustments for NAOU ; 16 Feb 94
- +1 ;;3.0; CONTROLLED SUBSTANCES ;**66**;13 Feb 97;Build 3
- +2 IF '$DATA(PSDSITE)
- DO ^PSDSET
- IF '$DATA(PSDSITE)
- GOTO QUIT
- +3 ;I '$D(^XUSEC("PSD ERROR",DUZ)) W !!,"Sorry, you need the PSD ERROR Security key to do adjustments.",!! G QUIT
- +4 NEW DIC,DIE,DINUM,D0,D1,DLAYGO,DR,DIR,DIRUT,DTOUT,DUOUT,PSDAT,PSDB,PSDEX,PSDLOC,PSDLOCN,DA,PSDOUT,PSDRUG,PSDRUGN,PSDS,PSAQ,PSDR,PSDREC,PSDT,X,Y,%,%H,%I
- +5 GOTO LOOK
- REV SET DIR(0)="Y"
- SET DIR("A")="Review"
- SET DIR("B")="No"
- SET DIR("?")="If you answer yes, I'll show you all adjustments performed within a selected time range."
- DO ^DIR
- KILL DIR
- IF $DATA(DIRUT)
- GOTO QUIT
- IF Y=1
- GOTO ^PSDADJN1
- +1 QUIT
- LOOK SET DIC="^PSD(58.8,"
- SET DIC(0)="AEMQ"
- SET DIC("A")="Select NAOU: "
- SET DIC("S")="I $P($G(^(0)),U,3)=+PSDSITE,$P($G(^(0)),U,2)[""N"",'$P(^(0),""^"",7),$S('$D(^(""I"")):1,+^(""I"")>DT:1,'^(""I""):1,1:0)"
- +1 DO ^DIC
- KILL DIC
- IF $DATA(DTOUT)!($DATA(DUOUT))!(Y<1)
- GOTO QUIT
- SET PSDLOC=+Y
- SET PSDLOCN=$PIECE(Y,U,2)
- +2 IF '+$PIECE($GET(^PSD(58.8,PSDLOC,2)),"^",5)
- WRITE !!,"This NAOU does not maintain a perpetual inventory balance to be adjusted.",!!
- KILL PSDLOC,PSDLOCN
- GOTO LOOK
- CHKD IF '$ORDER(^PSD(58.8,PSDLOC,1,0))
- WRITE !!,"There are no drugs in ",PSDLOCN
- GOTO QUIT
- +1 SET PSDOUT=0
- +2 FOR
- SET DIC="^PSD(58.8,PSDLOC,1,"
- SET DIC(0)="AEMQZ"
- SET DIC("A")="Select "_PSDLOCN_" drug: "
- SET DA(1)=PSDLOC
- Begin DoDot:1
- +3 WRITE !
- DO ^DIC
- KILL DIC
- IF $DATA(DTOUT)!($DATA(DUOUT))!(Y<1)
- SET PSDOUT=1
- QUIT
- +4 SET PSDRUG=+Y
- SET PSDRUGN=$PIECE($GET(^PSDRUG(+Y,0)),U)
- +5 SET PSAQ=$PIECE($GET(^PSD(58.8,+PSDLOC,1,+PSDRUG,0)),U,4)
- +6 WRITE !!,"Current Balance: ",PSAQ,?40
- +7 WRITE "Breakdown Unit: ",$PIECE($GET(^PSD(58.8,+PSDLOC,1,+PSDRUG,0)),U,8),!
- +8 SET DIR(0)="NOA^"_-PSAQ_":999999:2"
- SET DIR("A")="Enter adjustment quantity (with '-' if negative):"
- DO ^DIR
- KILL DIR
- +9 IF $DATA(DTOUT)!($DATA(DUOUT))
- SET PSDOUT=1
- QUIT
- +10 IF $DATA(DIRUT)
- QUIT
- +11 SET PSDREC=Y
- +12 SET DIR(0)="F^1:45"
- SET DIR("A")="Please enter reason for adjustment"
- WRITE !
- DO ^DIR
- KILL DIR
- IF $DATA(DIRUT)
- QUIT
- SET PSDR=Y
- POST SET DIR(0)="Y"
- SET DIR("A")="OK to post"
- SET DIR("B")="Yes"
- WRITE !
- DO ^DIR
- KILL DIR
- IF Y=1
- Begin DoDot:2
- +1 WRITE !!,"There were ",$SELECT($PIECE($GET(^PSD(58.8,+PSDLOC,1,+PSDRUG,0)),U,4):$PIECE($GET(^(0)),U,4),1:0)," on hand.",?40,"There are now ",$PIECE($GET(^(0)),U,4)+PSDREC," on hand.",!
- +2 FOR
- LOCK +^PSD(58.8,+PSDLOC,1,+PSDRUG,0):$SELECT($GET(DILOCKTM)>0:DILOCKTM,1:3)
- IF $TEST
- QUIT
- +3 DO NOW^%DTC
- SET PSDAT=+%
- +4 SET PSAQ=$PIECE($GET(^PSD(58.8,+PSDLOC,1,+PSDRUG,0)),U,4)
- +5 SET $PIECE(^PSD(58.8,+PSDLOC,1,+PSDRUG,0),U,4)=PSDREC+PSAQ
- +6 LOCK -^PSD(58.8,+PSDLOC,1,+PSDRUG,0)
- MON IF '$DATA(^PSD(58.8,+PSDLOC,1,+PSDRUG,5,0))
- SET ^(0)="^58.801A^^"
- +1 IF '$DATA(^PSD(58.8,+PSDLOC,1,+PSDRUG,5,$EXTRACT(DT,1,5)*100,0))
- SET DIC="^PSD(58.8,+PSDLOC,1,+PSDRUG,5,"
- SET DIC(0)="LM"
- SET DLAYGO=58.8
- SET (X,DINUM)=$EXTRACT(DT,1,5)*100
- SET DA(2)=PSDLOC
- SET DA(1)=PSDRUG
- DO ^DIC
- KILL DIC,DLAYGO
- +2 SET DIE="^PSD(58.8,+PSDLOC,1,+PSDRUG,5,"
- SET DA(2)=PSDLOC
- SET DA(1)=PSDRUG
- SET DA=$EXTRACT(DT,1,5)*100
- SET DR="7////^S X=$P($G(^(0)),U,5)+PSDREC"
- DO ^DIE
- +3 WRITE !,"Updating monthly adjustments and transaction history.",!
- TR FOR
- LOCK +^PSD(58.81,0):$SELECT($GET(DILOCKTM)>0:DILOCKTM,1:3)
- IF $TEST
- QUIT
- FIND SET PSDT=$PIECE(^PSD(58.81,0),U,3)+1
- IF $DATA(^PSD(58.81,PSDT))
- SET $PIECE(^PSD(58.81,0),U,3)=$PIECE(^PSD(58.81,0),U,3)+1
- GOTO FIND
- +1 SET DIC="^PSD(58.81,"
- SET DIC(0)="L"
- SET DLAYGO=58.81
- SET (DINUM,X)=PSDT
- DO ^DIC
- KILL DIC,DLAYGO
- LOCK -^PSD(58.81,0)
- +2 SET DIE="^PSD(58.81,"
- SET DA=PSDT
- SET DR="1////9;2////^S X=PSDLOC;3////^S X=PSDAT;4////^S X=PSDRUG;5////^S X=PSDREC;6////^S X=DUZ;9////^S X=PSAQ;15////^S X=PSDR;17////^S X=PSDLOC;100////1"
- DO ^DIE
- KILL DIE
- +3 IF '$DATA(^PSD(58.8,+PSDLOC,1,+PSDRUG,4,0))
- SET ^(0)="^58.800119PA^^"
- +4 SET DIC="^PSD(58.8,+PSDLOC,1,+PSDRUG,4,"
- SET DIC(0)="L"
- SET DLAYGO=58.8
- +5 SET (X,DINUM)=PSDT
- +6 SET DA(2)=PSDLOC
- SET DA(1)=PSDRUG
- DO ^DIC
- KILL DIC,DA,DLAYGO,PSDRUG
- SET Y=1
- End DoDot:2
- KILL PSDRUG
- QUIT
- End DoDot:1
- IF $DATA(DTOUT)!($DATA(DUOUT))!(PSDOUT)
- GOTO QUIT
- QUIT IF '$GET(PSDOUT)!('$DATA(DIRUT))
- DO REV
- QUIT
