Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RAHLR

RAHLR.m

Go to the documentation of this file. 
  1. RAHLR ;HISC/CAH/BNT - Generate Common Order (ORM) Message ; 06 Oct 2013  11:08 AM
  1.  ;;5.0;Radiology/Nuclear Medicine;**2,12,10,25,71,82,75,80,84,94,1005**;Mar 16, 1998;Build 13
  1.  ;Generates msg whenever a case is registered or cancelled or examined
  1.  ;              registered        cancelled        examined
  1.  ; Order control : NW                CA               XO
  1.  ; Order status  : IP                CA               CM
  1.  ;07/28/2008 BAY/KAM RA*5*94 Remove GMT offset from OBR-7 & add Reason for Study to OBX segment
  1.  ;02/14/2006 BAY/KAM RA*5*71 Add ability to update exam data to V/R
  1.  ;
  1.  ;Integration Agreements
  1.  ;----------------------
  1.  ;NOW^%DTC(10000); ^%ZTLOAD(10063); $$GET1^DIQ(2056); ^DIWP(10011)
  1.  ;$$HLDATE/$$HLNAME/$$M11^HLFNC(10106); INIT^HLFNC2(2161)
  1.  ;GENERATE^HLMA(2164); DEM^VADPT(10061); $$EN^VAFHLPID(263)
  1.  ;$$FMTHL7^XLFDT(10103)
  1.  ;
  1.  ;IA: 10039 global read .01 field WARD LOCATION (#42) file ^DIC(42,
  1.  ;IA: 10040 global read .01 field HOSPITAL LOCATION (#44) file ^SC(
  1.  ;
  1.  S:$D(HLNDAP) ZTSAVE("HLNDAP")="" S:$D(HLDAP) ZTSAVE("HLDAP")="" S:$D(RAEXMDUN) ZTSAVE("RAEXMDUN")=""
  1.  S:$D(RAEXEDT) ZTSAVE("RAEXEDT")=""
  1.  S ZTSAVE("RADFN")="",ZTSAVE("RADTI")="",ZTSAVE("RACNI")="",ZTIO="",ZTDTH=$H,ZTDESC="Rad/Nuc Med Compiling HL7 Common Order",ZTRTN="EN^RAHLR" D ^%ZTLOAD
  1.  K ZTDESC,ZTDTH,ZTIO,ZTRTN,ZTSAVE Q
  1. EN ; Called from the RA REG & RA CANCEL & RA EXAMINED protocols
  1.  ; Input Variables:
  1.  ;   RADFN=file 2 IEN (DFN)
  1.  ;   RADTI=file 70 Exam subrec IEN (reverse date/time of exam)
  1.  ;   RACNI=file 70 Case subrecord IEN
  1.  ;   RAEID=ien of the event driver protocol (defined in RAHLRPC)
  1.  ; Output Variables:
  1.  ;   HLA("HLS") array containing HL7 msg
  1.  ;
  1.  N EID,HL,INT,HLQ,HLFS,HLECH,HLA,HLCS,HLSCS,HLREP,HLECH
  1.  N DFN,DIWF,DIWL,DIWR,GMRAL,PI,RACANC,RACN0,RACPT,RACPTNDE,RADTE,RAI,RAN,RAOBR4,RAPRCNDE,RAPROC,RAPROCIT,RAPRV,RAX0,VA,VADM,VAERR,X,X0,Y,X1,OBR36
  1.  ;
  1.  D INIT ; initialize some HL7 variables
  1.  ;RAEXMDUN passed from EXM^RAHLRPC if conditions are met
  1.  Q:+$G(HL)=15  ;no known client(item) linked to the event driver protocol
  1.  Q:$O(HL(""))=""  ;disabled server appl, or no server appl 
  1.  ;** branch to new HL7 logic when the HL7 version surpasses 2.3 **
  1.  I HL("VER")>2.3,($T(^RAHLR1))'="" D EN^RAHLR1(RADFN,RADTI,RACNI,RAEID) Q
  1.  ;** branch to new HL7 logic when the HL7 version surpasses 2.3 **
  1.  S RACN0=$S($D(^RADPT(RADFN,"DT",RADTI,"P",RACNI,0)):^(0),1:"") Q:RACN0']""
  1.  ;Generate Message Text
  1.  S RAPROC=+$P(RACN0,U,2) I 'RAPROC Q  ;If case entered via 'Enter Last Past Visit before DHCP option, and procedure 'OTHER' is inactive, RAPROC will be null and will cause bomb-out unless we quit here
  1.  S RAPROCIT=+$P($G(^RAMIS(71,RAPROC,0)),U,12),RAPROCIT=$P(^RA(79.2,RAPROCIT,0),U,1)
  1.  S (RADTE,OBR36)=9999999.9999-RADTI,RADTE=$E(RADTE,4,7)_$E(RADTE,2,3)_"-"_+RACN0,RACANC=$S($D(^RA(72,"AA",RAPROCIT,0,+$P(RACN0,"^",3))):1,1:0)
  1.  S RAPRCNDE=$G(^RAMIS(71,+RAPROC,0)),RACPT=+$P(RAPRCNDE,U,9),RACPTNDE=$$NAMCODE^RACPTMSC(RACPT,DT)
  1.  ;RA*5*82 RAEXEDT= Override the EXM conditions if Case edited
  1.  ;I $G(RAEXMDUN)=1,'$G(RAEXEDT),$P(RACN0,U,30)'="",'$G(RATELE) Q  ;last chance to stop exm'd msg if it's already been sent RA*5*84 Is TELERAD ?? 
  1.  ;Compile 'PID' Segment
  1.  K VA,VADM,VAERR,RAVADM S DFN=RADFN D DEM^VADPT I VADM(1)']"" S HLP("ERRTEXT")="Invalid Patient Identifier" G EXIT
  1.  S RAVADM(3)=$S($E(+VADM(3),6,7)="00":"",1:+VADM(3)) ; NOTE: Check
  1.  ; for an inexact date of birth.  If inexact, pass null for DOB in
  1.  ; the 'PID' segment.  Some COTS systems can't handle inexact DOB's.
  1.  I HL("VER")']"2.2" D
  1.  .;
  1.  .;IHS/BJI/DAY - Patch 1005 - Gender Fix
  1.  .;S HLA("HLS",1)="PID"_HLFS_HLFS_$G(VA("PID"))_HLFS_$$M11^HLFNC(RADFN)_HLFS_HLFS_$$HLNAME^HLFNC(VADM(1))_HLFS_HLFS_$$HLDATE^HLFNC(RAVADM(3))_HLFS_$S(VADM(5)]"":$S("MF"[$P(VADM(5),"^"):$P(VADM(5),"^"),1:"O"),1:"U")
  1.  .S HLA("HLS",1)="PID"_HLFS_HLFS_$G(VA("PID"))_HLFS_$$M11^HLFNC(RADFN)_HLFS_HLFS_$$HLNAME^HLFNC(VADM(1))_HLFS_HLFS_$$HLDATE^HLFNC(RAVADM(3))_HLFS_$S(VADM(5)]"":$S("MFU"[$P(VADM(5),"^"):$P(VADM(5),"^"),1:"O"),1:"U")
  1.  .;
  1.  .S:$P(VADM(2),"^")]"" $P(HLA("HLS",1),HLFS,20)=$P(VADM(2),"^")
  1.  I HL("VER")]"2.2" S HLA("HLS",1)=$$EN^VAFHLPID(DFN,"2,3,5,7,8,19,20")
  1.  K RAVADM
  1.  ;Compile 'ORC' Segment
  1.  S X0="" ;if exam-set or print-set, store parent name if order exists
  1.  I $P(RACN0,U,25) S X0=$P(RACN0,U,11),X0=$P($G(^RAO(75.1,+X0,0)),U,2),X0=$P($G(^RAMIS(71,+X0,0)),U),X0=$S(X0="":"ORIGINAL ORDER PURGED",1:X0),X0=$S($P(RACN0,U,25)=1:"EXAM",1:"PRINT")_"SET: "_X0
  1.  ; BNT - Added ORC4 Placer Group Number for Printset identification.
  1.  ; ORC4 is a combination of SSN with the order inverted date/time.
  1.  S RAORC4="" I $P($G(RACN0),U,25)=2 D
  1.  . S:$P(VADM(2),"^")]"" RAORC4=$P(VADM(2),"^")
  1.  . S RAORC4=$G(RAORC4)_RADTI
  1.  S HLA("HLS",2)="ORC"_HLFS_$S(RACANC:"CA",$G(RAEXMDUN)=1:"XO",1:"NW")_HLFS_HLFS_HLFS_RAORC4_HLFS_$S(RACANC:"CA",$G(RAEXMDUN)=1:"CM",1:"IP")_HLFS_HLFS_HLFS_X0_HLFS_HLDT1
  1.  K RAORC4
  1.  ;Compile 'OBR' Segment
  1.  S RAOBR4=$P(RACPTNDE,U)_$E(HLECH)_$P(RACPTNDE,U,2)_$E(HLECH)_"C4"_$E(HLECH)_+RAPROC_$E(HLECH)_$P(RAPRCNDE,U)_$E(HLECH)_"99RAP"
  1.  ; Replace above with following when Imaging can cope with ESC chars
  1.  ; S RAOBR4=$P(RACPTNDE,U)_$E(HLECH)_$$ESCAPE^RAHLRU($P(RACPTNDE,U,2))_$E(HLECH)_"C4"_$E(HLECH)_+RAPROC_$E(HLECH)_$$ESCAPE^RAHLRU($P(RAPRCNDE,U))_$E(HLECH)_"99RAP"
  1.  I $P(RACPTNDE,U)']"" S $P(RAOBR4,$E(HLECH),1,3)=$P(RAOBR4,$E(HLECH),4,5)_$E(HLECH)_"LOCAL"
  1.  ;OBR-7 change: from HLDT1 to $$HLDATE^HLFNC(9999999.9999-RADTI) d/t of registration
  1.  ;Driver of change: CareStream Health PACS. Agfa requires a timestamp down to the second
  1.  ;POC @ Boston is Maureen Sullivan
  1.  ;S HLA("HLS",3)="OBR"_HLFS_HLFS_RADTE_HLFS_RADTI_"-"_RACNI_$E(HLECH)_RADTE_$E(HLECH)_"L"_HLFS_RAOBR4_HLFS_HLFS_HLFS_$$HLDATE^HLFNC(9999999.9999-RADTI)
  1.  ;
  1.  ;07/28/2008 BAY/KAM RA*5*94 Remove GMT offset from OBR-7 in next line
  1.  S HLA("HLS",3)="OBR"_HLFS_HLFS_RADTE_HLFS_RADTI_"-"_RACNI_$E(HLECH)_RADTE_$E(HLECH)_"L"_HLFS_RAOBR4_HLFS_HLFS_HLFS_$P($$HLDATE^HLFNC(9999999.9999-RADTI),"-",1)
  1.  ;
  1.  S HLA("HLS",3)=HLA("HLS",3)_HLFS_HLQ_HLFS_HLQ_HLFS_HLFS_HLFS_HLFS_HLFS_HLQ_HLFS_HLFS
  1.  S RAPRV=$$GET1^DIQ(200,+$P(RACN0,"^",14),.01)
  1.  S HLA("HLS",3)=HLA("HLS",3)_$S(RAPRV]"":+$P(RACN0,"^",14)_$E(HLECH)_$$HLNAME^HLFNC(RAPRV),1:"")
  1.  ;
  1.  N RACN00,RA20 S RACN00=$G(^RADPT(RADFN,"DT",RADTI,0))
  1.  ;Seg's fld 20 = pce 21 --> ien file #79.1~name of img loc~stn #~stn name
  1.  S RA20=+$G(^RA(79.1,+$P(RACN00,U,4),0))
  1.  S $P(HLA("HLS",3),HLFS,21)=$P(RACN00,U,4)_$E(HLECH)_$P($G(^SC(RA20,0)),U)_$E(HLECH)_$P(RACN00,U,3)_$E(HLECH)_$P($G(^DIC(4,+$P(RACN00,U,3),0)),U)
  1.  S $P(HLA("HLS",3),HLFS,21)=$P(HLA("HLS",3),HLFS,21)
  1.  ; Replace above with following when Imaging can cope with ESC chars
  1.  ; S $P(HLA("HLS",3),HLFS,21)=$$ESCAPE^RAHLRU($P(HLA("HLS",3),HLFS,21))
  1.  ;Seg's fld 21 = pce 22 --> abbrv I-type~Img type name
  1.  S RA20=$G(^RA(79.2,+$P(RACN00,U,2),0))
  1.  S $P(HLA("HLS",3),HLFS,22)=$P(RA20,U,3)_$E(HLECH)_$P(RA20,U)
  1.  S $P(HLA("HLS",3),HLFS,22)=$P(HLA("HLS",3),HLFS,22)
  1.  ; Replace above with following when Imaging can cope with ESC chars
  1.  ; S $P(HLA("HLS",3),HLFS,22)=$$ESCAPE^RAHLRU($P(HLA("HLS",3),HLFS,22))
  1.  ;
  1.  S $P(HLA("HLS",3),HLFS,23)=HLDT1,$P(HLA("HLS",3),HLFS,19)=$S($D(^DIC(42,+$P(RACN0,"^",6),0)):$P(^(0),"^"),$D(^SC(+$P(RACN0,"^",8),0)):$P(^(0),"^"),1:"Unknown")
  1.  ;
  1.  ; OBR-31.2 = Reason for Study P75
  1.  S $P(HLA("HLS",3),HLFS,32)=$E(HLECH)_$$ESCAPE^RAHLRU($P($G(^RAO(75.1,+$P(RACN0,"^",11),.1)),U))
  1.  ;
  1.  ; OBR-36 = Exam Date/Time
  1.  S $P(HLA("HLS",3),HLFS,37)=$$FMTHL7^XLFDT(OBR36)
  1.  ;
  1.  I 'RACANC S X=$P($G(^RAO(75.1,+$P(RACN0,"^",11),0)),"^",6),$P(HLA("HLS",3),HLFS,28)=$E(HLECH)_$E(HLECH)_$E(HLECH)_$E(HLECH)_$E(HLECH)_$TR(X,"129","SAR")
  1.  ; if long str, break so 2nd str begins with separator to avoid abend
  1.  I $L(HLA("HLS",3))>245 N RAPART,RA1 S RA1=HLA("HLS",3) F RAPART=5:1:15 S RAPART(1)=$P(RA1,HLFS,1,RAPART),RAPART(2)=$P(RA1,HLFS,RAPART+1,99) Q:$L(RAPART(1))<245&($L(RAPART(2))<245)&($P(RAPART(2),HLFS)="")
  1.  I $D(RAPART) K:RAPART=15 RAPART ;if RAPART reaches 15, then something's wrong so kill RAPART to allow abend due "string too long"
  1.  I $D(RAPART) S HLA("HLS",3)=$P(RAPART(1),HLFS)_HLFS,HLA("HLS",3,1)=$P(RAPART(1),HLFS,2,99)_HLFS,HLA("HLS",3,2)=RAPART(2) K RAPART,RA1
  1. OBXPRC ;Compile 'OBX' Segment for Procedure
  1.  S RAN=4 D OBXPRC^RAHLRU
  1. OBXMOD ;Compile 'OBX' Segment for two types of Modifiers
  1.  S RAN=5 D OBXMOD^RAHLRU
  1. OBXHIST ;Compile 'OBX' Segment for Clinical History and Reason for Study (added as prefix).
  1.  I $D(^RAO(75.1,+$P(RACN0,"^",11),.1)) D
  1.  .S RAN=RAN+1,HLA("HLS",RAN)="OBX"_HLFS_HLFS_"TX"_HLFS_"H"_$E(HLECH)_"HISTORY"_$E(HLECH)_"L"_HLFS_HLFS_"Reason for Study: "_$$ESCAPE^RAHLRU($P($G(^RAO(75.1,+$P(RACN0,"^",11),.1)),U)) D OBX11^RAHLRU
  1.  I $O(^RADPT(RADFN,"DT",RADTI,"P",RACNI,"H",0)) S RAN=RAN+1,HLA("HLS",RAN)="OBX"_HLFS_HLFS_"TX"_HLFS_"H"_$E(HLECH)_"HISTORY"_$E(HLECH)_"L"_HLFS_HLFS_" " D OBX11^RAHLRU  ;blank line
  1.  K ^UTILITY($J,"W") S DIWF="",DIWR=80,DIWL=1 F RAI=0:0 S RAI=$O(^RADPT(RADFN,"DT",RADTI,"P",RACNI,"H",RAI)) Q:'RAI  I $D(^(RAI,0)) S X=^(0) D ^DIWP
  1.  F RAI=0:0 S RAI=$O(^UTILITY($J,"W",DIWL,RAI)) Q:'RAI  I $D(^(RAI,0)) S RAN=RAN+1,HLA("HLS",RAN)="OBX"_HLFS_HLFS_"TX"_HLFS_"H"_$E(HLECH)_"HISTORY"_$E(HLECH)_"L"_HLFS_HLFS_^(0) D OBX11^RAHLRU
  1. ALLER ;Compile 'OBX' Segment for Allergies
  1.  S DFN=RADFN D ALLERGY^RADEM S X="" I $D(GMRAL) S RAI=0 F  S RAI=$O(PI(RAI)) Q:RAI'>0  S X0=PI(RAI) I X0]"" Q:($L(X)+$L(X0))>200  S X=X_X0_", "
  1.  I $L(X) S RAN=RAN+1,HLA("HLS",RAN)="OBX"_HLFS_HLFS_"TX"_HLFS_"A"_$E(HLECH)_"ALLERGIES"_$E(HLECH)_"L"_HLFS_HLFS_X D OBX11^RAHLRU
  1. OBXTCM ;Compile 'OBX' Segment for Tech Comment
  1.  D OBXTCM^RAHLRU
  1.  ;
  1. EXIT ; set HL7 message type & return to protocol
  1.  K ^UTILITY($J,"W")
  1.  S HL("MTN")="ORM"
  1.  N HLEID,HLARYTYP,HLFORMAT,HLMTIEN,HLP
  1.  S HLEID=EID,HLARYTYP="LM",HLFORMAT=1,HLMTIEN="",HLP("PRIORITY")="I"
  1.  D:$D(RASSSX(HLEID)) GETHLP^RAHLRS1(HLEID,.HLP,"RASSSX")
  1.  D:$D(RASSSX1(HLEID)) GETHLP^RAHLRS1(HLEID,.HLP,"RASSSX1")
  1.  D GENERATE^HLMA(HLEID,HLARYTYP,HLFORMAT,.HLRESLT,HLMTIEN,.HLP)
  1.  Q
  1. Q ;Entry Point to Process an ORR Message (Just a Quit Since No Processing is Required)
  1.  Q
  1. INIT ; initialize HL7 variables
  1.  D NOW^%DTC S HLDT=%,HLDT1=$$HLDATE^HLFNC(%)
  1.  ;Note: HLDT1 is used for HL7 fields: ORC-9 & OBR-22
  1.  Q:'$G(RAEID)  S EID=RAEID
  1.  S HL="HLS(""HLS"")",INT=1
  1.  D INIT^HLFNC2(EID,.HL,INT)
  1.  Q:'$D(HL("Q"))  ;no server application defined
  1.  S HLQ=HL("Q")
  1.  S HLECH=HL("ECH")
  1.  S HLFS=HL("FS")
  1.  S HLCS=$E(HL("ECH"))
  1.  S HLSCS=$E(HL("ECH"),4)
  1.  S HLREP=$E(HL("ECH"),2)
  1.  Q