Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSGOE6

PSGOE6.m

Go to the documentation of this file. 
  1. PSGOE6 ;BIR/CML3-ORDER ENTRY THROUGH OE/RR ;10 Mar 98 / 2:35 PM
  1.  ;;5.0; INPATIENT MEDICATIONS ;**3,7,39,45,65,58,81,156,134**;16 DEC 97;Build 124
  1.  ;
  1.  ; Reference to ^PS(50.7 supported by DBIA #2180.
  1.  ; Reference to ^PS(51.1 is supported by DBIA #2177.
  1.  ; Reference to ^PS(51.2 is supported by DBIA #2178.
  1.  ; Reference to ^PS(55 is supported by DBIA #2191.
  1.  ; Reference to ^DD(53.1 is supported by DBIA #2256.
  1.  ; Reference to ^VA(200 is supported by DBIA #10060.
  1.  ; Reference to ^DICN is supported by DBIA #10009.
  1.  ;
  1.  K PSGFOK S F1=53.1,PSGPR=$S($D(PSGOERR):PSJORPV,1:PSGOEPR),PSGMR=$S($P(PSGNEDFD,"^",2):$P(PSGNEDFD,"^",2),1:PSGOEDMR),PSGSCH=$P(PSGNEDFD,"^",4),(PSGOROE1,PSGSI,SDT,PSGMRN,PSGSM,PSGHSM,PSGUD,PSGSD,PSGFD,PSGSI,PSGNEFD,PSGNESD)=""
  1.  S:PSGMR PSGMRN=$S('$P(PSGNEDFD,"^",2):"ORAL",'$D(^PS(51.2,PSGMR,0)):PSGMR,$P(^(0),"^")]"":$P(^(0),"^"),1:PSGMR) I PSGPR S PSGPRN=$P($G(^VA(200,PSGPR,0)),"^") S:PSGPRN="" PSGPRN=PSGPR
  1.  S PSGST=$S($P(PSGNEDFD,"^",3)]"":$P(PSGNEDFD,"^",3),1:"C")
  1.  ; Naked references in line below refer to ^PS(53.45,PSJSYSP
  1.  K ^PS(53.45,PSJSYSP,1),^(2) I PSGDRG S ^(2,0)="^53.4502P^"_PSGDRG_"^1",^(1,0)=PSGDRG,^PS(53.45,PSJSYSP,2,"B",PSGDRG,1)=""
  1.  ;
  1. 109 ; dosage ordered
  1.  W !,"DOSAGE ORDERED: ",$S(PSGDO]"":PSGDO_"// ",1:"") R X:DTIME I X="^"!'$T W:'$T $C(7) S PSGOROE1=1 G DONE
  1.  I X="" S X=PSGDO I X="" W $C(7),"  (Required)" G 109
  1.  S PSGF2=109 I X="@" W $C(7),"  (Required)" G 109
  1.  I X?1."?" S F1=53.1 D ENHLP^PSGOEM(53.1,109) G 109
  1.  I $E(X)="^" D FF G:Y>0 @Y G 109
  1.  I $E(X,$L(X))=" " F  S X=$E(X,1,$L(X)-1) Q:$E(X,$L(X))'=" "
  1.  I $S(X?.E1C.E:1,$L(X)>20:1,X="":1,X["^":1,X?1.P:1,1:X=+X) W $C(7),"  ",$S(X?1.P!(X=""):"(Required)",1:"??") S X="?" D ENHLP^PSGOEM(53.1,109) G 109
  1.  S PSGDO=X,PSGFOK(109)=""
  1.  ;
  1. 3 ; med route
  1.  W !,"MED ROUTE: ",$S(PSGMR:PSGMRN_"// ",1:"") R X:DTIME I X="^"!'$T W:'$T $C(7) S PSGOROE1=1 G DONE
  1.  I X="",PSGMR S X=PSGMRN I PSGMR'=PSGMRN,$D(^PS(51.2,PSGMR,0)) W "  "_$P(^(0),"^",3) S PSGFOK(3)="" G 26
  1.  S PSGF2=3 I $S(X="@":1,X]"":0,1:'PSGMR) W $C(7),"  (Required)" S X="?" D ENHLP^PSGOEM(53.1,3) G 3
  1.  I X?1."?" D ENHLP^PSGOEM(53.1,3)
  1.  I $E(X)="^" D FF G:Y>0 @Y G 3
  1.  K DIC S DIC="^PS(51.2,",DIC(0)="EMQZ",DIC("S")="I $P(^(0),""^"",4)" D ^DIC K DIC I Y'>0 G 3
  1.  S PSGMR=+Y,PSGMRN=Y(0,0),PSGFOK(3)=""
  1.  ;
  1. 26 ; schedule
  1.  W !,"SCHEDULE: ",$S(PSGSCH]"":PSGSCH_"// ",1:"") R X:DTIME I X="^"!'$T W:'$T $C(7) S PSGOROE1=1 G DONE
  1.  S:X="" X=PSGSCH S PSGF2=26 ; I "@"[X W $C(7),"  (Required)" S X="?" D ENHLP^PSGOEM(53.1,26) G 26
  1.  I X?1."?" D ENHLP^PSGOEM(53.1,26) G 26
  1.  I $E(X)="^" D FF G:Y>0 @Y G 26
  1.  I X="" S (PSGS0XT,PSGS0Y,PSGST)=""
  1.  E  D EN^PSGS0 I '$D(X) W $C(7),"  ??" S X="?" D ENHLP^PSGOEM(53.1,26) G 26
  1.  S PSGSCH=X,(PSGFOK(26),PSGST)="",PSGOES=1 S:PSGS0XT="O" $P(PSGNEDFD,"^",3)="O",PSGST="O" D ^PSGNE3 K PSGOES
  1.  ;
  1. 66 ; provider's comments
  1.  ;
  1.  ;
  1. DONE ;
  1.  I PSGOROE1 K Y W $C(7),"  ...order not entered..."
  1.  K F,F0,F1,PSGF2,F3,PSGFOK,SDT Q
  1.  ;
  1. FF ; up-arrow to another field
  1.  S Y=-1 I '$D(PSGFOK) W $C(7),"  ??" Q
  1.  S X=$E(X,2,99) I X=+X S Y=$S($D(PSGFOK(X)):X,1:-1) W "  " W:Y>0 $$CODES2^PSIVUTL(53.1,X) W:Y'>0 $C(7),"??" Q
  1.  K DIC S DIC="^DD(53.1,",DIC(0)="QEM",DIC("S")="I $D(PSGFOK(+Y))" D ^DIC K DIC S Y=+Y
  1.  Q
  1.  ;
  1. DEL ;
  1.  W !?3,"SURE YOU WANT TO DELETE" S %=0 D YN^DICN I %'=1 W "  <NOTHING DELETED>"
  1.  Q
  1.  ;
  1. GTST(ON) ; Find schedule type for pending order.
  1.  N PD,PDAP,ST,X,ST1 S ST=""
  1.  S ST=$P($G(^PS(53.1,+ON,0)),"^",7)
  1.  I $P($G(^PS(53.1,+ON,0)),U,24)="R" D
  1.  .; naked ref below is from line above, ^PS(53.1,ON,0)
  1.  .S X=$P(^(0),U,25) S ST=$S(X["N"!(X["P"):$P($G(^PS(53.1,+X,0)),U,7),X["V":"C",1:$P($G(^PS(55,PSGP,5,+X,0)),U,7))
  1.  .I ST]"" S (PSGOST,PSGST)=ST,PSGSTN=$$ENSTN^PSGMI(ST) Q
  1.  I ST'="" D
  1.  . S ST1=""
  1.  . S PD=+$G(^PS(53.1,+ON,.2)) S X=$G(^PS(50.7,PD,0)),ST1=$P(X,U,7)
  1.  . I $G(ST1)="R" S ST="R"
  1.  . K ST1
  1.  I ST="" D
  1.  . ;PSJ*5*156 - Don't allow backdoor to override intended schedule type from CPRS unless the default
  1.  . ;            schedule type (if any) is "Fill on Request".
  1.  . S PD=+$G(^PS(53.1,+ON,.2)) S X=$G(^PS(50.7,PD,0)),ST=$P(X,U,7)  ;see if there is a default schedule type.
  1.  . I ST="R" Q  ;Fill on Request default schedule type will override incoming schedule type from CPRS
  1.  . S ST=""  ;Reset to null in case default schedule type other than Fill on Request is defined.
  1.  . D OTS I ST="O" Q
  1.  . I PSGSCH="ON CALL"!(PSGSCH="ONCALL")!(PSGSCH="ON-CALL") S ST="OC" Q
  1.  . I PSGSCH["PRN" S ST="P" Q
  1.  . S ST="C"
  1.  S (PSGOST,PSGST)=ST,PSGSTN=$$ENSTN^PSGMI(ST)
  1.  Q
  1. OTS I PSGSCH]"" S X=+$O(^PS(51.1,"B",PSGSCH,0)) I $P($G(^PS(51.1,X,0)),"^",5)="O" S ST="O" Q
  1.  I PSGSCH="TODAY"!(PSGSCH="NOW")!(PSGSCH="STAT")!(PSGSCH="ONCE")!(PSGSCH="ONE TIME")!(PSGSCH="ONE-TIME")!(PSGSCH="ONETIME")!(PSGSCH="1TIME")!(PSGSCH="1 TIME")!(PSGSCH="1-TIME") S ST="O"
  1.  Q