- PSDBAL ;BIR/JPW-Display/Print Current Drug Balance ; 29 Aug 94
- ;;3.0; CONTROLLED SUBSTANCES ;;13 Feb 97
- I '$D(PSDSITE) D ^PSDSET Q:'$D(PSDSITE)
- I '$D(^XUSEC("PSJ RPHARM",DUZ))&('$D(^XUSEC("PSD TECH",DUZ))) W !!,"Contact your Pharmacy Coordinator for access to display current CS drug",!,"balances.",!!,"PSJ RPHARM or PSD TECH security key required.",! Q
- ASKD ;ask disp location
- S PSDS=$P(PSDSITE,U,3),PSDSN=$P(PSDSITE,U,4)
- G:$P(PSDSITE,U,5) CHKD
- K DIC,DA S DIC=58.8,DIC(0)="QEAZ",DIC("S")="I $P(^(0),""^"",3)=+PSDSITE,$S($P(^(0),""^"",2)[""M"":1,$P(^(0),""^"",2)[""S"":1,1:0)"
- S DIC("A")="Select Primary Dispensing Site: "
- S DIC("B")=PSDSN
- D ^DIC K DIC G:Y<0 END
- S PSDS=+Y,PSDSN=$P(Y,"^",2),$P(PSDSITE,U,3)=+Y,$P(PSDSITE,U,4)=PSDSN
- CHKD I '$O(^PSD(58.8,PSDS,1,0)) W !!,"There are no CS stocked drugs for your dispensing vault.",!! G END
- W !!,?5,"You may select a single drug, several drugs,",!,?5,"or enter ^ALL to select all drugs.",!!
- DRUG ;ask drug
- W ! K DA,DIC
- F S DIC("W")="W:$P(^PSDRUG(Y,0),""^"",9) "" N/F"" I $P(^PSD(58.8,PSDS,1,Y,0),""^"",14)]"""",$P(^(0),""^"",14)'>DT W $C(7),"" *** INACTIVE ***""",DA(1)=+PSDS,DIC(0)="QEAM",DIC="^PSD(58.8,"_PSDS_",1," D ^DIC K DIC Q:Y<0 D
- .S PSDR(+Y)=""
- I '$D(PSDR)&(X'="^ALL") G END
- I X="^ALL" S ALL=1
- DEV ;sel device
- S Y=$P($G(^PSD(58.8,+PSDS,2)),"^",9),C=$P(^DD(58.8,24,0),"^",2) D Y^DIQ S PSDEV=Y
- W ! K %ZIS,IOP,IO("Q"),POP S %ZIS="QM",%ZIS("B")=PSDEV D ^%ZIS I POP W !!,"NO DEVICE SELECTED OR REPORT PRINTED!!",! G END
- I $D(IO("Q")) K IO("Q"),ZTIO,ZTSAVE,ZTDTH,ZTSK S ZTRTN="START^PSDBAL",ZTDESC="CS PHARM List Stock Balances" D SAVE,^%ZTLOAD,HOME^%ZIS K ZTSK G END
- U IO
- START ;entry for compile
- K ^TMP("PSDBAL",$J)
- I $D(ALL) F PSD=0:0 S PSD=$O(^PSD(58.8,+PSDS,1,PSD)) Q:'PSD I $D(^PSD(58.8,+PSDS,1,PSD,0)) S PSDR(+PSD)=""
- F PSD=0:0 S PSD=$O(PSDR(PSD)) Q:'PSD I $D(^PSD(58.8,+PSDS,1,PSD,0)) S NODE=^(0) D
- .S PSDOK="" I +$P(NODE,"^",14),+$P(NODE,"^",14)'>DT Q:'+$P(NODE,"^",4) S PSDOK="*"
- .S BAL=+$P(NODE,"^",4),PSDRN=$S($P($G(^PSDRUG(+PSD,0)),"^")]"":$P(^(0),"^"),1:"ZZ/"_PSD_" NAME MISSING"),EXP=$S(+$P(NODE,"^",12):+$P(NODE,"^",12),1:"")
- .I EXP S Y=EXP X ^DD("DD") S EXP=Y
- .S ^TMP("PSDBAL",$J,PSDRN,PSD)=BAL_"^"_PSDOK_"^"_EXP
- PRINT ;prints data
- S (PG,PSDOUT)=0 D NOW^%DTC S Y=+$E(%,1,12) X ^DD("DD") S RPDT=Y
- K LN S $P(LN,"-",80)="" D HDR
- I '$D(^TMP("PSDBAL",$J)) W !!,?15,"**** NO STOCK BALANCE DATA AVAILABLE ****",!! G DONE
- S PSDR="" F S PSDR=$O(^TMP("PSDBAL",$J,PSDR)) Q:PSDR=""!(PSDOUT) F PSD=0:0 S PSD=$O(^TMP("PSDBAL",$J,PSDR,PSD)) Q:'PSD D
- .D:$Y+4>IOSL HDR Q:PSDOUT
- .S NODE=^TMP("PSDBAL",$J,PSDR,PSD),BAL=+NODE,PSDOK=$P(NODE,"^",2),EXP=$P(NODE,"^",3)
- .W !,PSDOK,?2,PSDR,?63,$J(BAL,6),! W:EXP]"" ?5,"Expiration Date: ",EXP,!
- DONE I $E(IOST)'="C" W @IOF
- I $E(IOST,1,2)="C-",'PSDOUT W ! K DIR,DIRUT S DIR(0)="EA",DIR("A")="END OF REPORT! Press <RET> to return to the menu" D ^DIR K DIR
- END ;
- K %,%H,%I,%ZIS,ALL,BAL,C,DA,DIC,DTOUT,DUOUT,EXP,LN,NODE,PG,POP,PSD,PSDEV,PSDOK,PSDOUT,PSDR,PSDRN,PSDS,PSDSN,RPDT,X,Y
- K ^TMP("PSDBAL",$J),ZTDESC,ZTDTH,ZTIO,ZTRTN,ZTSAVE,ZTSK
- D ^%ZISC S:$D(ZTQUEUED) ZTREQ="@"
- Q
- SAVE S (ZTSAVE("PSDS"),ZTSAVE("PSDSN"),ZTSAVE("PSDSITE"))=""
- S:$D(ALL) ZTSAVE("ALL")="" S:$D(PSDR) ZTSAVE("PSDR(")=""
- Q
- HDR ;header
- I $E(IOST,1,2)="C-",PG K DA,DIR S DIR(0)="E" D ^DIR K DIR I 'Y S PSDOUT=1 Q
- S PG=PG+1 W:$Y @IOF W !,?12,"Current Stock Balances for ",PSDSN,?72,"Page: ",PG,!,?20,RPDT,!!
- W ?5,"DRUG",?60,"CURRENT BALANCE",!,LN,!!
- Q
- PSDBAL ;BIR/JPW-Display/Print Current Drug Balance ; 29 Aug 94
- +1 ;;3.0; CONTROLLED SUBSTANCES ;;13 Feb 97
- +2 IF '$DATA(PSDSITE)
- DO ^PSDSET
- IF '$DATA(PSDSITE)
- QUIT
- +3 IF '$DATA(^XUSEC("PSJ RPHARM",DUZ))&('$DATA(^XUSEC("PSD TECH",DUZ)))
- WRITE !!,"Contact your Pharmacy Coordinator for access to display current CS drug",!,"balances.",!!,"PSJ RPHARM or PSD TECH security key required.",!
- QUIT
- ASKD ;ask disp location
- +1 SET PSDS=$PIECE(PSDSITE,U,3)
- SET PSDSN=$PIECE(PSDSITE,U,4)
- +2 IF $PIECE(PSDSITE,U,5)
- GOTO CHKD
- +3 KILL DIC,DA
- SET DIC=58.8
- SET DIC(0)="QEAZ"
- SET DIC("S")="I $P(^(0),""^"",3)=+PSDSITE,$S($P(^(0),""^"",2)[""M"":1,$P(^(0),""^"",2)[""S"":1,1:0)"
- +4 SET DIC("A")="Select Primary Dispensing Site: "
- +5 SET DIC("B")=PSDSN
- +6 DO ^DIC
- KILL DIC
- IF Y<0
- GOTO END
- +7 SET PSDS=+Y
- SET PSDSN=$PIECE(Y,"^",2)
- SET $PIECE(PSDSITE,U,3)=+Y
- SET $PIECE(PSDSITE,U,4)=PSDSN
- CHKD IF '$ORDER(^PSD(58.8,PSDS,1,0))
- WRITE !!,"There are no CS stocked drugs for your dispensing vault.",!!
- GOTO END
- +1 WRITE !!,?5,"You may select a single drug, several drugs,",!,?5,"or enter ^ALL to select all drugs.",!!
- DRUG ;ask drug
- +1 WRITE !
- KILL DA,DIC
- +2 FOR
- SET DIC("W")="W:$P(^PSDRUG(Y,0),""^"",9) "" N/F"" I $P(^PSD(58.8,PSDS,1,Y,0),""^"",14)]"""",$P(^(0),""^"",14)'>DT W $C(7),"" *** INACTIVE ***"""
- SET DA(1)=+PSDS
- SET DIC(0)="QEAM"
- SET DIC="^PSD(58.8,"_PSDS_",1,"
- DO ^DIC
- KILL DIC
- IF Y<0
- QUIT
- Begin DoDot:1
- +3 SET PSDR(+Y)=""
- End DoDot:1
- +4 IF '$DATA(PSDR)&(X'="^ALL")
- GOTO END
- +5 IF X="^ALL"
- SET ALL=1
- DEV ;sel device
- +1 SET Y=$PIECE($GET(^PSD(58.8,+PSDS,2)),"^",9)
- SET C=$PIECE(^DD(58.8,24,0),"^",2)
- DO Y^DIQ
- SET PSDEV=Y
- +2 WRITE !
- KILL %ZIS,IOP,IO("Q"),POP
- SET %ZIS="QM"
- SET %ZIS("B")=PSDEV
- DO ^%ZIS
- IF POP
- WRITE !!,"NO DEVICE SELECTED OR REPORT PRINTED!!",!
- GOTO END
- +3 IF $DATA(IO("Q"))
- KILL IO("Q"),ZTIO,ZTSAVE,ZTDTH,ZTSK
- SET ZTRTN="START^PSDBAL"
- SET ZTDESC="CS PHARM List Stock Balances"
- DO SAVE
- DO ^%ZTLOAD
- DO HOME^%ZIS
- KILL ZTSK
- GOTO END
- +4 USE IO
- START ;entry for compile
- +1 KILL ^TMP("PSDBAL",$JOB)
- +2 IF $DATA(ALL)
- FOR PSD=0:0
- SET PSD=$ORDER(^PSD(58.8,+PSDS,1,PSD))
- IF 'PSD
- QUIT
- IF $DATA(^PSD(58.8,+PSDS,1,PSD,0))
- SET PSDR(+PSD)=""
- +3 FOR PSD=0:0
- SET PSD=$ORDER(PSDR(PSD))
- IF 'PSD
- QUIT
- IF $DATA(^PSD(58.8,+PSDS,1,PSD,0))
- SET NODE=^(0)
- Begin DoDot:1
- +4 SET PSDOK=""
- IF +$PIECE(NODE,"^",14)
- IF +$PIECE(NODE,"^",14)'>DT
- IF '+$PIECE(NODE,"^",4)
- QUIT
- SET PSDOK="*"
- +5 SET BAL=+$PIECE(NODE,"^",4)
- SET PSDRN=$SELECT($PIECE($GET(^PSDRUG(+PSD,0)),"^")]"":$PIECE(^(0),"^"),1:"ZZ/"_PSD_" NAME MISSING")
- SET EXP=$SELECT(+$PIECE(NODE,"^",12):+$PIECE(NODE,"^",12),1:"")
- +6 IF EXP
- SET Y=EXP
- XECUTE ^DD("DD")
- SET EXP=Y
- +7 SET ^TMP("PSDBAL",$JOB,PSDRN,PSD)=BAL_"^"_PSDOK_"^"_EXP
- End DoDot:1
- PRINT ;prints data
- +1 SET (PG,PSDOUT)=0
- DO NOW^%DTC
- SET Y=+$EXTRACT(%,1,12)
- XECUTE ^DD("DD")
- SET RPDT=Y
- +2 KILL LN
- SET $PIECE(LN,"-",80)=""
- DO HDR
- +3 IF '$DATA(^TMP("PSDBAL",$JOB))
- WRITE !!,?15,"**** NO STOCK BALANCE DATA AVAILABLE ****",!!
- GOTO DONE
- +4 SET PSDR=""
- FOR
- SET PSDR=$ORDER(^TMP("PSDBAL",$JOB,PSDR))
- IF PSDR=""!(PSDOUT)
- QUIT
- FOR PSD=0:0
- SET PSD=$ORDER(^TMP("PSDBAL",$JOB,PSDR,PSD))
- IF 'PSD
- QUIT
- Begin DoDot:1
- +5 IF $Y+4>IOSL
- DO HDR
- IF PSDOUT
- QUIT
- +6 SET NODE=^TMP("PSDBAL",$JOB,PSDR,PSD)
- SET BAL=+NODE
- SET PSDOK=$PIECE(NODE,"^",2)
- SET EXP=$PIECE(NODE,"^",3)
- +7 WRITE !,PSDOK,?2,PSDR,?63,$JUSTIFY(BAL,6),!
- IF EXP]""
- WRITE ?5,"Expiration Date: ",EXP,!
- End DoDot:1
- DONE IF $EXTRACT(IOST)'="C"
- WRITE @IOF
- +1 IF $EXTRACT(IOST,1,2)="C-"
- IF 'PSDOUT
- WRITE !
- KILL DIR,DIRUT
- SET DIR(0)="EA"
- SET DIR("A")="END OF REPORT! Press <RET> to return to the menu"
- DO ^DIR
- KILL DIR
- END ;
- +1 KILL %,%H,%I,%ZIS,ALL,BAL,C,DA,DIC,DTOUT,DUOUT,EXP,LN,NODE,PG,POP,PSD,PSDEV,PSDOK,PSDOUT,PSDR,PSDRN,PSDS,PSDSN,RPDT,X,Y
- +2 KILL ^TMP("PSDBAL",$JOB),ZTDESC,ZTDTH,ZTIO,ZTRTN,ZTSAVE,ZTSK
- +3 DO ^%ZISC
- IF $DATA(ZTQUEUED)
- SET ZTREQ="@"
- +4 QUIT
- SAVE SET (ZTSAVE("PSDS"),ZTSAVE("PSDSN"),ZTSAVE("PSDSITE"))=""
- +1 IF $DATA(ALL)
- SET ZTSAVE("ALL")=""
- IF $DATA(PSDR)
- SET ZTSAVE("PSDR(")=""
- +2 QUIT
- HDR ;header
- +1 IF $EXTRACT(IOST,1,2)="C-"
- IF PG
- KILL DA,DIR
- SET DIR(0)="E"
- DO ^DIR
- KILL DIR
- IF 'Y
- SET PSDOUT=1
- QUIT
- +2 SET PG=PG+1
- IF $Y
- WRITE @IOF
- WRITE !,?12,"Current Stock Balances for ",PSDSN,?72,"Page: ",PG,!,?20,RPDT,!!
- +3 WRITE ?5,"DRUG",?60,"CURRENT BALANCE",!,LN,!!
- +4 QUIT
