Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PXRMP26I

PXRMP26I.m

Go to the documentation of this file. 
  1. PXRMP26I ;SLC/PKR - Inits for PXRM*2.0*26. ;05/07/2014
  1.  ;;2.0;CLINICAL REMINDERS;**26**;Feb 04, 2005;Build 404
  1.  Q
  1.  ;==========================================
  1. CFINC(Y) ;List of computed findings to include in the build.
  1.  N CFLIST,CFNAME
  1.  S CFLIST("VA-ALLERGY")=""
  1.  S CFLIST("VA-FILEMAN DATE")=""
  1.  S CFLIST("VA-PROGRESS NOTE")=""
  1.  S CFLIST("VA-REMINDER DEFINITION")=""
  1.  ;S CFLIST("")=""
  1.  S CFNAME=$P($G(^PXRMD(811.4,Y,0)),U)
  1.  Q $S($D(CFLIST(CFNAME)):1,1:0)
  1.  ;
  1.  ;==========================================
  1. CHECK(GLOB,DLGPTR) ; check for duplicates
  1.  N INDEX,RETURN S INDEX=0,RESULT=1
  1.  ;RESULT=1 ok to add, RESULT=-1 not ok to add
  1.  F  S INDEX=$O(@GLOB@(INDEX)) Q:INDEX=""!(RESULT=-1)  D
  1.  .S:DLGPTR=$P(@GLOB@(INDEX),U) RESULT=-1 ;if the pointer matches one of the prompts already stored, it's a duplicate, don't store it again.
  1.  Q RESULT
  1.  ;
  1.  ;==================================================
  1. CTAXBDES ;Copy taxonomy brief descriptions to the description field.
  1.  N BDES,IEN,NAME
  1.  D BMES^XPDUTL("Copying all taxonomy Brief Descriptions to Description.")
  1.  S NAME=""
  1.  F  S NAME=$O(^PXD(811.2,"B",NAME)) Q:NAME=""  D
  1.  . S IEN=$O(^PXD(811.2,"B",NAME,""))
  1.  . S BDES=$P(^PXD(811.2,IEN,0),U,2)
  1.  . D BMES^XPDUTL("Working on taxonomy "_NAME)
  1.  . I BDES="" D MES^XPDUTL(" Brief description does not exist.") Q
  1.  . I $D(^PXD(811.2,IEN,1)) D MES^XPDUTL(" Already copied.") Q
  1.  . D MES^XPDUTL(" Brief description: "_BDES)
  1.  . S ^PXD(811.2,IEN,1,0)="^^1^1^"_DT_"^^"
  1.  . S ^PXD(811.2,IEN,1,1,0)=BDES
  1.  Q
  1.  ;
  1.  ;==========================================
  1. DELDD ;Delete the old data dictionaries.
  1.  N DIU,TEXT
  1.  D EN^DDIOL("Removing old data dictionaries.")
  1.  S DIU(0)=""
  1.  F DIU=811.2,801.41 D
  1.  . S TEXT=" Deleting data dictionary for file # "_DIU
  1.  . D EN^DDIOL(TEXT)
  1.  . D EN^DIU2
  1.  Q
  1.  ;
  1.  ;==========================================
  1. DELOPT ;AGP ICD10: added code to remove options from menu.
  1.  N RESULT
  1.  ;Remove PXRM TAXONOMY DIALOG from PXRM DIALOG PARAMETERS also set the 
  1.  ;PXRM TAXONOMY DIALOG to delete in the build file.
  1.  S RESULT=$$DELETE^XPDMENU("PXRM DIALOG PARAMETERS","PXRM TAXONOMY DIALOG")
  1.  Q
  1.  ;
  1.  ;===============================================
  1. DEXXREFS ;Delete unused Exchange Installation History 'B' indexes.
  1.  N MSG
  1.  ;Component List
  1.  D DELIX^DDMOD(811.8031,.01,1,"K","","MSG")
  1.  ;Additional Details
  1.  D DELIX^DDMOD(811.80315,.01,1,"K","","MSG")
  1.  Q
  1.  ;
  1.  ;===============================================
  1. INILT ;Initialize list templates
  1.  ;THIS MAY NO LONGER BE NECESSARY, THIS NEEDS TO BE CONFIRMED
  1.  ;N IEN,IND,LIST,TEMP0
  1.  ;D LTL^PXRMP26I(.LIST)
  1.  ;S IND=0
  1.  ;IA #4123
  1.  ;F  S IND=$O(LIST(IND)) Q:IND=""  D
  1.  ;. S IEN=$O(^SD(409.61,"B",LIST(IND),"")) Q:IEN=""
  1.  ;. S TEMP0=$G(^SD(409.61,IEN,0))
  1.  ;. K ^SD(409.61,IEN)
  1.  ;. S ^SD(409.61,IEN,0)=TEMP0
  1.  Q
  1.  ;
  1.  ;==========================================
  1. LTL(LIST) ;This is the list of list templates that being distributed
  1.  ;in the patch.
  1.  ;S LIST(1)="PXRM EX LIST COMPONENTS"
  1.  ;S LIST(2)="PXRM EX REMINDER EXCHANGE"
  1.  Q
  1.  ;
  1.  ;==========================================
  1. PRE ;Pre-init
  1.  ;Disable options and protocols
  1.  D OPTION^PXRMUTIL("DISABLE")
  1.  D PROTOCOL^PXRMUTIL("DISABLE")
  1.  D BUILDD^PXRMDIEV("PXRM*2.0*26")
  1.  D DELOPT
  1.  D TMGRRO^PXRMP26I
  1.  D PRE^PXRMP26D
  1.  D DELDD^PXRMP26I
  1.  D DELEXE^PXRMEXSI("EXARRAY","PXRMP26E")
  1.  Q
  1.  ;
  1.  ;==========================================
  1. POST ;Post-init
  1.  D TMGRN^PXRMP26I
  1.  D CTAXBDES^PXRMP26I
  1.  D CPALL^PXRMTXCR
  1.  D SETPVER^PXRMUTIL("2.0P26")
  1.  D POST^PXRMP26D
  1.  D DEXXREFS^PXRMP26I
  1.  ;Install Exchange File entries.
  1.  ;D SMEXINS^PXRMEXSI("EXARRAY","PXRMP26E")
  1.  D RBLD20I^PXRMTAXD
  1.  D RBPDS^PXRMP26I
  1.  ;Check the Selected Codes Multiple and repair any that are corrupted.
  1.  D CHECKALL^PXRMTXIC
  1.  ;Enable options and protocols
  1.  D OPTION^PXRMUTIL("ENABLE")
  1.  D PROTOCOL^PXRMUTIL("ENABLE")
  1.  D BUILDE^PXRMDIEV("PXRM*2.0*26")
  1.  ;If the indexes for files #45 and #9000011 are still rebuilding,
  1.  ;disable reminder evaluation.
  1.  I '$D(^PXRMINDX(45,"DATE BUILT")) D INDEXD^PXRMDIEV(45)
  1.  I '$D(^PXRMINDX(9000011,"DATE BUILT")) D INDEXD^PXRMDIEV(9000011)
  1.  ;Put the old taxonomy management and edit options out of order.
  1.  D OUT^XPDMENU("PXRM TAXONOMY MANAGEMENT (OLD)","This option is obsolete.")
  1.  D OUT^XPDMENU("PXRM TAXONOMY EDIT","This option is obsolete.")
  1.  D OUT^XPDMENU("PXRMCS INACTIVE DIALOG CODES","This option is obsolete.")
  1.  D SENDIM^PXRMP26I
  1.  Q
  1.  ;
  1.  ;==========================================
  1. RBPDS ;Rebuild the Patient Data Source index.
  1.  N IEN,NAME,PDS
  1.  D BMES^XPDUTL("Rebuilding Patient Data Source Index.")
  1.  S NAME=""
  1.  F  S NAME=$O(^PXD(811.2,"B",NAME)) Q:NAME=""  D
  1.  . S IEN=$O(^PXD(811.2,"B",NAME,""))
  1.  . S PDS=$P(^PXD(811.2,IEN,0),U,4)
  1.  . D MES^XPDUTL(" Taxonomy: "_NAME_"; IEN="_IEN_"; PDS="_PDS)
  1.  . D SPDS^PXRMPDS(IEN,PDS)
  1.  Q
  1.  ;
  1.  ;==========================================
  1. SENDIM ;Send install message.
  1.  N FROM,NODE,PARAM,SYSTEM,SUBJECT,TO,VALUE
  1.  S NODE="PXRM*2.0*26"
  1.  K ^TMP(NODE,$J)
  1.  ;DBIA #1131 for ^XMB("NETNAME")
  1.  S FROM="PXRM*2.0*26 Install@"_^XMB("NETNAME")
  1.  ;DBIA #2541
  1.  S SYSTEM=$$KSP^XUPARAM("WHERE")
  1.  I $$PROD^XUPROD(1) S TO("G.CLINICAL REMINDERS SUPPORT@DOMAIN.EXT")=""
  1.  E  D
  1.  . N MGIEN,MGROUP
  1.  . S MGIEN=$G(^PXRM(800,1,"MGFE"))
  1.  . S MGROUP=$S(MGIEN'="":"G."_$$GET1^DIQ(3.8,MGIEN,.01),1:DUZ)
  1.  . S TO(MGROUP)=""
  1.  S SUBJECT="Install of PXRM*2.0*26"
  1.  S ^TMP(NODE,$J,1,0)="PXRM*2.0*26 has been installed."
  1.  S ^TMP(NODE,$J,2,0)="System is "_SYSTEM
  1.  D SEND^PXRMMSG(NODE,SUBJECT,.TO,FROM)
  1.  Q
  1.  ;
  1.  ;===============================================
  1. TMGRN ;Replace the old taxonomy mangement option with the new one on the
  1.  ;PXRM MANAGERS MENU.
  1.  N RESULT
  1.  S RESULT=$$DELETE^XPDMENU("PXRM MANAGERS MENU","PXRM TAXONOMY MANAGEMENT (OLD)")
  1.  S RESULT=$$ADD^XPDMENU("PXRM MANAGERS MENU","PXRM TAXONOMY MANAGEMENT","TXM",20)
  1.  Q
  1.  ;
  1.  ;===============================================
  1. TMGRRO ;Handle the old PXRM TAXONOMY MANAGEMENT option. Do not delete it until
  1.  ;the cleanup patch, rename it for now. If the rename has already been
  1.  ;done, don't do it again.
  1.  I +$$LKOPT^XPDMENU("PXRM TAXONOMY MANAGEMENT (OLD)")>0 Q
  1.  D BMES^XPDUTL("Setting up taxonomy management option.")
  1.  D RENAME^XPDMENU("PXRM TAXONOMY MANAGEMENT","PXRM TAXONOMY MANAGEMENT (OLD)")
  1.  Q
  1.  ;