Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSS51P1

PSS51P1.m

Go to the documentation of this file. 
  1. PSS51P1 ;BIR/LDT - API FOR INFORMATION FROM FILE 51.1 ;5 Sep 03
  1.  ;;1.0;PHARMACY DATA MANAGEMENT;**85,91,108,118,94**;9/30/97;Build 26
  1.  ;
  1. ZERO(PSSIEN,PSSFT,PSSPP,PSSTSCH,LIST) ;
  1.  ;PSSIEN - IEN of entry in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;PSSFT - Free Text name in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;PSSPP - PACKAGE PREFIX field (#4) in ADMINISTRATION SCHEDULE file (#51.1). Screens for Administration
  1.  ;Schedules for the Package Prefix passed.
  1.  ;PSSTSCH - TYPE OF SCHEDULE field (#5) of ADMINISTRATION SCHEDULE file (#51.1). Screens for
  1.  ;          One-time "O" if PSSTSCH passed in.
  1.  ;LIST - Subscript of ^TMP array in the form ^TMP($J,LIST,Field Number where Field Number is the
  1.  ;       Field Number of the data piece being returned.
  1.  ;Returns NAME field (#.01), STANDARD ADMINISTRATION TIMES field (#1), FREQUENCY (IN MINUTES) field (#2),
  1.  ;MAXIMUM DAYS FOR ORDERS field (#2.5), PACKAGE PREFIX field (#4), TYPE OF SCHEDULE field (#5),
  1.  ;STANDARD SHIFTS field (#6), OUTPATIENT EXPANSION field (#8), and OTHER LANGUAGE EXPANSIONS field (#8.1)
  1.  ;of ADMINISTRATION SCHEDULE file (#51.1).
  1.  N DIERR,ZZERR,PSS51P1,SCR,PSS
  1.  I $G(LIST)']"" Q
  1.  K ^TMP($J,LIST)
  1.  I +$G(PSSIEN)'>0,($G(PSSFT)']"") S ^TMP($J,LIST,0)=-1_"^"_"NO DATA FOUND" Q
  1.  I $G(PSSIEN)]"",+$G(PSSIEN)'>0 S ^TMP($J,LIST,0)=-1_"^"_"NO DATA FOUND" Q
  1.  I $G(PSSTSCH)]"",PSSTSCH'="O" S PSSTSCH=""
  1.  S SCR("S")="" I $G(PSSTSCH)]""!$G(PSSPP)]"" D SETSCR
  1.  I +$G(PSSIEN)>0 N PSSIEN2 S PSSIEN2=$$FIND1^DIC(51.1,"","A","`"_PSSIEN,"B",SCR("S"),"") D
  1.  .I +PSSIEN2'>0 S ^TMP($J,LIST,0)=-1_"^"_"NO DATA FOUND" Q
  1.  .S ^TMP($J,LIST,0)=1
  1.  .D GETS^DIQ(51.1,+PSSIEN2,".01;1;2;4;5;6;2.5;8;8.1","IE","PSS51P1") S PSS(1)=0
  1.  .F  S PSS(1)=$O(PSS51P1(51.1,PSS(1))) Q:'PSS(1)  D SETZRO^PSS51P1B
  1.  I +$G(PSSIEN)'>0,$G(PSSFT)]"" D
  1.  .I PSSFT["??" D LOOP^PSS51P1B(1) Q
  1.  .D FIND^DIC(51.1,,"@;.01;1","QP",PSSFT,,"B",SCR("S"),,"")
  1.  .I +$G(^TMP("DILIST",$J,0))=0 S ^TMP($J,LIST,0)=-1_"^"_"NO DATA FOUND" Q
  1.  .I +^TMP("DILIST",$J,0)>0 S ^TMP($J,LIST,0)=+^TMP("DILIST",$J,0) N PSSXX S PSSXX=0 F  S PSSXX=$O(^TMP("DILIST",$J,PSSXX)) Q:'PSSXX  D
  1.  ..S PSSIEN=+^TMP("DILIST",$J,PSSXX,0) K PSS51P1 D GETS^DIQ(51.1,+PSSIEN,".01;1;2;4;5;6;2.5;8;8.1","IE","PSS51P1") S PSS(1)=0
  1.  ..F  S PSS(1)=$O(PSS51P1(51.1,PSS(1))) Q:'PSS(1)  D SETZRO^PSS51P1B
  1.  K ^TMP("DILIST",$J)
  1.  Q
  1.  ;
  1. WARD(PSSIEN,PSSFT,PSSIEN2,LIST) ;
  1.  ;PSSIEN - IEN of entry in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;PSSFT - Free Text name in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;PSSIEN2 - IEN of entry in WARD sub-file (#51.11)
  1.  ;LIST - Subscript of ^TMP array in the form ^TMP($J,LIST,Field Number where Field Number is the
  1.  ;       Field Number of the data piece being returned.
  1.  ;Returns NAME field (#.01), WARD multiple (#51.11) WARD field (#.01), and WARD ADMINISTRATION TIMES field (#1)
  1.  ;of ADMINISTRATION SCHEDULE file (#51.1).
  1.  N DIERR,ZZERR,PSS51P1,PSS,CNT
  1.  S CNT=0
  1.  I $G(LIST)']"" Q
  1.  K ^TMP($J,LIST)
  1.  I +$G(PSSIEN)'>0,($G(PSSFT)']"") S ^TMP($J,LIST,0)=-1_"^"_"NO DATA FOUND" Q
  1.  I $G(PSSIEN)]"",+$G(PSSIEN)'>0 S ^TMP($J,LIST,0)=-1_"^"_"NO DATA FOUND" Q
  1.  I $G(PSSIEN2)]"",+$G(PSSIEN2)'>0 S ^TMP($J,LIST,0)=-1_"^"_"NO DATA FOUND" Q
  1.  D WARD^PSS51P1C
  1.  Q
  1.  ;
  1. HOSP(PSSIEN,PSSFT,LIST) ;
  1.  ;PSSIEN - IEN of entry in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;PSSFT - Free Text name in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;LIST - Subscript of ^TMP array in the form ^TMP($J,LIST,Field Number where Field Number is the
  1.  ;       Field Number of the data piece being returned.
  1.  ;Returns NAME field (#.01), HOSPITAL LOCATION multiple (#51.17) HOSPITAL LOCATION field (#.01), ADMINISTRATION TIMES field (#1),
  1.  ;and SHIFTS field (#2) of ADMINISTRATION SCHEDULE file (#51.1).
  1.  N DIERR,ZZERR,PSS51P1,SCR,PSS,CNT
  1.  I $G(LIST)']"" Q
  1.  D HOSP^PSS51P1A
  1.  Q
  1.  ;
  1. IEN(PSSFT,LIST) ;
  1.  ;PSSFT - Free Text name in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;LIST - Subscript of ^TMP array in the form ^TMP($J,LIST,Field Number where Field Number is the
  1.  ;       Field Number of the data piece being returned.
  1.  ;Returns NAME field (#.01) and STANDARD ADMINISTRATION TIMES field (#1) of ADMINISTRATION SCHEDULE file (#51.1).
  1.  N DIERR,ZZERR,PSS51P1,SCR,PSS
  1.  I $G(LIST)']"" Q
  1.  K ^TMP($J,LIST)
  1.  I $G(PSSFT)']"" S ^TMP($J,LIST,0)=-1_"^"_"NO DATA FOUND" Q
  1.  D IEN^PSS51P1A
  1.  Q
  1.  ;
  1. AP(PSSPP,PSSFT,PSSWDIEN,PSSTYP,LIST,PSSFREQ) ;
  1.  ;PSSPP - PACKAGE PREFIX in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;PSSFT - Free Text name in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;PSSWDIEN - IEN of entry of WARD multiple in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;PSSSTYP - TYPE OF SCHEDULE field (#5) in ADMINISTRATION SCHEDULE file (#51.1). 
  1.  ;LIST - Subscript of ^TMP array in the form ^TMP($J,LIST,Field Number where Field Number is the
  1.  ;       Field Number of the data piece being returned.
  1.  ;Returns NAME field (#.01), STANDARD ADMINISTRATION TIMES field (#1), and PACKAGE PREFIX field (#4)
  1.  ;of ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;If PSSWDIEN is passed in then the WARD multiple (#51.11) WARD field (#.01), and WARD ADMINISTRATION TIMES field (#1)
  1.  ;of ADMINISTRATION SCHEDULE file (#51.1) is returned.
  1.  N DIERR,ZZERR,PSS51P1,SCR,PSS,PSSIEN,PSSVAL,PSSTMP
  1.  I $G(PSSFREQ)']"" S PSSFREQ=""
  1.  I $G(LIST)']"" Q
  1.  D AP^PSS51P1A
  1.  Q
  1.  ;
  1. IX(PSSFT,PSSPP,LIST) ;
  1.  ;PSSFT - Free Text name in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;PSSPP - PACKAGE PREFIX in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;LIST - Subscript of ^TMP array in the form ^TMP($J,LIST,Field Number where Field Number is the
  1.  ;       Field Number of the data piece being returned.
  1.  ;Returns NAME field (#.01), STANDARD ADMINISTRATION TIMES field (#1), FREQUENCY (IN MINUTES) field (#2),
  1.  ;MAXIMUM DAYS FOR ORDERS field (#2.5),PACKAGE PREFIX field (#4), TYPE OF SCHEDULE field (#5), STANDARD
  1.  ;SHIFTS field (#6), OUTPATIENT EXPANSION field (#8), and OTHER LANGUAGE EXPANSION field (#8.1) of
  1.  ;ADMINISTRATION SCHEDULE file (#51.1).
  1.  N DIERR,ZZERR,PSS51P1,PSS
  1.  I $G(LIST)']"" Q
  1.  D IX^PSS51P1A
  1.  Q
  1.  ;
  1. ADM(PSSADM) ; admin times
  1.  N X S X=PSSADM
  1.  I $S($L($P(X,"-"))>4:1,$L(X)>119:1,$L(X)<2:1,X'>0:1,1:X'?.ANP) K X Q "^"
  1.  S X(1)=$P(X,"-") I X(1)'?2N,X(1)'?4N K X Q "^"
  1.  S X(1)=$L(X(1)) F X(2)=2:1:$L(X,"-") S X(3)=$P(X,"-",X(2)) I $S($L(X(3))'=X(1):1,X(3)>$S(X(1)=2:24,1:2400):1,1:X(3)'>$P(X,"-",X(2)-1)) K X Q
  1.  I '$D(X) Q "^"
  1.  K:$D(X) X(1),X(2),X(3) Q PSSADM
  1.  ;
  1. ALL(PSSIEN,PSSFT,LIST) ;
  1.  ;PSSIEN - IEN of entry in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;PSSFT - Free Text name in ADMINISTRATION SCHEDULE file (#51.1).
  1.  ;LIST - Subscript of ^TMP array in the form ^TMP($J,LIST,Field Number where Field Number is the
  1.  ;       Field Number of the data piece being returned.
  1.  ;Returns NAME field (#.01), STANDARD ADMINISTRATION TIMES field (#1), FREQUENCY (IN MINUTES) field (#2),
  1.  ;MAXIMUM DAYS FOR ORDERS field (#2.5), PACKAGE PREFIX field (#4), TYPE OF SCHEDULE field (#5),
  1.  ;STANDARD SHIFTS field (#6), OUTPATIENT EXPANSION field (#8), OTHER LANGUAGE EXPANSIONS field (#8.1),
  1.  ; HOSPITAL LOCATION multiple (#51.17) HOSPITAL LOCATION field (#.01), ADMINISTRATION TIMES field (#1),
  1.  ;SHIFTS field (#2), WARD multiple (#51.11) WARD field (#.01), and WARD ADMINISTRATION TIMES field (#1)
  1.  ;of ADMINISTRATION SCHEDULE file (#51.1).
  1.  N DIERR,ZZERR,PSS
  1.  I $G(LIST)']"" Q
  1.  K ^TMP($J,LIST)
  1.  I +$G(PSSIEN)'>0,($G(PSSFT)']"") S ^TMP($J,LIST,0)=-1_"^"_"NO DATA FOUND" Q
  1.  I $G(PSSIEN)]"",+$G(PSSIEN)'>0 S ^TMP($J,LIST,0)=-1_"^"_"NO DATA FOUND" Q
  1.  D ALL^PSS51P1C
  1.  Q
  1.  ;
  1. SETSCR ;Set Screen for One-time schedule type
  1.  ;Naked reference below refers to ^PS(51.1,+Y,0)
  1.  I $G(PSSTSCH)]"" S SCR("S")="I $P(^(0),""^"",5)=""O"""
  1.  ;Naked reference below refers to ^PS(51.1,+Y,0)
  1.  I $G(PSSPP)]"" S SCR("S")=$S(SCR("S")]"":SCR("S")_" I $P(^(0),""^"",4)=PSSPP",1:"I $P(^(0),""^"",4)=PSSPP")
  1.  Q
  1. FREQ(PSSVAL,PSSFREQ) ; VALIDATES FREQUNCY FIELD
  1.  S PSSTMP=0
  1.  I PSSVAL>PSSFREQ S PSSTMP=1
  1.  I PSSVAL<1 S PSSTMP=1
  1.  I PSSFREQ="" S PSSTMP=0
  1.  Q PSSTMP
  1. PSSDQ ;DQ^DICQ call on 51.1
  1.  N DIC,D,DZ S DIC="^PS(51.1,",D="B",DIC(0)="EQS",DZ="??" D DQ^DICQ Q
  1.  ;
  1. SCHED(PSSWIEN,PSSARRY) ;
  1.  I $G(PSSWIEN)="" S PSSWIEN=0
  1.  D SCHED^PSSSCHED(PSSWIEN,.PSSARRY) Q