Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSIVORFB

PSIVORFB.m

Go to the documentation of this file. 
  1. PSIVORFB ;BIR/MLM-FILE/RETRIEVE ORDERS IN ^PS(55 ;17-Mar-2014 13:20;DU
  1.  ;;5.0; INPATIENT MEDICATIONS ;**3,18,28,68,58,85,110,111,120,134,213,161,1010,1015,1018**;16 DEC 97;Build 21
  1.  ;
  1.  ; Reference to ^PS(50.7 is supported by DBIA #2180.
  1.  ; Reference to ^PS(51.2 is supported by DBIA #2178.
  1.  ; Reference to ^PS(52.6 is supported by DBIA #1231.
  1.  ; Reference to ^PS(52.7 is supported by DBIA #2173.
  1.  ; Reference to ^PS(55 is supported by DBIA #2191.
  1.  ; Reference to ^PS(51.1 is supported by DBIA #2177.
  1.  ; Reference to ^PSUHL is supported by DBIA #4803.
  1.  ;
  1.  ; Modified - IHS/CIA/PLS - 12/05/03 - Line NEW55+3
  1.  ;          - IHS/MSC/PB - 4/25/12 - added line tag OFFSET
  1.  ;          - IHS/MSC/PB - modified line GTDRG+6 to add the stability offset value to
  1.  ;            the DRG array for each additive and solution
  1.  ;          - IHS/MSC/PB - 2/11/13 added line OFFSET+5 to add a default value of seven days if the offset is 0
  1.  ;          - IHS/MSC/PLS - 03/17/14 - Added change to NEW55 and LIMSTOP EP from VistA PSJ*5.0*273
  1.  ;
  1. NEW55 ; Get new order number in 55.
  1.  N DA,DD,DO,DIC,DLAYGO,X,Y,PSIVLIM,MINS,PSJDSTP1,PSJDSTP2,A,PSJCLIN,PSJDNM,PSJPROV,PSJWARD,PSJPAO,PSJALRT
  1.  I $D(^PS(55,+DFN)),'$D(^PS(55,+DFN,0)) D ENSET0^PSGNE3(+DFN)
  1.  ;IHS/MSC/PLS - 03/17/14 - Added logic from PSJ*5.0*273
  1.  I $G(PSJORD)["V"!($G(PSJORD)["P"),$G(P(2))]"" D
  1.  .I '$G(PSIVSITE) S PSIVSN=$P(P("IVRM"),"^") D ENCHK^PSIVSET
  1.  .D LIMSTOP(.PSJDSTP1,.PSJDSTP2)
  1.  I ($G(PSJORD)["P"!($G(PSJORD)["V"))&$G(PSIVLIM) I $$CMPLIM(PSJORD,PSJDSTP1,PSJDSTP2) D
  1.  . D
  1.  .. S PSJPROV=DUZ I PSJORD["P" S PSJPROV=$P($G(^PS(53.1,+PSJORD,0)),"^",2)
  1.  .. I PSJORD["V" S PSJPROV=$P($G(^PS(55,DFN,"IV",+PSJORD,0)),"^",6)
  1.  .. D NOW^%DTC S XQA(PSJPROV)="",XQAID="PSJ,"_DFN_";"_PSJPROV_";"_%,XQADATA=""
  1.  .. D
  1.  ... I PSJORD["P" S A=$G(^PS(53.1,+PSJORD,"DSS"))
  1.  ... I PSJORD["V" S A=$G(^PS(55,PSGP,"IV",+PSJORD,"DSS"))
  1.  ... S PSJCLIN=$P(A,"^") I PSJCLIN]"" S PSJCLIN=$P(^SC(PSJCLIN,0),"^")
  1.  .. S A=$G(^DPT(DFN,0)),PSJWARD=$G(^(.1))
  1.  .. S XQAMSG=$P(A,"^")_" ("_$E($P(A,"^"))_$E($P(A,"^",9),6,9)_"): ["_$S(PSJWARD]"":$E(PSJWARD,1,10),$G(PSJCLIN)]"":$E(PSJCLIN,1,10),1:"UNKNOWN")_"] "
  1.  .. S A=$O(DRG("AD",0)) I A]"" S A=DRG("AD",A)
  1.  .. I A="" S A=$O(DRG("SOL",0)) I A]"" S A=DRG("SOL",A)
  1.  .. S PSJDNM=$P(^PS(50.7,+$P(A,"^",6),0),"^")
  1.  .. S XQAMSG=XQAMSG_PSJDNM_" your DURATION not used for stop date/time"
  1.  .. D SETUP^XQALERT
  1.  .. S PSJALRT=$$FMTDUR^PSJLIVMD($S(PSJORD["P":$P($G(^PS(53.1,+PSJORD,2.5)),"^",4),PSJORD["IV":$P($G(^PS(55,DFN,"IV",+PSJORD,2.5)),"^",4),1:"UNK"))
  1.  ; IHS/CIA/PLS - 12/05/03 - Reapplied IHS fix for HRN lookup
  1.  ;S DIC="^PS(55,",DIC(0)="LN",DLAYGO=55,(DINUM,X)=+DFN D ^DIC Q:Y<0
  1.  S DIC="^PS(55,",DIC(0)="LN",DLAYGO=55,DINUM=+DFN,X="`"_+DFN D ^DIC Q:Y<0
  1. LOCK0 F  L +^PS(55,DFN,"IV",0):$S($G(DILOCKTM)>0:DILOCKTM,1:3) I  Q
  1.  S ND=$S($D(^PS(55,DFN,"IV",0)):^(0),1:"^55.01") F DA=$P(ND,"^",3)+1:1 W "." I '$D(^PS(55,DFN,"IV",DA)) S $P(ND,"^",3)=DA,$P(ND,"^",4)=$P(ND,"^",4)+1,^PS(55,DFN,"IV",0)=ND Q
  1.  L +^PS(55,DFN,"IV",+DA):$S($G(DILOCKTM)>0:DILOCKTM,1:3) E  G LOCK0
  1.  S ^PS(55,DFN,"IV",+DA,0)=+DA,^PS(55,DFN,"IV","B",+DA,+DA)=""
  1.  L -^PS(55,DFN,"IV",0) S ON55=+DA_"V"
  1.  I $G(PSJALRT)]"" S PSIVAL="IV LIMIT OVERRIDDEN ("_$G(PSJALRT)_"): ALERT SENT",PSIVALT="",PSIVREA="E" D
  1.  .D LOG^PSIVORAL S P("LIMIT")="",P("OVRIDE")=1 K IVLIM,IVLIMIT
  1.  .S $P(^PS(55,DFN,"IV",+ON55,2.5),"^",4)="" S:$G(PSJORD)["P" $P(^PS(53.1,+PSJORD,2.5),"^",4)=""
  1.  .K PSIVAL,PSIVREA,PSIVALT
  1.  Q
  1. SET55 ; Move data from local variables to 55.
  1.  I '$D(ON55) W !,"*** Can't create this order at this time ***" Q
  1.  N DA,DIK,ND,PSIVACT,PSIVDUR
  1.  S:'$D(P(21)) (P(21),P("21FLG"))="" S ND(0)=+ON55,P(22)=$S(VAIN(4):+VAIN(4),1:.5) F X=2:1:23 I $D(P(X)) S $P(ND(0),U,X)=P(X)
  1.  S ND(.3)=$G(P("INS")),ND(2.5)="" N X S X=$S($G(PSGORD):PSGORD,1:$G(ON)) I X D
  1.  .N PKG S PKG=$E(X,$L(X)) S PKG=$S(PKG="V":"""IV""",PKG="U":5,PKG="P":"P",1:"") Q:PKG=""
  1.  .S PSIVDUR=$$GETDUR^PSJLIVMD(DFN,+X,$E(X,$L(X)),1) Q:PSIVDUR=""
  1.  .I $G(IVLIMIT) S ND(2.5)="^^^"_PSIVDUR K IVLIMIT Q
  1.  S $P(ND(0),U,17)="A",ND(1)=P("REM"),ND(3)=P("OPI"),ND(.2)=$P($G(P("PD")),U)_U_$G(P("DO"))_U_+P("MR")_U_$G(P("PRY"))_U_$G(P("NAT"))_U_U_U_$G(P("PRNTON"))
  1.  F X=0,1,2.5,3,.2,.3 S ^PS(55,DFN,"IV",+ON55,X)=ND(X)
  1.  ; PSJ*5*213 - if Piggyback, intermittent syringe, or
  1.  ; intermittent chemotherapy, and frequency is null, attempt to
  1.  ; set frequency again based on P(15),PSGS0XT, and piece 3 of ZZND if they exist.
  1.  ; If this still is null, attempt to re-set based upon the schedule name.
  1.  I $G(P("IVCAT"))="I"!($P($G(ND(0)),U,4)?1(1"P",1"S",1"C"))&($P($G(ND(0)),U,15)="") D
  1.  . I $P($G(ND(0)),U,4)="S",$P($G(ND(0)),U,5)'=1 Q  ;Not intermittent syringe
  1.  . I $P($G(ND(0)),U,4)="C",$P($G(ND(0)),U,23)?1(1"A",1"H") Q  ;Not chemo piggyback or syringe
  1.  . I $P($G(ND(0)),U,4)="C",$P($G(ND(0)),U,23)="S",$P($G(ND(0)),U,5)'=1 Q  ;Not intermitent chemo syringe
  1.  . S $P(^PS(55,DFN,"IV",+ON55,0),U,15)=$S($G(P(15))'="":P(15),$G(PSGS0XT)'="":PSGS0XT,$P($G(ZZND),"^",3)'="":$P(ZZND,"^",3),1:$$GETFRQ($P($G(ND(0)),U,9))) K PSJFRQ,PSJSKED
  1.  S $P(^PS(55,DFN,"IV",+ON55,2),U,1,4)=P("LOG")_U_+P("IVRM")_U_U_P("SYRS"),$P(^(2),U,8,10)=P("RES")_U_$G(P("FRES"))_U_$S($G(VAIN(4)):+VAIN(4),1:"")
  1.  S X=^PS(55,DFN,0) I $P(X,"^",7)="" S $P(X,"^",7)=$P($P(P("LOG"),"^"),"."),$P(X,"^",8)="A",^(0)=X D LOGDFN^PSUHL(DFN)
  1.  S $P(^PS(55,DFN,"IV",+ON55,2),U,11)=+P("CLRK")
  1.  S:+$G(P("CLIN")) $P(^PS(55,DFN,"IV",+ON55,"DSS"),"^")=P("CLIN")
  1.  S:+$G(P("APPT")) $P(^PS(55,DFN,"IV",+ON55,"DSS"),"^",2)=P("APPT")
  1.  S:+$G(P("NINIT")) ^PS(55,DFN,"IV",+ON55,4)=P("NINIT")_U_P("NINITDT")
  1.  ;IHS/MSC/PB - 4/25/12 line below modified to set the 9999999 node to the stability offset value
  1.  S:$G(P("OFFSET")) ^PS(55,DFN,"IV",+ON55,9999999)=$G(P("OFFSET"))
  1.  I '$G(PSIVCHG)!($G(PSJREN)&($G(PSIVCHG)=2)) I $G(P("PON")),P("PON")'=ON55 D
  1.  . N X S X=$S(P("PON")["P":"^PS(53.1,+P(""PON""),12,0)",P("PON")["V"&$G(PSJREN):"^PS(55,DFN,""IV"",+P(""PON""),5,0)",1:"") Q:X=""
  1.  . I $O(@X) S %X=X,%Y="^PS(55,"_DFN_",""IV"","_+ON55_",5," D %XY^%RCR
  1.  F DRGT="AD","SOL" D PUTD55
  1.  K DA,DIK S DA(1)=DFN,DA=+ON55,DIK="^PS(55,"_DA(1)_",""IV"",",PSIVACT=1 D IX^DIK
  1.  I $G(PSJCOM),$G(PSJCOMSI),$G(PSJORD)["V" K PSJCOMSI N PSJCHILD,PSJOEORD S PSJOEORD=0 F  S PSJOEORD=$O(^PS(55,"ACX",PSJCOM,PSJOEORD)) Q:'PSJOEORD  D
  1.  . N PSJCHILD S PSJCHILD=0 F  S PSJCHILD=$O(^PS(55,"ACX",PSJCOM,PSJOEORD,PSJCHILD)) Q:'PSJCHILD  S PSJCHILD(+PSJCHILD)=PSJCOM
  1.  . S PSJCHILD=0 F  S PSJCHILD=$O(PSJCHILD(PSJCHILD)) Q:'PSJCHILD  D
  1.  .. Q:PSJCHILD=PSJORD  K DR,DA,DIE,ORD S DR="31////"_$P($G(P("OPI")),"^",1,2),DA(1)=DFN
  1.  .. N ON,ON55 S (ON,ON55)=+PSJCHILD_"V" S:+$G(PSJPINIT)'>0 PSJPINIT=DUZ S PSIVALT=1,PSIVAL="COMPLEX ORDER" D ENTACT^PSIVAL D
  1.  ... I $P($G(^PS(55,DFN,"IV",+ON55,3)),"^")'=$P(P("OPI"),"^") S P("FC")="OTHER PRINT INFO^"_$P($G(^(3)),"^")_U_$P(P("OPI"),"^") D GTFC^PSIVORAL
  1.  ... I $D(^PS(55,DFN,"IV",+ON55,0)) S ^PS(55,DFN,"IV",+ON55,3)=P("OPI") D EN1^PSJHL2(DFN,"XX",ON55)
  1.  Q
  1.  ;
  1. PUTD55 ; Move drug data from local array into 55
  1.  K ^PS(55,DFN,"IV",+ON55,DRGT) S ^PS(55,DFN,"IV",+ON55,DRGT,0)=$S(DRGT="AD":"^55.02PA",1:"^55.11IPA")
  1.  F X=0:0 S X=$O(DRG(DRGT,X)) Q:'X  D
  1.  .S Y=^PS(55,DFN,"IV",+ON55,DRGT,0),$P(Y,U,3)=$P(Y,U,3)+1,DRG=$P(Y,U,3),$P(Y,U,4)=$P(Y,U,4)+1
  1.  .S ^PS(55,DFN,"IV",+ON55,DRGT,0)=Y,Y=$P(DRG(DRGT,X),U)_U_$P(DRG(DRGT,X),U,3) S:DRGT="AD" $P(Y,U,3)=$P(DRG(DRGT,X),U,4) S ^PS(55,DFN,"IV",+ON55,DRGT,+DRG,0)=Y
  1.  Q
  1. GT55 ; Retrieve data from 55 into local array
  1.  K DRG,DRGN,P S:'$D(ON55) ON55=ON S P("REN")="",Y=$G(^PS(55,DFN,"IV",+ON55,0)) F X=1:1:23 S P(X)=$P(Y,U,X)
  1.  S P("21FLG")=P(21)
  1.  S P("PON")=ON55,PSJORIFN=P(21),P(6)=P(6)_U_$P($G(^VA(200,+P(6),0)),U),(DRG,DRGN)="",P("REM")=$G(^PS(55,DFN,"IV",+ON55,1))
  1.  S Y=$G(^PS(55,DFN,"IV",+ON55,2)),P("LOG")=$P(Y,U),P("IVRM")=$P(Y,U,2)_U_$P($G(^PS(59.5,+$P(Y,U,2),0)),U)
  1.  S P("CLRK")=$P(Y,U,11)_U_$P($G(^VA(200,+$P(Y,U,11),0)),U),P("RES")=$P(Y,U,8),P("FRES")=$P(Y,U,9),P("SYRS")=$P(Y,U,4),P("OPI")=$G(^PS(55,DFN,"IV",+ON55,3))
  1.  S P("INS")=$G(^PS(55,DFN,"IV",+ON55,.3))
  1.  S P("CLIN")=$P($G(^PS(55,DFN,"IV",+ON55,"DSS")),"^"),P("APPT")=$P($G(^PS(55,DFN,"IV",+ON55,"DSS")),"^",2)
  1.  S P("DTYP")=$S(P(4)="":0,P(4)="P"!(P(23)="P")!(P(5)):1,P(4)="H":2,1:3)
  1.  D:'$D(PSJLABEL) GTPC(ON55) S ND=$G(^PS(55,DFN,"IV",+ON55,.2)),P("PD")=$S($P(ND,U):$P(ND,U)_U_$$OIDF^PSJLMUT1(+ND)_U_$P($G(^PS(50.7,+ND,0)),U),1:""),P("DO")=$P(ND,U,2),P("PRY")=$P(ND,U,4),P("NAT")=$P(ND,U,5),(PSJCOM,P("PRNTON"))=$P(ND,U,8)
  1.  I P("PRY")="D",'+P("IVRM") S P("IVRM")=+$G(PSIVSN)_U_$P($G(^PS(59.5,+$G(PSIVSN),0)),U)
  1.  S P("MR")=$P(ND,U,3),ND=$G(^PS(51.2,+P("MR"),0)),P("MR")=P("MR")_U_$S($P(ND,U,3)]"":$P(ND,U,3),1:$P(ND,U)) D GTCUM
  1.  D GTDRG,GTOT^PSIVUTL(P(4))
  1.  N ND2P5 S ND2P5=$G(^PS(55,DFN,"IV",+ON55,2.5)) D
  1.  .S P("DUR")=$P(ND2P5,"^",2)
  1.  .S P("LIMIT")=$P(ND2P5,"^",4)
  1.  .S P("IVCAT")=$P(ND2P5,"^",5)
  1. K ; Kill and exit.
  1.  K FIL,ND
  1.  Q
  1. GTDRG ; Get drug info and place in DRG(.
  1.  F DRGT="AD","SOL" S FIL=$S(DRGT="AD":52.6,1:52.7) F Y=0:0 S Y=$O(^PS(55,DFN,"IV",+ON55,DRGT,Y)) Q:'Y  D
  1.  .; naked ref below refers to line above
  1.  .S DRG=$G(^(Y,0)),ND=$G(^PS(FIL,+DRG,0)),(DRGI,DRG(DRGT,0))=$G(DRG(DRGT,0))+1
  1.  .;IHS/MSC/PB 4/25/12 modified to add stability offset value to the DRG array for each additive and solution
  1.  .;S DRG(DRGT,+DRGI)=+DRG_U_$P(ND,U)_U_$P(DRG,U,2)_U_$P(DRG,U,3)_U_$P(ND,U,13)_U_$P(ND,U,11)
  1.  .S DRG(DRGT,+DRGI)=+DRG_U_$P(ND,U)_U_$P(DRG,U,2)_U_$P(DRG,U,3)_U_$P(ND,U,13)_U_$P(ND,U,11)_U_$P($G(^PS(FIL,+DRG,9999999)),"^")
  1.  Q
  1.  ;
  1. GTCUM ; Retrieve dispensing info.
  1.  S ND=$G(^PS(55,DFN,"IV",+ON55,9)),P("LF")=$P(ND,U),P("LFA")=$P(ND,U,2),P("CUM")=$P(ND,U,3)
  1.  Q
  1.  ;
  1. GTPC(ON) ; Retrieve Provider Comments and create "scratch" fields to edit
  1.  Q
  1.  ;
  1. SETNEW ; Create new order and set
  1.  D NEW55,SET55
  1.  Q
  1.  ;
  1. CMPLIM(PSJORD,PSJDSTP1,PSJDSTP2) ; Compare stop date of order against IV Limit
  1.  I $P($G(^PS(53.1,+PSJORD,0)),"^",25)]"" D CHKD Q:PSJPAO 0
  1.  I $G(PSJDSTP1),$E(+PSJDSTP1,1,11)'=$E(+P(3),1,11),+PSJDSTP2'=+P(3) Q 1
  1.  Q 0
  1.  ;
  1. LIMSTOP(PSJDSTP1,PSJDSTP2) ; Calculate default stop date using IV Limit
  1.  ;      Output: PSJDSTP1 - Default stop using duration only
  1.  ;              PSJDSTP2 - Default stop using duration and IV parameters for time
  1.  S PSIVLIM=$$GETLIM^PSIVCAL(DFN,PSJORD)
  1.  I 'PSIVLIM,PSIVLIM]"" S PSIVLIM=$$GETMIN^PSIVCAL(PSIVLIM,DFN,PSJORD)
  1.  I PSIVLIM]"" D
  1.  . S MINS=$$GETMIN^PSIVCAL(PSIVLIM,DFN,PSJORD),PSJDSTP1=$$FMADD^XLFDT(P(2),0,0,MINS)
  1.  . S X=$P(PSJDSTP1,"."),PSJDSTP2=X_$S($P($G(PSIVSITE),"^",14)="":.2359,1:"."_$P(PSIVSITE,"^",14))
  1.  Q
  1.  ;
  1. GETFRQ(PSJSKED) ;Get frequency using name of schedule
  1.  I PSJSKED="" K PSJSKED Q ""
  1.  S (PSJCNTX,PSJFRQ)=""
  1.  I $D(^PS(51.1,"APPSJ",PSJSKED)) F  S PSJCNTX=$O(^PS(51.1,"APPSJ",PSJSKED,PSJCNTX)) Q:PSJCNTX=""  D  Q:$G(PSJFRQ)'=""
  1.  . I $P($G(^PS(51.1,PSJCNTX,0)),U,3)'="" S PSJFRQ=$P(^PS(51.1,PSJCNTX,0),U,3)
  1.  K PSJCNTX
  1.  Q PSJFRQ
  1.  ;
  1. CHKD ;Check for a previous active order and compare the duration
  1.  N PSJPO,A,PSJDUR
  1.  S PSJDUR=$$GETLIM^PSIVCAL(DFN,PSJORD)
  1.  S PSJPAO=0,PSJPO=PSJORD
  1. CHKDR S PSJPO=$P($G(^PS(53.1,+PSJPO,0)),"^",25) Q:PSJPO=""
  1.  I PSJPO["P" G CHKDR
  1.  I PSJPO["V" S PSIVLIM=$$GETLIM^PSIVCAL(DFN,PSJPO) I PSJDUR'=PSIVLIM S PSJPAO=1 Q
  1.  G CHKDR
  1. OFFSET ; IHS/MSC/PB - 4/25/12 - Added to get the minimum offset value for setting expiration date on IV labels
  1.  ; needs DRG array set in PSIVORFA. Piece 7 has the offset value for the solution or additive
  1.  S II="",OFFSET=31 F  S II=$O(DRG(II)) Q:II=""  S JJ=0 F  S JJ=$O(DRG(II,JJ)) Q:JJ'>0  D
  1.  .Q:$P(DRG(II,JJ),"^",7)=""
  1.  .S:$P(DRG(II,JJ),"^",7)<OFFSET OFFSET=$P(DRG(II,JJ),"^",7)
  1.  S:$G(OFFSET)=31 OFFSET=0
  1.  Q