Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSOCIDC2

PSOCIDC2.m

Go to the documentation of this file. 
  1. PSOCIDC2 ;BIR/LE-continuation of Copay Correction of erroneous billed copays ;11/8/05 12:50pm
  1.  ;;7.0;OUTPATIENT PHARMACY;**226,225**;DEC 1997;Build 29
  1.  ;External reference to ^XUSEC supported by DBIA 10076
  1.  ;External reference to IBARX supported by DBIA 125
  1.  ;External reference to $$PROD^XUPROD(1) supported by DBIA 4440
  1.  ;
  1. TOTAL ;
  1.  N COUNT,COUNTED,UCOUNT,UCOUNTED,CCOUNT,CCOUNTED
  1.  I '$D(PSOVETS) S PSOVETS=0
  1.  N I,J
  1.  F I=1:1:3 S (PSOCNT("YR2004",I),PSOCNT("YR2005",I),PSOCNT("YR2006",I))=0
  1.  S PSODFN=0 F  S PSODFN=$O(^XTMP(NAMSP,"TOT REL",PSODFN)) Q:'PSODFN  D
  1.  .S COUNTED=0
  1.  .F J="YR2004","YR2005","YR2006" F I=1:1:3 S COUNT=$G(^XTMP(NAMSP,"TOT REL",PSODFN,J,I)) I COUNT>0 S:'$G(COUNTED) COUNTED=1,PSOVETS=PSOVETS+1 S PSOCNT(J,I)=PSOCNT(J,I)+COUNT
  1.  F I=1:1:3 S PSOCNT=PSOCNT+$G(PSOCNT("YR2004",I))+$G(PSOCNT("YR2005",I))+$G(PSOCNT("YR2006",I))
  1.  ;
  1.  S (I,J)=-""
  1.  I '$D(PSOCVETS) S PSOCVETS=0
  1.  F I=1:1:3 S (PSOCCNT("YR2004",I),PSOCCNT("YR2005",I),PSOCCNT("YR2006",I))=0
  1.  S PSODFN=0 F  S PSODFN=$O(^XTMP(NAMSP,"TOT CAN",PSODFN)) Q:'PSODFN  D
  1.  .S CCOUNTED=0
  1.  .F J="YR2004","YR2005","YR2006" F I=1:1:3 S CCOUNT=$G(^XTMP(NAMSP,"TOT CAN",PSODFN,J,I)) I CCOUNT>0 S:'$G(CCOUNTED) CCOUNTED=1,PSOCVETS=PSOCVETS+1 S PSOCCNT(J,I)=PSOCCNT(J,I)+CCOUNT
  1.  F I=1:1:3 S PSOCCNT=PSOCCNT+$G(PSOCCNT("YR2004",I))+$G(PSOCCNT("YR2005",I))+$G(PSOCCNT("YR2006",I))
  1.  ;
  1.  S (I,J)=""
  1.  I '$D(PSOUVETS) S PSOUVETS=0
  1.  F I=1:1:3 S (PSOUCNT("YR2004",I),PSOUCNT("YR2005",I),PSOUCNT("YR2006",I))=0
  1.  S PSOUDFN=0 F  S PSOUDFN=$O(^XTMP(NAMSP,"TOT UNREL",PSOUDFN)) Q:'PSOUDFN  D
  1.  .S UCOUNTED=0
  1.  .F J="YR2004","YR2005","YR2006" F I=1:1:3 S UCOUNT=$G(^XTMP(NAMSP,"TOT UNREL",PSOUDFN,J,I)) I UCOUNT>0 S:'$G(UCOUNTED) UCOUNTED=1,PSOUVETS=PSOUVETS+1 S PSOUCNT(J,I)=PSOUCNT(J,I)+UCOUNT
  1.  F I=1:1:3 S PSOUCNT=PSOUCNT+$G(PSOUCNT("YR2004",I))+$G(PSOUCNT("YR2005",I))+$G(PSOUCNT("YR2006",I))
  1.  ;
  1.  Q
  1.  ;
  1. CHECK ;check for ICD and IB nodes
  1.  ;
  1.  N PSOREF,PSOIB,PSOOICD,PSOBILLD
  1.  S PSOREF=YY
  1.  S PSOOICD=$P($G(^PSRX(RXP,"ICD",1,0)),"^",2,8)
  1.  ; see if bill already exists
  1.  I PSOREF=0 D
  1.  . I +$P($G(^PSRX(RXP,"IB")),"^",2)>0 D CHKIB^PSOCP1
  1.  . S PSOREL=$P($G(^PSRX(RXP,2)),"^",13)
  1.  I PSOREF>0 D
  1.  . I +$G(^PSRX(RXP,1,PSOREF,"IB")) D CHKIB^PSOCP1
  1.  . S PSOREL=$P($G(^PSRX(RXP,1,YY,0)),"^",18)
  1.  I $G(PSOIB)=1!($G(PSOIB)=3) S PSOBILLD=1
  1.  ;    if billed/RELEASED and no IBQ node for both sc<50 and nsc
  1.  I $G(PSOBILLD)&('$D(^PSRX(RXP,"IBQ"))) D
  1.  . I $TR(PSOOICD,"^")[1  S ^XTMP(NAMSP,"CANCEL",PSODFN,RXP,YY)=$P(PSOREL,".")_"^"_PSODT_"^"_PSOSCP
  1.  . I $TR(PSOOICD,"^")[0 S ^XTMP(NAMSP,"NOIBQ",PSODFN,RXP,YY)=$P(PSOREL,".")_"^"_PSODT_"^"_PSOSCP
  1.  ;           find unbilled ones with an ICD node and no IBQ node.
  1.  I '$G(PSOBILLD)&('$D(^PSRX(RXP,"IBQ"))) D
  1.  . Q:$TR(PSOOICD,"^")=""
  1.  . S ^XTMP(NAMSP,"NOIBQ",PSODFN,RXP,YY)=$P(PSOREL,".")_"^"_PSODT_"^"_PSOSCP
  1.  I YY S PSOTRF=PSOTRF+1
  1.  Q
  1.  ;
  1. CANCEL ;Cancel erroneous copays/set IBQ node if not there
  1.  ;released rx's
  1.  N PSOCAP,PSODIV,PSODV,PSOFILL,PSOLOG,PSONAM,PSOOUT,PSOPAR,PSOPAR7,PSOSITE
  1.  N PSOSITE7,PSOSQ,PSOTOT,PSOYEAR,PSOYR,SSN,SAVCPUN,SAVREF,PSOIB,PSOOIBQ,PSONIBQ,PSOOICD,PSOOIB
  1.  N I,IFN,PSOANSQ,PSOTYP,COM,CC,PREA,PSONW,PSOOLD,PSOREL,PSO,PSOCPUN,PSOFLD,PSOTYPE,CANCEL
  1.  S PSOTYPE="CAN"
  1.  S PSODFN=0 F CC=1:1 S PSODFN=$O(^XTMP(NAMSP,"CANCEL",PSODFN)) Q:'PSODFN  D  Q:STOP
  1.  .I CC#100=0,$D(^XTMP(NAMSP,0,"STOP")) D  Q
  1.  .. S $P(^XTMP(NAMSP,0,"LAST"),"^",1,2)="STOP^"_$$NOW^XLFDT,STOP=1
  1.  .S (PSOCAP(304),PSOCAP(305),PSOCAP(306))=0 ; INITIAL ANNUAL CAP FOR 2004 & 2005
  1.  .F RXP=0:0 S RXP=$O(^XTMP(NAMSP,"CANCEL",PSODFN,RXP)) Q:'RXP  D
  1.  ..S (SAVCPUN,PSOCPUN)=($P(^PSRX(RXP,0),"^",8)+29)\30
  1.  ..S YY="" F  S YY=$O(^XTMP(NAMSP,"CANCEL",PSODFN,RXP,YY)) Q:YY=""  D
  1.  ...S (SAVREF,PSOREF)=YY
  1.  ...;  verify again that it was billed and not already cancelled
  1.  ...S PSOBILLD=0
  1.  ...I YY=0,+$P($G(^PSRX(RXP,"IB")),"^",2)>0 D CHKIB^PSOCP1 I $G(PSOIB)=1!($G(PSOIB)=3) S PSOBILLD=1
  1.  ...I YY>0,+$P($G(^PSRX(RXP,1,PSOREF,"IB")),"^")>0 D CHKIB^PSOCP1 I $G(PSOIB)=1!($G(PSOIB)=3) S PSOBILLD=1
  1.  ...Q:'PSOBILLD
  1.  ...S PSOREL=$P($G(^XTMP(NAMSP,"CANCEL",PSODFN,RXP,YY)),"^"),PSOFLD=$P($G(^XTMP(NAMSP,"CANCEL",PSODFN,RXP,YY)),"^",2),PSOSCP=$P($G(^XTMP(NAMSP,"CANCEL",PSODFN,RXP,YY)),"^",3)
  1.  ...S PSO=3 D NOW^%DTC S PSODT=%,PSODA=RXP,PSOCOMM="-BKGD CIDC COPAY CANCEL",PSOOLD="",PSONW="",PREA=""
  1.  ...D CHKACT
  1.  ...S PSOIB="",PSOIB=$S(PSOREF>0:$G(^PSRX(RXP,1,YY,"IB")),'PSOREF:$G(^PSRX(PSODA,"IB")),1:"")
  1.  ...S (PSOOIBQ,PSOOICD,PSOOIB)=""
  1.  ...S PSOOICD=$P($G(^PSRX(RXP,"ICD",1,0)),"^",2,8),PSOOIB=$G(^PSRX(RXP,"IB")),PSOOIBQ=$G(^PSRX(RXP,"IBQ"))
  1.  ...I PSOOIBQ=""&($TR(PSOOICD,"^")[0!($TR(PSOOICD,"^")[1)) D SETIBQ
  1.  ...D SITE S PSOCOMM="-BKGD CIDC COPAY CANCEL" D RXED^PSOCPA S:PSOOICD[1&($D(^PSRX(RXP,"IB"))) $P(^PSRX(RXP,"IB"),"^")=""
  1.  ...S PSOCPUN=SAVCPUN,PSOREF=SAVREF
  1.  ...D ACCUM
  1.  ;
  1.  ;ICD NODES WITHOUT IBQ NODE; set IBQ node but only set 1st piece of IB node if unreleased.
  1.  S PSOTYP="IBQ"
  1.  S PSODFN=0 F CC=1:1 S PSODFN=$O(^XTMP(NAMSP,"NOIBQ",PSODFN)) Q:'PSODFN  D  Q:STOP
  1.  .I CC#100=0,$D(^XTMP(NAMSP,0,"STOP")) D  Q
  1.  .. S $P(^XTMP(NAMSP,0,"LAST"),"^",1,2)="STOP^"_$$NOW^XLFDT,STOP=1
  1.  .S (PSOCAP(304),PSOCAP(305),PSOCAP(306))=0 ; INITIAL ANNUAL CAP FOR 2004 & 2005
  1.  .F RXP=0:0 S RXP=$O(^XTMP(NAMSP,"NOIBQ",PSODFN,RXP)) Q:'RXP  D
  1.  ..S (SAVCPUN,PSOCPUN)=($P(^PSRX(RXP,0),"^",8)+29)\30
  1.  ..S YY="" F  S YY=$O(^XTMP(NAMSP,"NOIBQ",PSODFN,RXP,YY)) Q:YY=""  D
  1.  ...S (SAVREF,PSOREF)=YY
  1.  ...D SITE
  1.  ...S PSOREL=$P($G(^XTMP(NAMSP,"NOIBQ",PSODFN,RXP,YY)),"^"),PSOFLD=$P($G(^XTMP(NAMSP,"NOIBQ",PSODFN,RXP,YY)),"^",2),PSOSCP=$P($G(^XTMP(NAMSP,"NOIBQ",PSODFN,RXP,YY)),"^",3)
  1.  ...S (PSOOIBQ,PSOOICD,PSOOIB)=""
  1.  ...S PSOOICD=$P($G(^PSRX(RXP,"ICD",1,0)),"^",2,8),PSOOIB=$G(^PSRX(RXP,"IB")),PSOOIBQ=$G(^PSRX(RXP,"IBQ"))
  1.  ...I PSOOIBQ=""&($TR(PSOOICD,"^")[0!($TR(PSOOICD,"^")[1)) D SETIBQ D   ;don't want to set again if already did it as part of copay cancel
  1.  ....S I="",IFN=0 F I=0:0 S I=$O(^PSRX(RXP,"A",I)) Q:'I  S IFN=I
  1.  ....S COM=" BKGD CIDC UPDATE"
  1.  ....D NOW^%DTC S IFN=IFN+1,^PSRX(RXP,"A",0)="^52.3DA^"_IFN_"^"_IFN,^PSRX(RXP,"A",IFN,0)=%_"^I^.5^"_YY_"^"_COM
  1.  ....K DA
  1.  ....S:PSOOICD[1&($D(^PSRX(RXP,"IB"))) $P(^PSRX(RXP,"IB"),"^")=""
  1.  ...D:'$G(^XTMP(NAMSP,"CANCEL",PSODFN,RXP,YY)) ACCUM
  1.  ...S PSOCPUN=SAVCPUN,PSOREF=SAVREF
  1.  Q
  1.  ;
  1. CHKACT ;check activity log for prev entry
  1.  N ZACT,ZPSI,ZACTI
  1.  S ZPSI=0 F  S ZPSI=$O(^PSRX(PSODA,"COPAY",ZPSI)) Q:ZPSI=""  S ZACTI="",ZACTI=$G(^PSRX(PSODA,"COPAY",ZPSI,0)) D  Q:$G(ZACT)
  1.  . I ZACTI["BKGD CIDC COPAY CANCEL"&($P(ZACTI,"^",2)="R") S PSOOLD="",PSONW="",PREA="C",ZACT=1 Q
  1.  I '$G(ZACT) S PSOOLD="Copay",PSONW="No Copay",PREA="R" K PSOREF D ACTLOG^PSOCPA S PSOREF=YY,PSOOLD="",PSONW="",PREA="C"
  1.  Q
  1.  ;
  1. SETIBQ ; get data from IBQ node, set IBQ node, and 1st piece of IB node
  1.  K PSOANSQ
  1.  N PSONIBQ
  1.  F PSOTYP=1:1:8 D
  1.  . I PSOTYP=1 S PSOANSQ("VEH")=$P(PSOOICD,"^",PSOTYP)
  1.  . I PSOTYP=2 S PSOANSQ("RAD")=$P(PSOOICD,"^",PSOTYP)
  1.  . I PSOTYP=3 S PSOANSQ("SC")=$P(PSOOICD,"^",PSOTYP)
  1.  . I PSOTYP=4 S PSOANSQ("PGW")=$P(PSOOICD,"^",PSOTYP)
  1.  . I PSOTYP=5 S PSOANSQ("MST")=$P(PSOOICD,"^",PSOTYP)
  1.  . I PSOTYP=6 S PSOANSQ("HNC")=$P(PSOOICD,"^",PSOTYP)
  1.  . I PSOTYP=7 S PSOANSQ("CV")=$P(PSOOICD,"^",PSOTYP)
  1.  . I PSOTYP=8 S PSOANSQ("SHAD")=$P(PSOOICD,"^",PSOTYP)
  1.  S ^PSRX(RXP,"IBQ")=PSOANSQ("SC")_"^"_PSOANSQ("MST")_"^"_PSOANSQ("VEH")_"^"_PSOANSQ("RAD")_"^"_PSOANSQ("PGW")_"^"_PSOANSQ("HNC")_"^"_PSOANSQ("CV")_"^"_PSOANSQ("SHAD")
  1.  Q
  1.  ;
  1. ACCUM ; ACCUMULATE TOTALS
  1.  S (PSOTOT,PSOYR,PSOYEAR,PSOLOG,PSONAM,PSOCHRG)=""
  1.  ; get finished, but unreleased totals
  1.  I PSOREL="" S PSOYR=$E(PSOFLD,1,3) Q:PSOYR=""  D  S PSOYEAR="" Q
  1.  .S PSOYEAR=$S(PSOYR="304":"YR2004",PSOYR="305":"YR2005",PSOYR="306":"YR2006",1:"") Q:PSOYEAR=""
  1.  .S PSOCHRG=7
  1.  .I PSOYEAR="YR2006" S PSOCHRG=8
  1.  .S PSOTOT=$G(^XTMP(NAMSP,"TOT UNREL",PSODFN,PSOYEAR))
  1.  .S ^XTMP(NAMSP,"TOT UNREL",PSODFN,PSOYEAR)=PSOTOT+(PSOCPUN*PSOCHRG)
  1.  .S ^XTMP(NAMSP,"TOT UNREL",PSODFN,PSOYEAR,PSOCPUN)=$G(^XTMP(NAMSP,"TOT UNREL",PSODFN,PSOYEAR,PSOCPUN))+1
  1.  .S PSONAM=$P($G(^DPT(PSODFN,0)),"^"),PSONAM=$P(PSONAM,",")
  1.  .S PSONAM=$E(PSONAM,1,6)
  1.  .S ^XTMP(NAMSP,"IBQ UPD",PSONAM,PSODFN,RXP,PSOREF)=PSOFLD
  1.  ;for released ones
  1.  S PSOYR=$E(PSOREL,1,3)
  1.  S:PSOYR'="" PSOYEAR=$S(PSOYR="304":"YR2004",PSOYR="305":"YR2005",PSOYR="306":"YR2006",1:"")
  1.  Q:PSOYEAR=""
  1.  S PSOCHRG=7
  1.  I PSOYEAR="YR2006" S PSOCHRG=8
  1.  ;
  1.  ;get Xtmp billing amt which would be IBAM tot + any previous refills
  1.  S PSOTOT=$G(^XTMP(NAMSP,"TOT REL",PSODFN,PSOYEAR))
  1.  ;
  1.  ;if none yet then init to the IBAM total for the year
  1.  I 'PSOTOT D
  1.  .F PSOSQ=0:0 S PSOSQ=$O(^IBAM(354.7,PSODFN,1,PSOSQ)) Q:'PSOSQ  D
  1.  ..S PSOLOG=$G(^IBAM(354.7,PSODFN,1,PSOSQ,0))
  1.  ..I $E(PSOLOG,1,3)=PSOYR S PSOTOT=PSOTOT+$P(PSOLOG,"^",2)
  1.  ;
  1.  ;update Xtmp tot nodes with current fill amounts
  1.  ;  note:  cancel copays and updated IBQ node released prescription are collected under TOT REL for the RPT^PSOCIDC3
  1.  ;             routine.  Cancelled copays are denoted with an asterisk.
  1.  S ^XTMP(NAMSP,"TOT REL",PSODFN,PSOYEAR)=PSOTOT+(PSOCPUN*PSOCHRG)
  1.  S ^XTMP(NAMSP,"TOT REL",PSODFN,PSOYEAR,PSOCPUN)=$G(^XTMP(NAMSP,"TOT REL",PSODFN,PSOYEAR,PSOCPUN))+1
  1.  ;
  1.  ;indicate COPAY CANCEL for this fill 
  1.  ;       ;by adding to Xtmp "BILLED"
  1.  S PSONAM=$P($G(^DPT(PSODFN,0)),"^"),PSONAM=$P(PSONAM,",")
  1.  S PSONAM=$E(PSONAM,1,6)
  1.  S ^XTMP(NAMSP,"REL",PSONAM,PSODFN,RXP,PSOREF)=PSOREL
  1.  ;
  1. CAN I PSOTYPE="CAN"&($G(^XTMP(NAMSP,"CANCEL",PSODFN,RXP,YY))) N PSOFILL S CANCEL="" S PSOFILL=YY D CHK^PSOCIDC3 I CANCEL D
  1.  . S ^XTMP(NAMSP,"TOT CAN",PSODFN,PSOYEAR)=PSOTOT+(PSOCPUN*PSOCHRG)
  1.  . S ^XTMP(NAMSP,"TOT CAN",PSODFN,PSOYEAR,PSOCPUN)=$G(^XTMP(NAMSP,"TOT CAN",PSODFN,PSOYEAR,PSOCPUN))+1
  1.  Q
  1.  ;
  1. SITE ; SET UP VARIABLES NEEDED BY BILLING
  1.  S PSOSITE=$S(YY=0:$P(^PSRX(RXP,2),"^",9),1:$P($G(^PSRX(RXP,1,YY,0)),"^",9))
  1.  Q:PSOSITE=""
  1.  S PSOPAR=$G(^PS(59,PSOSITE,1))
  1.  S PSOPAR7=$G(^PS(59,PSOSITE,"IB"))
  1.  S PSOSITE7=$P($G(^PS(59,PSOSITE,"IB")),"^")
  1.  Q
  1.  ;