Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSJUTL3

PSJUTL3.m

Go to the documentation of this file. 
  1. PSJUTL3 ;BIR/MLM-MISC. INPATIENT UTILITIES ;29 OCT 01 / 4:29 PM
  1.  ;;5.0; INPATIENT MEDICATIONS ;**58**;16 DEC 97
  1.  ;
  1.  ; Reference to ^PS(55 is supported by DBIA# 2191.
  1.  ; Reference to ^PSSLOCK is supported by DBIA# 2789.
  1.  ;
  1. EN ;
  1.  Q:$$PATCH^XPDUTL("PSJ*5.0*58")
  1.  S ZTDTH=$H,ZTRTN="QUEIV^PSJUTL3",ZTIO="",ZTDESC="Inpatient medications - Mark IV orders as verified"
  1.  D ^%ZTLOAD
  1.  Q
  1. QUEIV ;
  1.  D XTMP
  1.  NEW DFN,START,PSJX
  1.  D NOW^%DTC S START=%
  1.  F DFN=0:0 S DFN=$O(^PS(55,DFN)) Q:'DFN  D
  1.  . S PSJX=$P($G(^PS(55,DFN,5.1)),U,11)
  1.  . Q:PSJX=3
  1.  . I PSJX=2 D MARKIV(DFN) Q
  1.  . D CNIV^PSJUTL1(DFN)
  1.  D SEND(START)
  1.  Q
  1. XTMP ;
  1.  I '$D(^XTMP("PSJ NEW PERSON",0)) D
  1.  . NEW X1,X2 S X1=DT,X2=30 D C^%DTC
  1.  . S ^XTMP("PSJ NEW PERSON",0)=X_U_DT_U_"Correct changed user names"
  1.  Q
  1.  ;
  1. MARKIV(DFN) ;
  1.  ;Mark the Verifying Pharmacy field for active order created prior
  1.  ; to PSJ*5*58
  1.  NEW ON,ON55,X,PSJPINIT,PSJIDT,PSJNOW,PSIVACT
  1.  Q:'$$L^PSSLOCK(DFN,0)
  1.  D NOW^%DTC S PSJNOW=$E(%,1,12)
  1.  S PSJIDT=$$INSTLDT^PSJUTL1() I PSJIDT="" S PSJIDT=PSJNOW
  1.  S $P(^PS(55,DFN,5.1),U,11)=3
  1.  F ON=0:0 S ON=$O(^PS(55,DFN,"IV",ON)) Q:'ON  D
  1.  . S X=$G(^PS(55,DFN,"IV",ON,2))
  1.  . I +X>PSJIDT Q
  1.  . S PSJPINIT=$P(X,U,11)
  1.  . NEW XX,XX1,PSJIEN
  1.  . F XX=0:0 S XX=$O(^PS(55,DFN,"IV",ON,"A",XX)) Q:'XX  D
  1.  .. NEW PSJX S XX1=$G(^PS(55,DFN,"IV",ON,"A",XX,0))
  1.  .. Q:$P(XX1,U,3)=""
  1.  .. K PSJIEN S PSJX=""
  1.  .. I $P(XX1,U,6)="" D
  1.  ... D NAME^PSJBCMA1($P(XX1,U,3),,,.PSJIEN)
  1.  ... S:PSJIEN>0 $P(^PS(55,DFN,"IV",ON,"A",XX,0),U,6)=PSJIEN,XX1=^(0)
  1.  .. Q:+$P($G(^PS(55,DFN,"IV",ON,4)),U,4)
  1.  .. I $P(XX1,U,2)="F",($P(XX1,U,4)'="FINISHED BY TECHNICIAN") S PSJPINIT=$P(XX1,U,6),PSJX=1
  1.  .. S:$G(PSJIEN)=-1 ^XTMP("PSJ NEW PERSON",1,$P(XX1,U,3),DFN,ON,XX)=PSJX
  1.  . Q:+PSJPINIT'>0
  1.  . Q:+$P($G(^PS(55,DFN,"IV",ON,4)),U,4)
  1.  . D VF(ON,DFN,PSJPINIT,PSJNOW)
  1.  D UL^PSSLOCK(DFN)
  1.  Q
  1. VF(ON,DFN,PSJPINIT,PSJNOW) ; Update verifying pharm and date fields.
  1.  K DA,DIE,DR
  1.  S PSIVACT=""
  1.  S DIE="^PS(55,"_DFN_",""IV"",",DA=ON,DA(1)=DFN
  1.  S DR="140////"_PSJPINIT_";141////"_PSJNOW_";142////1" D ^DIE
  1.  S ON55=ON,PSIVREA="V",PSIVALT=""
  1.  S PSIVAL="AUTO VERIFIED WITH PATCH PSJ*5*58"
  1.  D LOG^PSIVORAL K PSIVAL,PSIVALT,PSIVREA
  1.  Q
  1. SEND(START) ;
  1.  NEW DIFROM,XMDUZ,XMSUB,XMTEXT,XMY,STOP,LINE
  1.  D NOW^%DTC S STOP=%
  1.  S LINE(1)="Marking prior IV orders as verified started: "_$$FMTE^XLFDT(START)
  1.  S LINE(2)="It ran to completion: "_$$FMTE^XLFDT(STOP)
  1.  I $O(^XTMP("PSJ NEW PERSON",0)) D
  1.  . S LINE(3)=""
  1.  . S LINE(4)="Please assign the PSJI ACTIVITY LOG VA200 option to a holder of the"
  1.  . S LINE(5)="PSJI MGR key who is familiar with the Pharmacy users to correct any "
  1.  . S LINE(6)="names that the software was unable to match to the New Person file (#200)."
  1.  S XMSUB="PSJ*5*58 IV Verification",XMTEXT="LINE("
  1.  S XMDUZ="PSJ*5*58"
  1.  S XMY(+DUZ)="" D ^XMD
  1.  Q