Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCCVCST5

SCCVCST5.m

Go to the documentation of this file. 
  1. SCCVCST5 ;ALB/TMP - Scheduling Conversion Template Utilities - CST; APR 20, 1998
  1.  ;;5.3;Scheduling;**211,1015**;Aug 13, 1993;Build 21
  1.  ;
  1. VAL1(SCCVEVT,SCFILE,SCCVDA,SCMULT) ;Validate that entry selected can be converted
  1.  ;
  1.  N OK,DATA,SCERR,SCCLN,ENC,SCF
  1.  S OK=0,DATA=$G(@SCFILE@(SCCVDA,0))
  1.  S SCF=SCFILE
  1.  ;
  1.  I DATA="" S SCERR=1 G VAL1Q
  1.  ;
  1.  I SCFILE["SCE" D  G:$G(SCERR)!(SCF["SDV") VAL1Q
  1.  . ; Encounter - change SCF,SCCVDA,DATA for enctr type
  1.  . I DATA>SCCVACRP S SCERR=2 Q  ;Date must be before 10-1-96
  1.  . I SCCVEVT=1,$P(DATA,U,5) S SCERR=3 Q  ;Can't already have a visit
  1.  . I SCCVEVT=2,'$P($G(^SCE(SCCVDA,"CNV")),U,4) S SCERR=8 Q  ;Must be converted to reconvert
  1.  . I $P(DATA,U,6)!($P(DATA,U,8)>3) S SCERR=4 Q  ;Can't convert a child encounter
  1.  . S SCF=$$SETFL^SCCVCST3($P(DATA,U,8),SCCVDFN)
  1.  . I SCF["SDV" S OK=1 Q  ;No further checks needed for A/E
  1.  . S SCCVDA=+DATA
  1.  . S:SCF["""DIS""" SCCVDA=9999999-SCCVDA
  1.  . S DATA=$G(@SCF@(SCCVDA,0))
  1.  . S:DATA="" SCERR=1
  1.  ;
  1.  I SCF["""DIS""" D  G VAL1Q ; Disposition
  1.  . I SCCVEVT=2 S ENC=$P(DATA,U,18) D  Q
  1.  .. I '$P(DATA,U,19)!'$P($G(^SCE(ENC,"CNV")),U,4) S SCERR=8 Q  ;Must be converted to reconvert
  1.  .. S OK=1
  1.  . ;
  1.  . I SCCVEVT=1,$P(DATA,U,18),$P($G(^SCE(+$P(DATA,U,18),0)),U,5) S SCERR=3 Q
  1.  . IF SCCVEVT=1,$$REQ^SDM1A(+DATA)="CO",'$P($G(^SCE(+$P(DATA,U,18),0)),U,7) S SCERR=9 Q  ; Must be checked out
  1.  . I $P(DATA,U,2)=2 S SCERR=5 Q  ;Must be dispositioned properly
  1.  . S OK=1
  1.  ;
  1.  I SCF["""S""" D  G VAL1Q  ; Appt
  1.  . I SCCVEVT=2 S ENC=+$P(DATA,U,20) D  Q
  1.  .. I '$P(DATA,U,23)!'$P($G(^SCE(ENC,"CNV")),U,4) S SCERR=8 Q  ;Must be converted to reconvert
  1.  .. S OK=1
  1.  . ;
  1.  . I SCCVEVT=1,$P(DATA,U,20),$P($G(^SCE(+$P(DATA,U,20),0)),U,5) S SCERR=3 Q
  1.  . IF SCCVEVT=1,$$REQ^SDM1A(SCCVDA)="CO",'$P($G(^SCE(+$P(DATA,U,20),0)),U,7) S SCERR=9 Q  ; Must be checked out
  1.  . I $P(DATA,U,2)'="",$P(DATA,U,2)'="I",$P(DATA,U,2)'="NT" S SCERR=6 Q  ; Can't be 'unfinished' status
  1.  . I $P($G(^SC(+DATA,0)),U,3)'="C" S SCERR=7 Q  ;Must be clinic
  1.  . S OK=1
  1.  ;
  1.  I SCF["SDV",SCF=SCFILE D  G VAL1Q ; Full standalone add/edit
  1.  . N SCCS,DATA1,STAT
  1.  . S SCCS=0 F  S SCCS=$O(@SCF@(SCCVDA,"CS",SCCS)) Q:'SCCS  S DATA1=$G(^(SCCS,0)) W "." D  Q:OK
  1.  .. S ENC=+$P(DATA1,U,8)
  1.  .. ; In 'CS' nodes at least one entry must:
  1.  .. ;    - be a non-child encounter (error 4)
  1.  .. ;    - have no encounter or no visit if converting (error 3)
  1.  .. ;    - have already been converted if reconverting (error 8)
  1.  .. ;    - must be checked out if requred              (error 9)
  1.  .. ;
  1.  .. S STAT=0
  1.  .. IF 'STAT,$P($G(^SCE(ENC,0)),U,6) S STAT=4 ; -- not child check
  1.  .. ;
  1.  .. IF 'STAT,SCCVEVT=1 D
  1.  ... IF 'ENC Q                                ; -- no encounter check
  1.  ... IF $P($G(^SCE(ENC,0)),U,5) S STAT=3 Q    ; -- no visit check
  1.  .. ;
  1.  .. IF 'STAT,SCCVEVT'=1 D
  1.  ... IF '$P($G(^SCE(ENC,"CNV")),U,4)!'$P(DATA1,U,9) S STAT=8 ; -- must be already converted check
  1.  .. ;
  1.  .. IF 'STAT,$$REQ^SDM1A(SCCVDA)="CO",'$P($G(^SCE(+ENC,0)),U,7) S STAT=9 ; -- must be checked out check
  1.  .. ;
  1.  .. I 'STAT K SCERR S OK=1 Q  ; -- at least one node passes
  1.  .. S SCERR(STAT)=""
  1.  ;
  1. VAL1Q I $G(SCMULT) K SCERR
  1.  I $D(SCERR) D DISPERR^SCCVCST4(.SCERR,SCF) S OK=0
  1.  Q OK
  1.  ;