Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSOBPSR1

PSOBPSR1.m

Go to the documentation of this file. 
  1. PSOBPSR1 ;BHM/LE - continued Ignored Claims Report ;03/01/07
  1.  ;;7.0;OUTPATIENT PHARMACY;**260**;13 Feb 97;Build 84
  1.  ;External reference to File ^PS(55 supported by DBIA 2228
  1.  ;External reference to $$GET1^DIQ is supported by DBIA 2056
  1.  ;External reference to ^VADPT is supported by DBIA 10061
  1.  ;External reference to ^XLFDT is supported by DBIA 10103
  1.  ;External reference to ^%ZISC is supported by DBIA 10089
  1.  ;
  1. EN N CLOSE,CDATE,DFN,DRG,RXIEN,PAG,PCNT,PRTD,PNAM,I,II,J,Y,X,XX,S1,S2,S3,S4,S5,FCNT,CBYI
  1.  N SP1,SP2,SEQ2,CINFO,RDATE,RSEQ,PSORX,RXINFO,DNAMI,CDIV,CDIVN,OCDIV,RXNUMB,PSORXN,RXE
  1.  U IO K ^TMP("PSOBPSRP",$J),^TMP("PSOBPSRC",$J)
  1.  S (SP1,SP2)="",$P(SP1,"=",81)="",$P(SP2,"-",81)=""
  1.  ;
  1.  ; - Loop through reject dates xref
  1.  S (RXIEN,PCNT,FCNT,PRTD)=0 K DIRUT
  1.  S RDATE=PSOSD
  1.  ;
  1. DATE ;
  1.  S RDATE=$O(^PSRX("REJDAT",RDATE)) G NEXT:RDATE=""!(RDATE>PSOED)
  1. RX ;
  1.  S RXIEN=$O(^PSRX("REJDAT",RDATE,RXIEN)) G DATE:RXIEN=""
  1.  S (DFN,DRG,PNAM,DNAM,DNAMI,RXE)=""
  1.  K RXINFO D GETS^DIQ(52,RXIEN_",",".01;2;6","IE","RXINFO")
  1.  S PNAM=$G(RXINFO(52,RXIEN_",",2,"E")),DNAM=$G(RXINFO(52,RXIEN_",",6,"E"))
  1.  S DFN=$G(RXINFO(52,RXIEN_",",2,"I")),DNAMI=$G(RXINFO(52,RXIEN_",",6,"I"))
  1.  S RXE=$G(RXINFO(52,RXIEN_",",.01,"E"))_" "
  1.  I '$G(PSOAPT),'$D(PSOPT(DFN)) G RX   ;user selected specific patients
  1.  I '$G(PSODRUG),'$D(PSODRG(DNAMI)) G RX
  1.  ;
  1.  ;look for ignored rejects 
  1.  S SEQ2=0 F  S SEQ2=$O(^PSRX(RXIEN,"REJ",SEQ2)) Q:'SEQ2&(SEQ2'?1N.N)  D
  1.  . S (CDATE,CBY,CBYI,CFILL,CDIV)=""
  1.  . K CLOSE D GETS^DIQ(52.25,SEQ2_","_RXIEN_",","5;10;11;12","IE","CLOSE")
  1.  . S CDATE=$G(CLOSE(52.25,SEQ2_","_RXIEN_",",10,"I"))
  1.  . S CFILL=$G(CLOSE(52.25,SEQ2_","_RXIEN_",",5,"I"))
  1.  . S CDIV=$$RXSITE^PSOBPSUT(RXIEN,CFILL)
  1.  . I '$G(PSOSIT)&'$D(PSODIV(CDIV)) Q
  1.  . I $G(CLOSE(52.25,SEQ2_","_RXIEN_",",12,"I"))=6,(CDATE'<PSOSD&(CDATE'>PSOED)) D
  1.  . . S CBY=$G(CLOSE(52.25,SEQ2_","_RXIEN_",",11,"E"))
  1.  . . S CBYI=$G(CLOSE(52.25,SEQ2_","_RXIEN_",",11,"I"))
  1.  . . I '$G(PSOUSER),'$D(PSOU(CBYI)) Q  ;user selected specific user for "ignored by" column in report
  1.  . . D SET
  1.  G RX
  1.  ;
  1. NEXT ; - If not Sorting (already printed), SKIP, otherwise, print the report
  1.  I '$D(^TMP("PSOBPSRP")) G NDTP
  1.  S (S1,S2,S3,DFN,RSEQ,PSORX,PSORXN,RXNUMB,CDIV,OCDIV,CDIVN)=""
  1.  F  S CDIV=$O(^TMP("PSOBPSRP",$J,CDIV)) Q:CDIV=""  D  Q:$D(DIRUT)
  1.  . F  S S1=$O(^TMP("PSOBPSRP",$J,CDIV,S1)) Q:S1=""  D  Q:$D(DIRUT)
  1.  . . F  S S2=$O(^TMP("PSOBPSRP",$J,CDIV,S1,S2)) Q:S2=""  D  Q:$D(DIRUT)
  1.  . . . F  S S3=$O(^TMP("PSOBPSRP",$J,CDIV,S1,S2,S3)) Q:S3=""  D  Q:$D(DIRUT)
  1.  . . . . F  S DFN=$O(^TMP("PSOBPSRP",$J,CDIV,S1,S2,S3,DFN)) Q:DFN=""  D  Q:$D(DIRUT)
  1.  . . . . . F  S PSORXN=$O(^TMP("PSOBPSRP",$J,CDIV,S1,S2,S3,DFN,PSORXN)) Q:PSORXN=""  D  Q:$D(DIRUT)
  1.  . . . . . . F  S RSEQ=$O(^TMP("PSOBPSRP",$J,CDIV,S1,S2,S3,DFN,PSORXN,RSEQ)) Q:RSEQ=""  D  Q:$D(DIRUT)
  1.  . . . . . . . I $Y>(IOSL-7)&($E(IOST)="C") D HDR I $D(DIRUT) Q
  1.  . . . . . . . I $Y>(IOSL-12)&($E(IOST)'="C") D HDR I $D(DIRUT) Q
  1.  . . . . . . . S (RXNUMB,PSORX)="",RXNUMB=$E(PSORXN,1,$L(PSORXN)-1),PSORX=$O(^PSRX("B",RXNUMB,PSORX))
  1.  . . . . . . . D PRINT(DFN,PSORX)
  1.  . . . I '$D(DIRUT),S2'=0,$O(^TMP("PSOBPSRP",$J,CDIV,S1,S2))'="" W SP2
  1.  . . I '$D(DIRUT),$O(^TMP("PSOBPSRP",$J,CDIV,S1))'="" W !,SP1
  1.  G CLOSE:$D(DIRUT)
  1.  ;
  1. NDTP I 'PRTD D HDR W !!?18,"**********   NO DATA TO PRINT   **********"
  1.  I $G(PCNT) D
  1.  . W !,SP1
  1.  . W !,"Total: ",PCNT," patient",$S(PCNT>1:"s",1:"")
  1.  . W " and ",FCNT," prescription fill",$S(FCNT>1:"s",1:""),"."
  1.  ;
  1. CLOSE ;
  1.  D ^%ZISC S:$D(ZTQUEUED) ZTREQ="@"
  1. END K ^TMP("PSOBPSRP",$J),^TMP("PSOBPSRC",$J)
  1.  K PSOAPT,PSODRUG,PSOUSER,PSOU,PSODRG,PSOPT,PSOSRT,PSOED,PSOSD,PSODIV,PSOSIT
  1.  Q
  1.  ;
  1. SET ;
  1.  S (S1,S2,S3)=0
  1.  F I=1:1:$L(PSOSRT,",") D
  1.  . S Y=$P(PSOSRT,",",I)
  1.  . S @("S"_I)=$S(Y=1:PNAM,Y=2:DNAM,Y=3:CBY)
  1.  S ^TMP("PSOBPSRP",$J,CDIV,S1,S2,S3,DFN,RXE,SEQ2)=""
  1.  Q
  1.  ;
  1. PRINT(DFN,RXIEN) ; - Print
  1.  ;Input: DFN-Patient;RXIEN=Prescription IEN
  1.  N X,XX,K,PNAM,PSSN,II,J,STR,CCOM,PMES,CBY,CREAS,CDAT,CFILL,RXNUM,DNAM,CINFO
  1.  S (CDAT,CREAS,CBY,DNAM,PNAM,PMES,PSSN,CCOM,CINFO,RXNUM)=""
  1.  ;
  1.  I OCDIV'=CDIV!(OCDIV="") D HDR I $D(DIRUT) Q
  1.  S OCDIV=CDIV
  1.  ;
  1.  D DEM^VADPT S PSSN=$P($G(VADM(2)),"^",2) K VADM
  1.  K RXINFO D GETS^DIQ(52,RXIEN_",",".01;2;6","EI","RXINFO")
  1.  S PNAM=RXINFO(52,RXIEN_",",2,"E"),DNAM=RXINFO(52,RXIEN_",",6,"E")
  1.  D GETS^DIQ(52.25,RSEQ_","_RXIEN_",","5;10;11;12;2;13","IE","CINFO")
  1.  S:$D(RXINFO(52,RXIEN_",",.01,"E")) RXNUM=RXINFO(52,RXIEN_",",.01,"E")
  1.  S:$D(CINFO(52.25,RSEQ_","_RXIEN_",",10,"I")) CDAT=CINFO(52.25,RSEQ_","_RXIEN_",",10,"I")
  1.  S CDAT=$$DT(CDAT)
  1.  S:$D(CINFO(52.25,RSEQ_","_RXIEN_",",12,"I")) CREAS=CINFO(52.25,RSEQ_","_RXIEN_",",12,"E")
  1.  S:$D(CINFO(52.25,RSEQ_","_RXIEN_",",11,"E")) CBY=CINFO(52.25,RSEQ_","_RXIEN_",",11,"E")
  1.  S:$D(CINFO(52.25,RSEQ_","_RXIEN_",",2,"E")) PMES=CINFO(52.25,RSEQ_","_RXIEN_",",2,"E")
  1.  D TEXT(.PMES,PMES,65)
  1.  S:$D(CINFO(52.25,RSEQ_","_RXIEN_",",13,"E")) CCOM=CINFO(52.25,RSEQ_","_RXIEN_",",13,"E")
  1.  D TEXT(.CCOM,CCOM,65)
  1.  S:$D(CINFO(52.25,RSEQ_","_RXIEN_",",5,"I")) CFILL=CINFO(52.25,RSEQ_","_RXIEN_",",5,"I")
  1.  ;
  1.  W !,RXNUM_"/"_CFILL,?15,$E(DNAM,1,21),?37,$E(PNAM,1,13)_"("_$P(PSSN,"-",3)_")",?57,CDAT,?66,$E(CBY,1,14)
  1.  S II="" F  S II=$O(CCOM(II)) Q:II=""  D
  1.  . W:II=1 !,"     Comments: "
  1.  . W:$D(CCOM(II)) ?15,CCOM(II),!
  1.  S II="" F  S II=$O(PMES(II)) Q:II=""  D
  1.  .  W:II=1 "Payer Message: "
  1.  .  W:$D(PMES(II)) ?15,PMES(II),!
  1.  ;
  1.  S:'$D(^TMP("PSOBPSRC",$J,DFN)) PCNT=PCNT+1 S ^TMP("PSOBPSRC",$J,DFN)=""
  1.  ;
  1.  S PRTD=1,FCNT=FCNT+1
  1.  Q
  1.  ;
  1. TEXT(TEXT,STR,L) ; Formats STR into TEXT array, lines lenght = L
  1.  N J,WORD,K S K=+$O(TEXT(""),-1) S:'K K=1
  1.  F J=1:1:$L(STR," ") D
  1.  . S WORD=$P(STR," ",J) I ($L($G(TEXT(K))_WORD))>L S K=K+1
  1.  . S TEXT(K)=$G(TEXT(K))_WORD_" "
  1.  Q
  1.  ;
  1. HDR ; - Prints the Header
  1.  N X,DIR,CDIVN S PAG=$G(PAG)+1
  1.  S CDIVN=$$GET1^DIQ(59,$G(CDIV)_",",".01")
  1.  I PAG>1,$E(IOST)="C" D  Q:$D(DIRUT)
  1.  . S DIR(0)="E",DIR("A")=" Press ENTER to Continue or ^ to Exit" D ^DIR
  1.  ;
  1.  W @IOF,"Ignored Rejects Report",?71,"Page: ",$J(PAG,3)
  1.  W !,"Sorted by",$$SRT(PSOSRT),?48,"Division: ",CDIVN
  1.  W !,"Date Range: "_$$DT(PSOSD+1\1)_" - "_$$DT(PSOED\1)
  1.  W ?48,"Run Date: "_$$FMTE^XLFDT($$NOW^XLFDT())
  1.  S X="",$P(X,"-",81)="" W !,X
  1.  W !,"RX#/FILL",?15,"DRUG",?37,"PATIENT",?56,"IGNORE DT",?66,"IGNORED BY"
  1.  W !,"--------------",?15,"---------------------",?37,"------------------",?56,"---------",?66,"--------------"
  1.  Q
  1.  ;
  1. SRT(ST) ; - Convert the "2,1" (example) to "DRUG,PATIENT"
  1.  ;Input: ST-String with the Sorting fields by number
  1.  ;Output: ST-String with the Sorting fields by name
  1.  N I,X,STR,FLD
  1.  S STR="PATIENT^DRUG^USER"
  1.  F I=1:1:$L(ST,",") D
  1.  . S FLD=+$P(ST,",",I),X=$P(STR,"^",FLD)
  1.  . S $P(ST,",",I)=" "_X
  1.  Q ST
  1.  ;
  1. DT(DT) ; - Convert FM Date to MM/DD/YYYY
  1.  I 'DT Q ""
  1.  I '(DT#10000) Q (1700+$E(DT,1,3))
  1.  I '(DT#100) Q $E(DT,4,5)_"/"_(1700+$E(DT,1,3))
  1.  Q $E(DT,4,5)_"/"_$E(DT,6,7)_"/"_$E((1700+$E(DT,1,3)),3,4)
  1.  ;