Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RAMAIN2

RAMAIN2.m

Go to the documentation of this file. 
  1. RAMAIN2 ;HISC/GJC-Radiology Utility File Maintenance (Part Two) ;8/15/05 10:07am
  1.  ;;5.0;Radiology/Nuclear Medicine;**45,62,71,65**;Mar 16, 1998;Build 8
  1.  ; 08/12/2005 bay/kam Remedy Call 104630 Patch 62
  1.  ; 03/02/2006 BAY/KAM Remedy Call 131482 Patch RA*5*71
  1.  ; 
  1.  ;Supported IA #10141 reference to MES^XPDUTL
  1.  ;Supported IA #10142 reference to EN^DDIOL
  1.  ;Supported IA #10103 reference to DT^XLFDT
  1.  ; 
  1. 2 ;;Procedure Enter/Edit
  1.  ; *** This subroutine once resided in RAMAIN i.e, '2^RAMAIN'. ***
  1.  ; RA PROCEDURE option
  1.  N RACTIVE,RAENALL,RAY,RAFILE,RASTAT,RAXIT
  1.  S (RAENALL,RANEW71,RAXIT)=0
  1.  N RADIO,RAPTY,RAASK,RAROUTE ;used by the edit template
  1.  F  D  Q:$G(RAXIT)
  1.  . K DA,DD,DIC,DINUM,DLAYGO,DO,RACMDIFF,RATRKCMA,RATRKCMB
  1.  . S DIC="^RAMIS(71,",DIC(0)="QEAMLZ",DLAYGO=71,DIC("DR")=6
  1.  . W ! D ^DIC K D,DD,DIC,DINUM,DLAYGO,DO
  1.  . S:+Y<0 RAXIT=1 I $G(RAXIT) K D,X,Y Q
  1.  . S (DA,RADA)=+Y,RAY=Y,RAFILE=71
  1.  . ;RA*5*71 changed next line for Remedy Call 131482
  1.  . S RANEW71=$S($P(Y,U,3)=1:1,1:0) ;used in template, edit CPT Code if new rec.
  1.  . L +^RAMIS(RAFILE,RADA):5
  1.  . I '$T D  Q
  1.  .. W !?5,"This record is currently being edited by another user."
  1.  .. W !?5,"Try again later!",$C(7) S RAXIT=1
  1.  .. Q
  1.  . S RAPNM=$P($G(Y(0)),U) ;proc. name for display purposes in template
  1.  . S RACTIVE=$P($G(^RAMIS(71,RADA,"I")),"^")
  1.  . S RASTAT=$S(RACTIVE="":1,RACTIVE>DT:1,1:0)
  1.  . D TRKCMB^RAMAINU(DA,.RATRKCMB) ;tracks existing
  1.  . ; CM definition before editing. RATRKCMB ids the before CM values
  1.  . S DIE="^RAMIS(71,",DR="[RA PROCEDURE EDIT]" D ^DIE
  1.  . K RAPNM S RAPROC(0)=$G(^RAMIS(71,RADA,0))
  1.  . ;
  1.  . ;check for data consistency between the 'CONTRAST MEDIA USED' &
  1.  . ;'CONTRAST MEDIA' fields.
  1.  . D CMINTEG^RAMAINU1(RADA,RAPROC(0))
  1.  . ;
  1.  . D TRKCMA^RAMAINU(RADA,RATRKCMB,.RATRKCMA,.RACMDIFF)
  1.  . I $O(^RAMIS(71,RADA,"NUC",0)),($P(RAPROC(0),"^",2)=1) D DELRADE(RADA)
  1.  . S RACTIVE=$P($G(^RAMIS(71,RADA,"I")),"^")
  1.  . S RASTAT=RASTAT_"^"_$S(RACTIVE="":1,RACTIVE>DT:1,1:0)
  1.  . ; 08/12/2005 104630 KAM - added '$G(RANEW71) to next line
  1.  . I RAPROC(0)]"",("^B^P^"'[(U_$P(RAPROC(0),"^",6)_U)),('+$P(RAPROC(0),"^",9)),'+$G(RANEW71) D
  1.  .. K %,C,D0,DE,DI,DIE,DQ,DR
  1.  .. W !?5,$C(7),"...no CPT code entered..."
  1.  .. W !?5,"...will change type to a 'broad' procedure.",!
  1.  .. S DA=RADA,DIE="^RAMIS(71,",DR="6///B" D ^DIE
  1.  .. Q
  1.  . ;08/12/2005 104630 - KAM added next 5 lines
  1.  . I RAPROC(0)]"",("^B^P^"'[(U_$P(RAPROC(0),"^",6)_U)),('+$P(RAPROC(0),"^",9)),+$G(RANEW71) D
  1.  .. K %,C,D0,DE,DI,DIK,DQ,DR
  1.  .. W !?5,$C(7),"...no CPT code entered..."
  1.  .. W !?5,"...will delete the record at this time.",!
  1.  .. S DIK="^RAMIS(71,",DA=RADA D ^DIK K DIK
  1.  . ;if an active parent w/o descendants, inactivate the parent
  1.  . I $P(RASTAT,U,2),($P(RAPROC(0),U,6)="P"),('$O(^RAMIS(71,RADA,4,0))) D
  1.  .. K D,D0,D1,DA,DI,DIC,DIE,DQ,DR
  1.  .. W !!?5,"Inactivating this parent procedure - no descendents.",!,$C(7)
  1.  .. S DA=RADA,DIE="^RAMIS(71,",DR="100///"_$S($D(DT):DT,1:$$DT^XLFDT())
  1.  .. D ^DIE K D,D0,D1,DA,DI,DIC,DIE,DQ,DR S $P(RASTAT,U,2)=0 ;inactive
  1.  .. Q
  1.  . I $P($G(^RA(79.2,+$P(RAPROC(0),U,12),0)),U,5)="Y",(+$O(^RAMIS(71,RADA,"NUC",0))) D VRDIO(RADA)
  1.  . I "^B^P^"[(U_$P(RAPROC(0),U,6)_U),($P(RAPROC(0),U,9)]"") D
  1.  .. K %,D,D0,DA,DE,DIC,DIE,DQ,DR
  1.  .. S DA=RADA,DIE="^RAMIS(71,",DR="9///@" D ^DIE
  1.  .. W !!?5,"...CPT code deleted because "_$S($P(RAPROC(0),U,6)="B":"Broad",1:"Parent")_" procedures",!?5,"should not have CPT codes.",!,$C(7)
  1.  .. Q
  1.  . K %,%X,%Y,C,D,D0,D1,DA,DE,DI,DIE,DQ,DR,RAIMAG,RAMIS,RAPROC,X,Y
  1.  .;send Orderable Item HL7 msg to CPRS if the ORDER DIALOG (#101.41)
  1.  .;file exists unconditionally
  1.  .D:$$ORQUIK^RAORDU()=1 PROC^RAO7MFN(RAENALL,RAFILE,RASTAT,RAY)
  1.  .;
  1.  . L -^RAMIS(RAFILE,RADA) K RADA
  1.  .;unconditionally update the parent procedure if the descendent
  1.  .I $O(^RAMIS(71,"ADESC",+RAY,0)) D UPDATP^RAO7UTL(RAY)
  1.  .;has been edited
  1.  . Q
  1.  K DIR,RACMDIFF,RATRKCMA,RATRKCMB
  1.  S DIR(0)="YA",DIR("B")="NO"
  1.  S DIR("A")="Want to run a validity check on CPT and stop codes? "
  1.  S DIR("?",1)="Answer 'YES' to print a list of Radiology/Nuclear Medicine Procedures"
  1.  S DIR("?",2)="with missing or invalid CPT's and/or Credit Clinic Stop Code(s)."
  1.  S DIR("?",3)="Broad procedures with invalid codes are included for information"
  1.  S DIR("?",4)="only.  Inactive procedures are not required to have valid codes."
  1.  S DIR("?",5)="To be valid, Stop Codes must be in the Imaging Stop Codes file 71.5;"
  1.  S DIR("?",6)="CPT's must be nationally active."
  1.  S DIR("?")="Please answer 'YES' or 'NO'."
  1.  W ! D ^DIR K DIR G:$D(DIRUT) EXIT
  1.  D:Y ^RAPERR
  1. EXIT K RADA,RANEW71,X,Y
  1.  Q
  1. 13 ;;Rad/Nuc Med Common Procedure File Enter/Edit
  1.  ; RA COMMON PROCEDURE option
  1.  N RADA,RAENALL,RAY,RAFILE,RALOW,RAMIS713,RASTAT,RAIMGTYI S RAENALL=0
  1.  W ! D EN1^RAUTL17 G:Y'>0 Q13 S RAIMGTYI=Y
  1. 131 S DIC="^RAMIS(71.3,",DIC(0)="AELMQZ",DLAYGO=71.3
  1.  S DIC("S")="N RA S RA=+$P(^(0),U) I RAIMGTYI=$P($G(^RAMIS(71,RA,0)),U,12)"
  1.  S DIC("W")="N RA4 S RA4=$P($G(^(0)),""^"",4) W:RA4]"""" ""   (""_RA4_"")"" W:RA4']"""" ""   (no sequence number)"""
  1.  W ! D ^DIC K DIC,DLAYGO,D,X
  1.  I Y<0 D Q13 G RESEQ
  1.  ; If a sequence # exists, the Common Proc. is active
  1.  S RADA=+Y,RAY=Y,RAFILE=71.3 L +^RAMIS(RAFILE,RADA):5
  1.  I '$T D  G Q13
  1.  . W !?5,"This record is currently being edited by another user."
  1.  . W !?5,"Try again later!",$C(7)
  1.  . Q
  1.  S RASTAT=$S($P(Y(0),"^",4)]"":1,1:0)_"^"
  1.  I '+$P(RASTAT,"^") S RALOW=$$LOW(RAIMGTYI)
  1.  S DA=RADA,DIE="^RAMIS(71.3,",DR="[RA COMMON PROCEDURE EDIT]" D ^DIE
  1.  S RAMIS713(0)=$G(^RAMIS(71.3,RADA,0))
  1.  ; If the procedure is different than the one originally selected and
  1.  ; the CPRS Order Dialog file exists, send the Orderable Item Update
  1.  ; message to CPRS.
  1.  I $P(RAMIS713(0),"^")'=$P(RAY,"^",2),($$ORQUIK^RAORDU()=1) D
  1.  . S RASTAT=RASTAT_0 D PROC^RAO7MFN(RAENALL,RAFILE,RASTAT,RAY)
  1.  . S RAY=RADA_"^"_$P($G(^RAMIS(71.3,RADA,0)),"^")_"^"_1,RASTAT=0_"^"
  1.  . Q
  1.  K %,%X,%Y,C,D,D0,DA,DE,DI,DIE,DQ,DR,X,Y
  1.  S RASTAT=RASTAT_$S($P($G(^RAMIS(71.3,+RAY,0)),"^",4)]"":1,1:0)
  1.  ; If before & after statuses differ, and the CPRS Order Dialog file
  1.  ; exists, send the Orderable Item Update message to CPRS.
  1.  I $$ORQUIK^RAORDU()=1,(($P(RASTAT,"^")+$P(RASTAT,"^",2))=1) D
  1.  . D PROC^RAO7MFN(RAENALL,RAFILE,RASTAT,RAY)
  1.  . Q
  1.  L -^RAMIS(RAFILE,RADA)
  1.  G 131
  1. Q13 K DDC,DDH,DISYS,I,POP,RA713
  1.  Q
  1. RESEQ ;Resequence the common procedure list
  1.  N D,D0,DI,DQ,H,I,J,CNT,DIC,DIE,DR,DA,TXT,X
  1.  I $D(XPDNM) D  ; if called during package install
  1.  . S TXT(1)=" "
  1.  . S TXT(2)="Resequencing the Rad/Nuc Med Common Procedure List."
  1.  . Q
  1.  E  W !!?5,"Resequencing the Rad/Nuc Med Common Procedure List"
  1.  S DIE="^RAMIS(71.3,",(I,CNT)=0
  1.  F  S I=$O(^RAMIS(71.3,"AA",RAIMGTYI,I)) Q:I'>0  D
  1.  . S J=0
  1.  . F  S J=$O(^RAMIS(71.3,"AA",RAIMGTYI,I,J)) Q:J'>0  I $D(^RAMIS(71.3,J,0)) D
  1.  .. S DA=J,CNT=CNT+1 N I,J
  1.  .. S DR="3////^S X=CNT" D ^DIE W:'$D(XPDNM) "."
  1.  .. Q
  1.  . Q
  1.  I $D(XPDNM) D  ; if called during package install
  1.  . S TXT(2)=$G(TXT(2))_"  Done!"
  1.  . D MES^XPDUTL(.TXT)
  1.  . Q
  1.  E  W "  Done!"
  1.  Q
  1. LOW(X) ; Find the lowest available sequence number for a procedure within
  1.  ; a specific Imaging Type.  Seq. #'s range from 1 to 40.  If the
  1.  ; range changes in the DD i.e, ^DD(71.3,3, this code as well as the 
  1.  ; code if EN3^RAUTL18 must also be altered.
  1.  ; If RAHIT is passed back as "", there is no available sequence number.
  1.  N RA,RAHIT S RAHIT=""
  1.  F RA=1:1:40 D  Q:RAHIT
  1.  . Q:$D(^RAMIS(71.3,"AA",X,RA))
  1.  . S:RAHIT="" RAHIT=RA
  1.  . Q
  1.  Q RAHIT
  1. VRDIO(RADA) ; Validate the 'Usual Dose' field within the 'Default Radiopha-
  1.  ; rmaceuticals' multiple.  'Usual Dose' must fall within the 'Low Adult
  1.  ; Dose' & 'High Adult Dose' range.  This subroutine will display the
  1.  ; Radiopharmaceutical in question along with the values in question if
  1.  ; inconsistencies are found.
  1.  ;
  1.  ; Input Variable: 'RADA' the ien of the Procedure
  1.  N RANUC S RADA(1)=RADA,RADA=0 D EN^DDIOL("","","!")
  1.  F  S RADA=$O(^RAMIS(71,RADA(1),"NUC",RADA)) Q:RADA'>0  D
  1.  . S RANUC(0)=$G(^RAMIS(71,RADA(1),"NUC",RADA,0))
  1.  . Q:$P(RANUC(0),"^",2)=""  ; no need to validate, nothing input
  1.  . I '$$USUAL^RADD2(.RADA,$P(RANUC(0),"^",2)) D
  1.  .. N RARRY S RARRY(1)="For Radiopharmaceutical: "
  1.  .. S RARRY(1)=RARRY(1)_$$EN1^RAPSAPI(+$P(RANUC(0),"^"),.01)_$C(7)
  1.  .. S RARRY(2)="" D EN^DDIOL(.RARRY,"")
  1.  .. Q
  1.  . Q
  1.  Q
  1. DELRADE(RADA) ; Delete the Default Radiopharmaceuticals multiple 
  1.  N RADA1 S RADA1=0
  1.  W !!?3,"Deleting default radiopharmaceuticals for this procedure...",!
  1.  F  S RADA1=$O(^RAMIS(71,RADA,"NUC",RADA1)) Q:RADA1'>0  D
  1.  . K %,%X,%Y,D,D0,DA,DI,DIC,DIE,DQ,DR,X,Y
  1.  . S DA(1)=RADA,DA=RADA1,DIE="^RAMIS(71,"_RADA_",""NUC"","
  1.  . S DR=".01///@" D ^DIE
  1.  . Q
  1.  K %,%X,%Y,D,D0,DA,DI,DIC,DIE,DQ,DR,X,Y
  1.  Q
  1.  ;