Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PXCEAE1

PXCEAE1.m

Go to the documentation of this file. 
  1. PXCEAE1 ;ISL/dee,ISA/KWP - Builds the List Manager display of a visit and related v-files ;6/20/96
  1.  ;;1.0;PCE PATIENT CARE ENCOUNTER;**22,73**;Aug 12, 1996
  1.  ;; ;
  1.  Q
  1.  ;
  1. BUILD(VISITIEN,AEVIEW,ARRAY,ARRAYIX) ;
  1.  ;AEVIEW is "B" for brief display and "D" for expanded display.
  1.  I '$D(^AUPNVSIT(VISITIEN)) S VALMBCK="Q" Q
  1.  N PXCECNT
  1.  D FULL^VALM1
  1.  D CLEAN^VALM10
  1.  K @ARRAYIX
  1.  S (VALMCNT,PXCECNT)=0
  1.  ;
  1.  ;
  1.  N IEN,FILE,VFILE,VROUTINE
  1.  F FILE="SIT","CSTP","PRV","POV","CPT","TRT","IMM","PED","SK","HF","XAM" D
  1.  . S VROUTINE="PXCE"_$S(FILE="IMM":"VIMM",1:FILE)
  1.  . S VFILE=$P($T(FORMAT^@VROUTINE),"~",5)
  1.  . I FILE="SIT" D
  1.  .. S IEN=VISITIEN
  1.  .. D AFILE(IEN,FILE,VFILE,VROUTINE,ARRAY,ARRAYIX,.VALMCNT,.PXCECNT,AEVIEW)
  1.  .. S VALMCNT=VALMCNT+1
  1.  .. S @ARRAY@(VALMCNT,0)=""
  1.  . E  D
  1.  .. S IEN=""
  1.  .. F  S IEN=$O(@VFILE@("AD",VISITIEN,IEN)) Q:'IEN  D AFILE(IEN,FILE,VFILE,VROUTINE,ARRAY,ARRAYIX,.VALMCNT,.PXCECNT,AEVIEW)
  1.  S @ARRAYIX@(0)=PXCECNT
  1.  I VALMCNT=0 S VALMBCK="Q"
  1.  Q
  1.  ;
  1. AFILE(IEN,FILE,VFILE,VROUTINE,ARRAY,ARRAYIX,VALMCNT,PXCECNT,AEVIEW) ;
  1.  N ENTRY,NODE,NODES,NODECNT
  1.  S PXCECNT=PXCECNT+1
  1.  S NODES=$P($T(FORMAT^@VROUTINE),"~",3)
  1.  F NODECNT=1:1 S NODE=$P(NODES,",",NODECNT) Q:NODE']""  S ENTRY(NODE)=$G(@VFILE@(IEN,NODE))
  1.  D DISPLAY(.ENTRY,VROUTINE,ARRAY,ARRAYIX,.VALMCNT,PXCECNT,AEVIEW)
  1.  I FILE="SIT" S @ARRAYIX@(PXCECNT)=VISITIEN_"^VST"
  1.  E  S @ARRAYIX@(PXCECNT)=IEN_"^"_FILE
  1.  Q
  1.  ;
  1. DISPLAY(ENTRY,PXCECODE,ARRAY,ARRAYIX,LINE,COUNT,VIEW) ; -- display the data
  1.  N PXCEFILE,PXCELINE,PXCETEXT,PXCEINT,PXCEEXT
  1.  S PXCEFILE=$P($T(FORMAT^@PXCECODE),"~",2)
  1.  F PXCELINE=1:1 S PXCETEXT=$P($T(FORMAT+PXCELINE^@PXCECODE),";;",2) Q:PXCETEXT']""  D
  1.  . S (PXCEEXT,PXCEINT)=$P(ENTRY($P(PXCETEXT,"~",1)),"^",$P(PXCETEXT,"~",2))
  1.  . I PXCETEXT'["CPT Modifier",PXCEINT="" Q  ;Q:PXCEINT=""
  1.  . Q:$P(PXCETEXT,"~",10)="N"
  1.  . I VIEW'="D",$P(PXCETEXT,"~",10)="D" Q
  1.  . I PXCECODE="PXCECSTP",$P(PXCETEXT,"~",3)=.01 Q
  1.  . I $P(PXCETEXT,"~",6)]"" D  Q:PXCEEXT=""
  1.  .. ;I PXCECODE["CPT",$P(PXCETEXT,"~",6)["DNAR" B  
  1.  .. S @("PXCEEXT="_$P(PXCETEXT,"~",6)_"("""_$S($P(PXCETEXT,"~",3)=.01:ENTRY($P(PXCETEXT,"~",1)),1:PXCEINT)_""")")
  1.  . E  D
  1.  .. N PXCEDILF,DIERR,PXCEI
  1.  .. S PXCEEXT=$$EXTERNAL^DILFD(PXCEFILE,$P(PXCETEXT,"~",3),"",PXCEINT,"PXCEDILF")
  1.  .. S PXCEEXT=$S('$D(DIERR):PXCEEXT,1:PXCEINT)
  1.  . S TEMP=PXCEEXT
  1.  . F PXI=1:1 Q:$P(TEMP,"^",PXI)=""  S PXCEEXT=$P(TEMP,"^",PXI) D ADDLINE
  1.  Q
  1. ADDLINE ;
  1.  S LINE=LINE+1
  1.  I PXCELINE=1!(PXCECODE="PXCECSTP") S @ARRAY@(LINE,0)=$J(COUNT,3)_" "
  1.  E  S @ARRAY@(LINE,0)="    "
  1.  S @ARRAY@(LINE,0)=@ARRAY@(LINE,0)_$P(PXCETEXT,"~",5)
  1.  I ($L(@ARRAY@(LINE,0))+$L(PXCEEXT))'>80 D
  1.  . S @ARRAY@(LINE,0)=@ARRAY@(LINE,0)_PXCEEXT
  1.  E  D
  1.  . N PXCEWRAP,PXCECOUN,PXCEHEAD
  1.  . S PXCEHEAD=$L(@ARRAY@(LINE,0))
  1.  . D WRAP^PXCEVFI4(PXCEEXT,80-PXCEHEAD,.PXCEWRAP)
  1.  . S @ARRAY@(LINE,0)=@ARRAY@(LINE,0)_$G(PXCEWRAP(1))
  1.  . S PXCECOUN=1
  1.  . F  S PXCECOUN=$O(PXCEWRAP(PXCECOUN)) Q:PXCECOUN']""  D
  1.  .. S LINE=LINE+1
  1.  .. S @ARRAY@(LINE,0)=$J("",PXCEHEAD)_PXCEWRAP(PXCECOUN)
  1.  Q
  1.  ;