PSDORV.m

PSDORV ;BIR/JPW-IV Pharm CS Order Request Entry ; 8 Aug 94

 ;;3.0; CONTROLLED SUBSTANCES ;;13 Feb 97

 I '$D(PSDSITE) D ^PSDSET Q:'$D(PSDSITE)

 S OK=$S($D(^XUSEC("PSJ RPHARM",DUZ)):2,$D(^XUSEC("PSJ PHARM TECH",DUZ)):2,1:0)

 I 'OK W $C(7),!!,?9,"** Please contact your Pharmacy Coordinator for access to order",!,?12,"narcotic supplies.",!!,"PSJ RPHARM or PSJ PHARM TECH security key required.",! K OK Q

 W !!,"Controlled Substances Order Entry",!! S PSDUZ=DUZ,PSDUZN=$P($G(^VA(200,PSDUZ,0)),"^"),(MSG,MSG1)=0,Y=DT X ^DD("DD") S REQD=Y

NAOU ;select NAOU to order supplies for

 K ^UTILITY($J,"W")

 N X,DIWL,DIWR,DIWF,PSD S PSD=0,DIWL=1,DIWR=80,DIWF="W"

 F  S PSD=$O(^PSD(58.8,+$P(PSDSITE,U,3),5,PSD)) Q:'PSD  S X=$G(^PSD(58.8,+$P(PSDSITE,U,3),5,PSD,0)) D ^DIWP

 D ^DIWW

 K DA,DIC S DIC=58.8,DIC(0)="QEA",DIC("A")="Select Ordering NAOU: ",DIC("S")="I $P(^(0),""^"",3)=+PSDSITE,$P(^(0),""^"",2)=""N"""

 D ^DIC K DIC G:Y<0 END S NAOU=+Y,NAOUN=$P(Y,"^",2)

 I '$D(^PSD(58.8,NAOU,0)) S MSG=1 D MSG G END

 I '$O(^PSD(58.8,NAOU,1,0)) S MSG=1,MSG1=2 D MSG G END

 S PSDS=+$P(^PSD(58.8,NAOU,0),"^",4) I '+PSDS S (MSG,MSG1)=1 D MSG G END

 I '$D(^PSD(58.8,+PSDS,0)) S MSG=2 D MSG G END

 I '$O(^PSD(58.8,+PSDS,1,0)) S MSG=2,MSG1=2 D MSG G END

 S TYPE=$P(^PSD(58.8,+PSDS,0),"^",2),OKTYP=$S(TYPE="M":1,TYPE="S":1,1:0) I 'OKTYP W !!,"Contact your Pharmacy Coordinator.",!,"The Pharmacy Dispensing Site is invalid for this NAOU." G END

DRUG ;select drug

 K DA,DIC S DIC("W")="W:$P(^PSDRUG(Y,0),""^"",9) ""   N/F"" I $P(^PSD(58.8,NAOU,1,Y,0),""^"",14)]"""",$P(^(0),""^"",14)'>DT W $C(7),""  *** INACTIVE ***"""

 S DA(1)=+NAOU,DIC(0)="QEAM",DIC="^PSD(58.8,"_NAOU_",1," D ^DIC K DIC G:Y<0 END S PSDR=+Y,PSDRN=$S($P(^PSDRUG(PSDR,0),"^")]"":$P(^(0),"^"),1:"DRUG NAME MISSING")

 I '$D(^PSD(58.8,NAOU,1,PSDR,0)) D MSG G END

 I '$D(^PSD(58.8,+PSDS,1,PSDR,0)) S MSG=2 D MSG G END

 S NBKU=$P(^PSD(58.8,+PSDS,1,PSDR,0),"^",8),NPKG=+$P(^(0),"^",9)

 I NBKU']"" S MSG1=3 D MSG G END

 I 'NPKG S MSG1=4 D MSG G END

 D LIST^PSDORL

QTY K ORD S PSDOUT=0 W !!,"QUANTITY ("_NBKU_"/"_NPKG_"): "_NPKG_"// " R X:DTIME I '$T!(X["^") G END

 S:X="" (X,PSDQTY)=NPKG I X["?"!(X'?1.N)!('X)!(X>999999) W !!,"Quantity must be a whole number between 1 and 999999",! G QTY

 S PSDQTY=X,CNT=0 D DIE,ASK^PSDORV1 G:PSDOUT END G DRUG

END K %,%DT,%H,%I,CNT,CNT1,DA,DIC,DIE,DINUM,DIR,DIROUT,DIRUT,DIWF,DIWL,DIWR,DR,DTOUT,DUOUT,LN,MSG,MSG1

 K NAOU,NAOUN,NBKU,NPKG,OK,OKTYP,ORD,PSDA,PSDOUT,PSDQTY,PSDR,PSDRD,PSDRN,PSDS,PSDT,PSDUZ,PSDUZN,REQD,TEXT,TYPE,WORD,X,Y

 Q

DIE ;create the order request

 S:'$D(^PSD(58.8,NAOU,1,PSDR,3,0)) ^(0)="^58.800118A^^"

 S PSDA=$P(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)+1 I $D(^PSD(58.8,NAOU,1,PSDR,3,PSDA)) S $P(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)=$P(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)+1 G DIE

 K DA,DIC,DIE,DD,DR,DO S DIC(0)="L",(DIC,DIE)="^PSD(58.8,"_NAOU_",1,"_PSDR_",3,",DA(2)=NAOU,DA(1)=PSDR,(X,DINUM)=PSDA D FILE^DICN K DIC

 D NOW^%DTC S PSDT=+$E(%,1,12) W ?10,!!,"processing now..."

 S DA=PSDA,DA(1)=PSDR,DA(2)=NAOU,DR="1////"_PSDT_";2////"_PSDS_";3////"_PSDUZ_";10////1;5////"_PSDQTY_";13" D ^DIE K DIE,DR

 Q

MSG ;display error message

 W $C(7),!!,?10,"Contact your Pharmacy Coordinator.",!,?10,"This "_$S(MSG=2:"Dispensing Site",MSG=1:"NAOU",1:"DRUG")_" is missing "

 W $S(MSG1=1:"Primary Disp. Site",MSG1=2:"stocked drugs",MSG1=3:"narcotic breakdown unit",MSG1=4:"narcotic package size",1:"data")_".",!

 Q

PSDORV    ;BIR/JPW-IV Pharm CS Order Request Entry ; 8 Aug 94

 +1       ;;3.0; CONTROLLED SUBSTANCES ;;13 Feb 97

 +2        IF '$DATA(PSDSITE)

               DO ^PSDSET

               IF '$DATA(PSDSITE)

                   QUIT 

 +3        SET OK=$SELECT($DATA(^XUSEC("PSJ RPHARM",DUZ)):2,$DATA(^XUSEC("PSJ PHARM TECH",DUZ)):2,1:0)

 +4        IF 'OK

               WRITE $CHAR(7),!!,?9,"** Please contact your Pharmacy Coordinator for access to order",!,?12,"narcotic supplies.",!!,"PSJ RPHARM or PSJ PHARM TECH security key required.",!

               KILL OK

               QUIT 

 +5        WRITE !!,"Controlled Substances Order Entry",!!

           SET PSDUZ=DUZ

           SET PSDUZN=$PIECE($GET(^VA(200,PSDUZ,0)),"^")

           SET (MSG,MSG1)=0

           SET Y=DT

           XECUTE ^DD("DD")

           SET REQD=Y

NAOU      ;select NAOU to order supplies for

 +1        KILL ^UTILITY($JOB,"W")

 +2        NEW X,DIWL,DIWR,DIWF,PSD

           SET PSD=0

           SET DIWL=1

           SET DIWR=80

           SET DIWF="W"

 +3        FOR 

               SET PSD=$ORDER(^PSD(58.8,+$PIECE(PSDSITE,U,3),5,PSD))

               IF 'PSD

                   QUIT 

               SET X=$GET(^PSD(58.8,+$PIECE(PSDSITE,U,3),5,PSD,0))

               DO ^DIWP

 +4        DO ^DIWW

 +5        KILL DA,DIC

           SET DIC=58.8

           SET DIC(0)="QEA"

           SET DIC("A")="Select Ordering NAOU: "

           SET DIC("S")="I $P(^(0),""^"",3)=+PSDSITE,$P(^(0),""^"",2)=""N"""

 +6        DO ^DIC

           KILL DIC

           IF Y<0

               GOTO END

           SET NAOU=+Y

           SET NAOUN=$PIECE(Y,"^",2)

 +7        IF '$DATA(^PSD(58.8,NAOU,0))

               SET MSG=1

               DO MSG

               GOTO END

 +8        IF '$ORDER(^PSD(58.8,NAOU,1,0))

               SET MSG=1

               SET MSG1=2

               DO MSG

               GOTO END

 +9        SET PSDS=+$PIECE(^PSD(58.8,NAOU,0),"^",4)

           IF '+PSDS

               SET (MSG,MSG1)=1

               DO MSG

               GOTO END

 +10       IF '$DATA(^PSD(58.8,+PSDS,0))

               SET MSG=2

               DO MSG

               GOTO END

 +11       IF '$ORDER(^PSD(58.8,+PSDS,1,0))

               SET MSG=2

               SET MSG1=2

               DO MSG

               GOTO END

 +12       SET TYPE=$PIECE(^PSD(58.8,+PSDS,0),"^",2)

           SET OKTYP=$SELECT(TYPE="M":1,TYPE="S":1,1:0)

           IF 'OKTYP

               WRITE !!,"Contact your Pharmacy Coordinator.",!,"The Pharmacy Dispensing Site is invalid for this NAOU."

               GOTO END

DRUG      ;select drug

 +1        KILL DA,DIC

           SET DIC("W")="W:$P(^PSDRUG(Y,0),""^"",9) ""   N/F"" I $P(^PSD(58.8,NAOU,1,Y,0),""^"",14)]"""",$P(^(0),""^"",14)'>DT W $C(7),""  *** INACTIVE ***"""

 +2        SET DA(1)=+NAOU

           SET DIC(0)="QEAM"

           SET DIC="^PSD(58.8,"_NAOU_",1,"

           DO ^DIC

           KILL DIC

           IF Y<0

               GOTO END

           SET PSDR=+Y

           SET PSDRN=$SELECT($PIECE(^PSDRUG(PSDR,0),"^")]"":$PIECE(^(0),"^"),1:"DRUG NAME MISSING")

 +3        IF '$DATA(^PSD(58.8,NAOU,1,PSDR,0))

               DO MSG

               GOTO END

 +4        IF '$DATA(^PSD(58.8,+PSDS,1,PSDR,0))

               SET MSG=2

               DO MSG

               GOTO END

 +5        SET NBKU=$PIECE(^PSD(58.8,+PSDS,1,PSDR,0),"^",8)

           SET NPKG=+$PIECE(^(0),"^",9)

 +6        IF NBKU']""

               SET MSG1=3

               DO MSG

               GOTO END

 +7        IF 'NPKG

               SET MSG1=4

               DO MSG

               GOTO END

 +8        DO LIST^PSDORL

QTY        KILL ORD

           SET PSDOUT=0

           WRITE !!,"QUANTITY ("_NBKU_"/"_NPKG_"): "_NPKG_"// "

           READ X:DTIME

           IF '$TEST!(X["^")

               GOTO END

 +1        IF X=""

               SET (X,PSDQTY)=NPKG

           IF X["?"!(X'?1.N)!('X)!(X>999999)

               WRITE !!,"Quantity must be a whole number between 1 and 999999",!

               GOTO QTY

 +2        SET PSDQTY=X

           SET CNT=0

           DO DIE

           DO ASK^PSDORV1

           IF PSDOUT

               GOTO END

           GOTO DRUG

END        KILL %,%DT,%H,%I,CNT,CNT1,DA,DIC,DIE,DINUM,DIR,DIROUT,DIRUT,DIWF,DIWL,DIWR,DR,DTOUT,DUOUT,LN,MSG,MSG1

 +1        KILL NAOU,NAOUN,NBKU,NPKG,OK,OKTYP,ORD,PSDA,PSDOUT,PSDQTY,PSDR,PSDRD,PSDRN,PSDS,PSDT,PSDUZ,PSDUZN,REQD,TEXT,TYPE,WORD,X,Y

 +2        QUIT 

DIE       ;create the order request

 +1        IF '$DATA(^PSD(58.8,NAOU,1,PSDR,3,0))

               SET ^(0)="^58.800118A^^"

 +2        SET PSDA=$PIECE(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)+1

           IF $DATA(^PSD(58.8,NAOU,1,PSDR,3,PSDA))

               SET $PIECE(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)=$PIECE(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)+1

               GOTO DIE

 +3        KILL DA,DIC,DIE,DD,DR,DO

           SET DIC(0)="L"

           SET (DIC,DIE)="^PSD(58.8,"_NAOU_",1,"_PSDR_",3,"

           SET DA(2)=NAOU

           SET DA(1)=PSDR

           SET (X,DINUM)=PSDA

           DO FILE^DICN

           KILL DIC

 +4        DO NOW^%DTC

           SET PSDT=+$EXTRACT(%,1,12)

           WRITE ?10,!!,"processing now..."

 +5        SET DA=PSDA

           SET DA(1)=PSDR

           SET DA(2)=NAOU

           SET DR="1////"_PSDT_";2////"_PSDS_";3////"_PSDUZ_";10////1;5////"_PSDQTY_";13"

           DO ^DIE

           KILL DIE,DR

 +6        QUIT 

MSG       ;display error message

 +1        WRITE $CHAR(7),!!,?10,"Contact your Pharmacy Coordinator.",!,?10,"This "_$SELECT(MSG=2:"Dispensing Site",MSG=1:"NAOU",1:"DRUG")_" is missing "

 +2        WRITE $SELECT(MSG1=1:"Primary Disp. Site",MSG1=2:"stocked drugs",MSG1=3:"narcotic breakdown unit",MSG1=4:"narcotic package size",1:"data")_".",!

 +3        QUIT