Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PXRMEUT

PXRMEUT.m

Go to the documentation of this file. 
  1. PXRMEUT ;SLC/PJH - General extract utilities ;07/29/2010
  1.  ;;2.0;CLINICAL REMINDERS;**4,6,17,18**;Feb 04, 2005;Build 152
  1.  ;
  1.  ;=================================================
  1. ASKNUM(TEXT,MIN,MAX) ;
  1.  N DIR,X,Y
  1.  K DIROUT,DIRUT,DTOUT,DUOUT
  1.  S DIR(0)="N"_U_MIN_":"_MAX
  1.  S DIR("A")=TEXT
  1.  S DIR("B")=MIN
  1.  S DIR("?")="Enter a number between "_MIN_" and "_MAX_"."
  1.  W !
  1.  D ^DIR
  1.  I $D(DTOUT)!$D(DUOUT) S Y=MIN
  1.  Q Y
  1.  ;
  1.  ;=================================================
  1. ASKYN(DEF,TEXT,RTN,HLP) ;
  1.  N DIR,X,Y
  1.  K DIROUT,DIRUT,DTOUT,DUOUT
  1.  S DIR(0)="Y0"
  1.  S DIR("A")=TEXT
  1.  S DIR("B")=DEF
  1.  S DIR("?")="Enter Y or N."
  1.  I $G(RTN)'="",$G(HLP)'="" D
  1.  . S DIR("?")="Enter Y or N. For detailed help type ??"
  1.  . S DIR("??")=U_"D HELP^"_RTN_"(HLP)"
  1.  W !
  1.  D ^DIR
  1.  I $D(DTOUT)!$D(DUOUT) S Y=DEF
  1.  Q Y
  1.  ;
  1.  ;=================================================
  1. BHELP ;Write the beginning date help.
  1.  N BDHTEXT,%DT
  1.  S BDHTEXT(1)="This is the beginning date for the "_LIT_"."
  1.  D HELP^PXRMEUT(.BDHTEXT)
  1.  S %DT="P",%DT(0)=-DT
  1.  D HELP^%DTC
  1.  Q
  1.  ;
  1.  ;=================================================
  1. CALC(NEXT,START,END) ;Calculate period start and end dates
  1.  ;Next is current run period
  1.  N CMON,CYR,ETYPE,NMON,NYR,PERIOD,YEAR
  1.  ;extract year and period (M1,M2,Q1,Q2,Y etc)
  1.  I NEXT["/" S YEAR=$P(NEXT,"/",2),PERIOD=$P(NEXT,"/"),ETYPE=$E(PERIOD)
  1.  I NEXT?4N S YEAR=NEXT,PERIOD="",ETYPE="Y"
  1.  ;Two digit year
  1.  S CYR=$E(YEAR,3,4),NYR=CYR
  1.  ;If yearly use Jan 1st of current year and next
  1.  I ETYPE="Y" D
  1.  .S CMON="1",NMON="1",NYR=NYR+1
  1.  ;If quarterly use start of first month of next quarter
  1.  I ETYPE="Q" D
  1.  .S CMON=$E(PERIOD,2,99),NMON=CMON*3+1 I NMON>12 S NYR=NYR+1,NMON=1
  1.  .S CMON=CMON*3-2
  1.  ;If monthly use start of next month
  1.  I ETYPE="M" D
  1.  .S CMON=$E(PERIOD,2,99),NMON=CMON+1 I NMON>12 S NYR=NYR+1,NMON=1
  1.  ;Zero fill the month fields
  1.  S CMON=$$RJ^XLFSTR(CMON,2,0),NMON=$$RJ^XLFSTR(NMON,2,0)
  1.  ;Zero fill the year fields
  1.  S CYR=$$RJ^XLFSTR(CYR,2,0),NYR=$$RJ^XLFSTR(NYR,2,0)
  1.  ;Report start date is start of current period 
  1.  S START=3_CYR_CMON_"01"
  1.  ;Report end date is start of next period less one day
  1.  S END=$$FMADD^XLFDT(3_NYR_NMON_"01",-1)
  1.  Q
  1.  ;
  1.  ;=================================================
  1. DATES(BDATE,EDATE,LIT) ;Get a past date range.
  1. BEGIN ;Select the beginning date.
  1.  N DIR,%DT,X,Y
  1.  K DIROUT,DIRUT,DTOUT,DUOUT
  1.  S DIR(0)="DA^::ETX"
  1.  S DIR("A")="Enter "_LIT_" BEGINNING DATE: "
  1.  S DIR("PRE")="S X=$$DCHECK^PXRMDATE(X) K:X=-1 X"
  1.  S DIR("?")="For detailed help type ??"
  1.  S DIR("??")=U_"D BHELP^PXRMEUT"
  1.  W !
  1.  D ^DIR K DIR
  1.  I $D(DIROUT) S DTOUT=1
  1.  I $D(DTOUT)!($D(DUOUT)) Q
  1.  S BDATE=Y
  1.  I $E(Y,6,7)="00" W $C(7),"  ?? Enter exact date" G BEGIN
  1.  S BDATE=Y
  1.  ;
  1. END ;Select the ending date.
  1.  S DIR(0)="DA^"_BDATE_"::ETX"
  1.  S DIR("A")="Enter "_LIT_" ENDING DATE: "
  1.  S DIR("PRE")="S X=$$DCHECK^PXRMDATE(X) K:X=-1 X"
  1.  S DIR("?")="This date cannot be before "_$$FMTE^XLFDT(BDATE,"D")_". For detailed help type ??"
  1.  S DIR("??")=U_"D EHELP^PXRMEUT"
  1.  D ^DIR
  1.  I $D(DIROUT) S DTOUT=1
  1.  I $D(DTOUT) Q
  1.  I $D(DUOUT) G BEGIN
  1.  S EDATE=Y
  1.  I $E(Y,6,7)="00" W $C(7),"  ?? Enter exact date" G END
  1.  K DIROUT,DIRUT,DTOUT,DUOUT
  1.  Q
  1.  ;
  1.  ;=================================================
  1. DOCUMENT(PXRMLIST,PXRMRULE,INDP,INTP,BEG,END) ;Document how the
  1.  ;list was built.
  1.  N CDATE,CLASS,CREATOR,IND,LDATA,LNAME
  1.  N NDL,NL,NPAT,OUTPUT,SNAME,SOURCE,TEXT,TYPE,VALMCNT
  1.  K ^TMP("PXRMLRED",$J)
  1.  S LDATA=$G(^PXRMXP(810.5,PXRMLIST,0))
  1.  S LNAME=$P(LDATA,U,1)
  1.  S CDATE=$P(LDATA,U,4)
  1.  S SOURCE=$P(LDATA,U,5),SNAME="NONE"
  1.  ;Check if generated from #810.2
  1.  I SOURCE S SNAME="Extract Parameter - "_$P($G(^PXRM(810.2,SOURCE,0)),U)
  1.  ;If not check if generated from #810.4
  1.  I 'SOURCE S SOURCE=$P(LDATA,U,6) S:SOURCE SNAME="List Rule - "_$P($G(^PXRM(810.4,SOURCE,0)),U)
  1.  ;Creator
  1.  S CREATOR=+$P(LDATA,U,7)
  1.  S CREATOR=$S(CREATOR>0:$$GET1^DIQ(200,CREATOR,.01),1:"None")
  1.  ;Type
  1.  S TYPE=$P(LDATA,U,8)
  1.  S TYPE=$$EXTERNAL^DILFD(810.5,.08,"",TYPE,.EM)
  1.  ;Class
  1.  S CLASS=$P($G(^PXRMXP(810.5,PXRMLIST,100)),U,1)
  1.  S CLASS=$S(CLASS="N":"National",CLASS="V":"VISN",1:"Local")
  1.  S NPAT=$P(^PXRMXP(810.5,PXRMLIST,30,0),U,4)
  1.  S TEXT(1)="List Name: "_LNAME_" ("_NPAT_" patients)"
  1.  S TEXT(2)=" Created: "_$$FMTE^XLFDT(CDATE,"5Z")
  1.  S TEXT(2)=$$LJ^XLFSTR(TEXT(2),40)_"Creator: "_CREATOR
  1.  S TEXT(3)=" Class: "_CLASS
  1.  S TEXT(3)=$$LJ^XLFSTR(TEXT(3),40)_"Type: "_TYPE
  1.  S TEXT(4)=" Source: "_SNAME
  1.  S TEXT(5)=" Patient List Beginning Date: "_$$FMTE^XLFDT(BEG,"5Z")
  1.  S TEXT(6)=" Patient List Ending Date: "_$$FMTE^XLFDT(END,"5Z")
  1.  S TEXT(7)=" "
  1.  S NL=7
  1.  F IND=1:1:NL S ^PXRMXP(810.5,PXRMLIST,200,IND,0)=TEXT(IND)
  1.  D BLDLIST^PXRMLRED(PXRMRULE,3)
  1.  F IND=1:1:VALMCNT S NL=NL+1,^PXRMXP(810.5,PXRMLIST,200,NL,0)=^TMP("PXRMLRED",$J,IND,0)
  1.  S NL=NL+1,^PXRMXP(810.5,PXRMLIST,200,NL,0)=" --- List Build Information ---"
  1.  S NL=NL+1,^PXRMXP(810.5,PXRMLIST,200,NL,0)="List Build Beginning Date: "_$$FMTE^XLFDT(BEG,"5Z")
  1.  S NL=NL+1,^PXRMXP(810.5,PXRMLIST,200,NL,0)="List Build Ending Date: "_$$FMTE^XLFDT(END,"5Z")
  1.  S NL=NL+1,^PXRMXP(810.5,PXRMLIST,200,NL,0)=" "
  1.  S NL=NL+1,^PXRMXP(810.5,PXRMLIST,200,NL,0)="Include deceased patients: "_$S(INDP:"Yes",1:"No")
  1.  S NL=NL+1,^PXRMXP(810.5,PXRMLIST,200,NL,0)="Include test patients: "_$S(INTP:"Yes",1:"No")
  1.  ;Get the beginning and ending date information
  1.  D DOCDATES^PXRMEUT1(PXRMRULE,BEG,END,.NDL,.OUTPUT)
  1.  F IND=1:1:NDL S NL=NL+1,^PXRMXP(810.5,PXRMLIST,200,NL,0)=OUTPUT(IND)
  1.  S ^PXRMXP(810.5,PXRMLIST,200,0)=U_U_NL_U_NL_U_DT_U
  1.  K ^TMP("PXRMLRED",$J)
  1.  Q
  1.  ;
  1.  ;=================================================
  1. EHELP ;Write the ending date help.
  1.  N EDHTEXT,%DT
  1.  S EDHTEXT(1)="This is the ending date for the "_LIT_"."
  1.  D HELP^PXRMEUT(.EDHTEXT)
  1.  S %DT="P",%DT(0)=-DT
  1.  D HELP^%DTC
  1.  Q
  1.  ;
  1.  ;=================================================
  1. HELP(HTEXT) ;General help text output routine.
  1.  N IND,NIN,NOUT,TEXTIN,TEXOUT
  1.  ;Make sure the text is in a form the formatting routine can handle.
  1.  S IND="",NIN=0
  1.  F  S IND=$O(HTEXT(IND)) Q:IND=""  S NIN=NIN+1,TEXTIN(NIN)=HTEXT(IND)
  1.  D FORMAT^PXRMTEXT(1,72,NIN,.TEXTIN,.NOUT,.TEXTOUT)
  1.  F IND=1:1:NOUT W !,TEXTOUT(IND)
  1.  W !
  1.  Q
  1.  ;
  1.  ;=================================================
  1. LDELOK(LISTIEN) ;Return a 1 if it is ok for this user to delete the list.
  1.  N CREATOR,DELOK
  1.  S CREATOR=$P(^PXRMXP(810.5,LISTIEN,0),U,7)
  1.  S DELOK=$S(CREATOR=DUZ:1,$D(^XUSEC("PXRM MANAGER",DUZ)):1,1:0)
  1.  Q DELOK
  1.  ;
  1.  ;=================================================
  1. MES(TEXT) ;General mail message
  1.  N XMSUB
  1.  K ^TMP("PXRMXMZ",$J)
  1.  S XMSUB="CLINICAL REMINDER EXTRACT"
  1.  S ^TMP("PXRMXMZ",$J,1,0)=TEXT
  1.  D SEND^PXRMMSG("PXRMXMZ",XMSUB,"",DUZ)
  1.  Q
  1.  ;
  1.  ;=================================================
  1. PERIOD(FREQ) ;Calculate next period
  1.  N CMON,CUR,CYR,ETYPE,NEXT,PERIOD,YEAR
  1.  ;Format current date YY/MM/DD
  1.  S CUR=$$FMTE^XLFDT($$NOW^XLFDT,7)
  1.  ;extract year and period
  1.  S YEAR=$P(CUR,"/"),PERIOD=$P(CUR,"/",2)
  1.  ;If yearly current year
  1.  I FREQ="Y" D
  1.  .S NEXT=YEAR
  1.  ;If quarterly use current quarter
  1.  I FREQ="Q" D
  1.  .S NEXT="Q"_((PERIOD-1\3)+1)_"/"_YEAR
  1.  ;If monthly use current month
  1.  I FREQ="M" D
  1.  .S NEXT="M"_PERIOD_"/"_YEAR
  1.  Q NEXT
  1.  ;
  1.  ;=================================================
  1. RMPAT(NODE,INDP,INTP) ;Remove dead and test patients from
  1.  ;the list.
  1.  I INDP,INTP Q
  1.  N DFN,DOD,REMOVE
  1.  S DFN=0
  1.  F  S DFN=$O(^TMP($J,NODE,DFN)) Q:DFN=""  D
  1.  .;DBIA 3744
  1.  . S REMOVE=$S('INTP:$$TESTPAT^VADPT(DFN),1:0)
  1.  . I REMOVE K ^TMP($J,NODE,DFN) Q
  1.  . I INDP Q
  1.  .;DBIA #10035
  1.  . S DOD=+$P($G(^DPT(DFN,.35)),U,1)
  1.  . I DOD=0 Q
  1.  . K ^TMP($J,NODE,DFN)
  1.  Q
  1.  ;