Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCCVEGD1

SCCVEGD1.m

Go to the documentation of this file. 
  1. SCCVEGD1 ;ALB/JRP,TMP - DSPLY RSLTS 4 ENCNTR CNVRSN GLBL ESTMTR;15-JAN-96
  1.  ;;5.3;Scheduling;**211,1015**;Aug 13, 1993;Build 21
  1. DSPGLBL(PTRLOG,OUTARRAY,STARTLN) ;BUILD DISPLAY FOR GLOBAL ESTIMATES
  1.  ;INPUT  : PTRLOG - Pointer to entry in SCHEDULING CONVERSION LOG
  1.  ;                  file (#404.98) that estimation is for
  1.  ;         OUTARRAY - Array to build display into (full global reference)
  1.  ;                      Defaults to ^TMP("SCCVEG",$J,"DISPLAY")
  1.  ;         STARTLN - The line # in the display where this portion starts
  1.  ;                   [optional]
  1.  ;OUTPUT : N - Number of lines in this display
  1.  ;         OUTARRAY will be returned as follows
  1.  ;           OUTARRAY(x,0) = Line x of display
  1.  ;
  1.  N ESTGLBL,GLOBAL,INFO,EQUALS,LINE,HEADER,FOOTER,TMP,DASHES,SD0,TOTAL
  1.  N DIC,X,DA,DR,DIQ,SCBLK,SC207
  1.  ;
  1.  Q:('$D(^SD(404.98,+$G(PTRLOG),0))) 0
  1.  ;
  1.  S:$G(OUTARRAY)="" OUTARRAY="^TMP(""SCCVEG"","_$J_",""DISPLAY"")"
  1.  S LINE=+$G(STARTLN)
  1.  S DASHES="",$P(DASHES,"-",81)="",EQUALS="",$P(EQUALS,"=",81)=""
  1.  ;
  1.  S TMP=$G(^SD(404.98,PTRLOG,2)),SD0=$G(^(0))
  1.  S TOTAL("SCE","NEW")=+$P(TMP,"^",7)
  1.  S TOTAL("SCE","UPD")=$P(TMP,"^",8)-$P(TMP,"^",7)
  1.  S TOTAL("AUPNVSIT")=+$P(TMP,"^",8)
  1.  S TOTAL("AUPNVPRV")=+$P(TMP,"^",9)
  1.  S TOTAL("AUPNVPOV")=+$P(TMP,"^",10)
  1.  S TOTAL("AUPNVCPT")=+$P(TMP,"^",11)
  1.  ;
  1.  ;Get estimated global growths
  1.  S DIC=404.98,DR="207:211",DIQ="ESTGLBL",DIQ(0)="IE",DA=PTRLOG
  1.  D EN^DIQ1
  1.  ;
  1.  S HEADER(1)="+"_$E(EQUALS,1,54)_"+"
  1.  S TMP=$$CENTER^SCCVEGU0("ESTIMATED GLOBAL BLOCK GROWTH",54)
  1.  S HEADER(2)="|"_TMP_"|"
  1.  S TMP=$$CENTER^SCCVEGU0($$FMTE^XLFDT($P(SD0,U,3),"5Z")_" - "_$$FMTE^XLFDT($P(SD0,U,4),"5Z"),54)
  1.  S HEADER(3)="|"_TMP_"|",HEADER(4)="|"_$E(DASHES,1,54)_"|",HEADER(5)="|"
  1.  S HEADER(6)="+"
  1.  F TMP=1:1:5 S HEADER(6)=HEADER(6)_$E(EQUALS,1,10)_"+"
  1.  ;
  1.  S FOOTER(1)="+"
  1.  F TMP=1:1:5 S FOOTER(1)=FOOTER(1)_$E(EQUALS,1,10)_"+"
  1.  ;
  1.  ;Build display for global estimates
  1.  S INFO="|"
  1.  F X=207:1:211 D
  1.  . S INFO=INFO_" "_$J(+$G(ESTGLBL(404.98,PTRLOG,X,"E")),8,0)_" |"
  1.  F X="SCE","AUPNVSIT","AUPNVPRV","AUPNVPOV","AUPNVCPT" D
  1.  . S HEADER(5)=HEADER(5)_$$CENTER^SCCVEGU0(X,10)_"|"
  1.  ;
  1.  ;Put lines into display
  1.  F TMP=1:1 Q:('$D(HEADER(TMP)))  S LINE=LINE+1,@OUTARRAY@(LINE,0)=HEADER(TMP)
  1.  S LINE=LINE+1,@OUTARRAY@(LINE,0)=INFO
  1.  F TMP=1:1 Q:('$D(FOOTER(TMP)))  S LINE=LINE+1,@OUTARRAY@(LINE,0)=FOOTER(TMP)
  1.  ;
  1.  ; ending text
  1.  ;
  1.  S FOOTER="**"_$J("",52)_"**"
  1.  S TMP=" The estimate algorithm factors in global"
  1.  S LINE=LINE+1,@OUTARRAY@(LINE,0)=$$INSERT^SCCVEGU0(TMP,FOOTER,5)
  1.  S TMP=" pointer data and data requirements (including"
  1.  S LINE=LINE+1,@OUTARRAY@(LINE,0)=$$INSERT^SCCVEGU0(TMP,FOOTER,5)
  1.  S TMP=" cross references) at a 70% efficiency level."
  1.  S LINE=LINE+1,@OUTARRAY@(LINE,0)=$$INSERT^SCCVEGU0(TMP,FOOTER,5)
  1.  S SCBLK=$$BLKSIZE^SCCVEGU1()
  1.  S SC207=+$G(ESTGLBL(404.98,PTRLOG,207,"E"))
  1.  S TMP=" Each block represents "_SCBLK_" bytes."
  1.  S LINE=LINE+1,@OUTARRAY@(LINE,0)=$$INSERT^SCCVEGU0(TMP,FOOTER,5)
  1.  S TMP=" SCE Example: "_SC207_" x "_SCBLK_" = "_$FN(SC207*SCBLK,",")_" bytes."
  1.  S LINE=LINE+1,@OUTARRAY@(LINE,0)=$$INSERT^SCCVEGU0(TMP,FOOTER,5)
  1.  S LINE=LINE+1,@OUTARRAY@(LINE,0)="+"_$E(EQUALS,1,54)_"+"
  1.  ;
  1.  Q (LINE-STARTLN)
  1.  ;