Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PXRHS05

PXRHS05.m

Go to the documentation of this file. 
  1. PXRHS05 ;ISL/SBW - PCE V EXAM extract routine ;12/10/96
  1.  ;;1.0;PCE PATIENT CARE ENCOUNTER;**13**;Aug 12, 1996
  1.  ; Extract returns EXAM data
  1. EXAM(DFN,ENDDT,BEGDT,OCCLIM) ; Control branching
  1.  ;INPUT  : DFN      - Pointer to PATIENT file (#2)
  1.  ;         ENDDT    - Ending date/time in internal FileMan format
  1.  ;                  - Defaults to today's date at 11:59 pm
  1.  ;         BEGDT    - Beginning date/time in internal FileMan format
  1.  ;                  - Defaults to one year prior to today's date
  1.  ;         OCCLIM   - Maximum # of each type of exam returned
  1.  ;OUTPUT :
  1.  ;  Data from V EXAM (9000010.13) file
  1.  ;  ^TMP("PXE,$J,EXAM,InvDt,IFN,0) = EXAM [E;.01]
  1.  ;     ^ EVENT DATE/TIME or VISIT/ADMIT DATE&TIME [I;1201 or .03] 
  1.  ;     ^ RESULTS CODE [I;.04] ^ RESULTS [E;.04]
  1.  ;     ^ ORDERING PROVIDER [E;1202] ^ ENCOUNTER PROVIDER [E;1204] ^
  1.  ;  ^TMP("PXE",$J,EXAM,InvDt,IFN,1) = HOSPITAL LOCATION [E;9000010;.22] 
  1.  ;     ^ HOSP. LOC. ABBREVIATION [E;44;1]
  1.  ;     ^ LOC OF ENCOUNTER [E;9000010;.06] ^ OUTSIDE LOC [E;9000010;2101]
  1.  ;  ^TMP("PXE",$J,EXAM,InvDt,IFN,"S") = DATA SOURCE [E;80102]
  1.  ;
  1.  ;   [] = [I(nternal)/E(xternal); Optional file #; Record #]
  1.  ;   Subscripts:
  1.  ;     EXAM  - EXAM name
  1.  ;     InvDt - Inverse FileMan date of DATE OF event or visit
  1.  ;     IFN   - Internal Record #
  1.  ;
  1.  Q:$G(DFN)']""!'$D(^AUPNVXAM("AA",DFN))
  1.  N PXEX,PXIVD,PXIFN,CNT,IBEGDT,IENDDT
  1.  S:+$G(OCCLIM)'>0 OCCLIM=999
  1.  S:+$G(BEGDT)'>0 BEGDT=DT-10000
  1.  S:+$G(ENDDT)'>0 ENDDT=DT_".235959"
  1.  ; Chg regular dt/time to inverted dt/time
  1.  S IBEGDT=9999999-ENDDT,IENDDT=9999999-BEGDT
  1.  K ^TMP("PXE",$J)
  1.  S PXEX=""
  1.  F  S PXEX=$O(^AUPNVXAM("AA",DFN,PXEX)) Q:PXEX=""  D
  1.  . S PXIVD=IBEGDT,CNT=0
  1.  . F  S PXIVD=$O(^AUPNVXAM("AA",DFN,PXEX,PXIVD)) Q:PXIVD'>0!(PXIVD>IENDDT)  D  Q:CNT'<OCCLIM
  1.  . . S PXIFN=0
  1.  . . F  S PXIFN=$O(^AUPNVXAM("AA",DFN,PXEX,PXIVD,PXIFN)) Q:PXIFN'>0  D  Q:CNT'<OCCLIM
  1.  . . . N DIC,DIQ,DR,DA,REC,VDATA,EXAM,EXDT,RESULTC,RESULT,COMMENT
  1.  . . . N OPROV,EPROV,HLOC,HLOCABB,SOURCE,IDT
  1.  . . . S DIC=9000010.13,DA=PXIFN,DIQ="REC(",DIQ(0)="IE"
  1.  . . . S DR=".01;.03;.04;1201;1202;1204;80102;81101"
  1.  . . . D EN^DIQ1
  1.  . . . Q:'$D(REC)
  1.  . . . S VDATA=$$GETVDATA^PXRHS03(+REC(9000010.13,DA,.03,"I"))
  1.  . . . S EXAM=REC(9000010.13,DA,.01,"E")
  1.  . . . S EXDT=REC(9000010.13,DA,1201,"I")
  1.  . . . S:EXDT']"" EXDT=$P(VDATA,U)
  1.  . . . S IDT=9999999-EXDT
  1.  . . . I IDT<IBEGDT!(IDT>IENDDT) Q  ;Only get data within date range
  1.  . . . S RESULTC=REC(9000010.13,DA,.04,"I")
  1.  . . . S RESULT=REC(9000010.13,DA,.04,"E")
  1.  . . . S OPROV=REC(9000010.13,DA,1202,"E")
  1.  . . . S EPROV=REC(9000010.13,DA,1204,"E")
  1.  . . . S HLOC=$P(VDATA,U,5)
  1.  . . . S HLOCABB=$P(VDATA,U,6)
  1.  . . . S SOURCE=REC(9000010.13,DA,80102,"E")
  1.  . . . S COMMENT=REC(9000010.13,DA,81101,"E")
  1.  . . . S ^TMP("PXE",$J,EXAM,IDT,DA,0)=EXAM_U_EXDT_U_RESULTC_U_RESULT_U_OPROV_U_EPROV
  1.  . . . S ^TMP("PXE",$J,EXAM,IDT,DA,1)=HLOC_U_HLOCABB_U_$P(VDATA,U,2)_U_$P(VDATA,U,4)
  1.  . . . S ^TMP("PXE",$J,EXAM,IDT,DA,"S")=SOURCE
  1.  . . . S ^TMP("PXE",$J,EXAM,IDT,DA,"COM")=COMMENT
  1.  . . . S CNT=CNT+1
  1.  Q