Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCMRTPM

SCMRTPM.m

Go to the documentation of this file. 
  1. SCMRTPM ;ALB/REW/PDR/cmf - Patient Position Changes MailMessages ; nov 1998
  1.  ;;5.3;Scheduling;**148,157,1015**;AUG 13, 1993;Build 21
  1.  ;
  1.  ;
  1. MAILLST(SCTP,SCFIELDA,SCDATE,SCBADTP,SCFTP)   ;
  1.  ; Input:
  1.  ;    SCTP     - Pointer to Team Position File (#404.57)
  1.  ;    SCFIELDA - Field array with internal values
  1.  ;    SCDATE   - Effective Date
  1.  ;    SCBADTP  - DFN array of patients unassignable to position
  1.  ;    SCFTP    - Pointer to 404.57 ('from' team ien)
  1.  ;
  1.  G:$G(SCNOMAIL) QTMULT  ;- flag can be set to stop message generation
  1.  G:'$D(SCBADTP) QTMULT
  1.  G:'$O(@SCBADTP@(0)) QTMULT  ;if no BAD REassignments
  1.  N XMDUZ,XMY,XMSUB,XMTEXT,VA,VAERR,XMZ,Y,SCTPDT,ZTQUEUED
  1.  N DFN,SCOK,SCPTNM,SCFLD,SCNODE,SCNDX,SCSPACE,SCE,SCB
  1.  N SCTPNM,SCTMNM,SCFTPNM,SCFTMNM,SCDELTEM,SCDETAIL
  1.  S ZTQUEUED=1
  1.  S DELTEM=1 ;ok to delete tmp global
  1.  S $P(SCSPACE," ",80)=""
  1.  S XMSUB="Multiple PATIENT-POSITION REASSIGNMENT FAILURES for "_$$POSNAME(+SCTP)
  1.  S XMTEXT="^TMP($J,""SCTPXM"","
  1.  S SCLNCNT=0
  1.  S SCOK=1
  1.  D SETLN("Team:                  "_$$TMNAME(+SCTP))
  1.  D SETLN("Position:              "_$$POSNAME(+SCTP))
  1.  D SETLN("Effective Date:        "_$$FMTE^XLFDT(SCDATE))
  1.  D SETLN("Total Processed:       "_$$PASSCNT^SCMCBK5(DFNA))
  1.  D SETLN("From Team:             "_$$TMNAME(+SCFTP))
  1.  D SETLN("From Position:         "_$$POSNAME(+SCFTP))
  1.  D SETLN(" ")
  1.  IF $D(SCFIELDA) D
  1.  .F SCNDX=1:1:14 S SCFLD=SCNDX*.01 IF $D(SCFIELDA(SCFLD)) D
  1.  ..S $P(SCNODE,U,SCNDX)=SCFIELDA(SCFLD)
  1.  ..D SETLN($$TEXT(404.43,SCNODE,SCNDX,SCSPACE,1))
  1.  D SETLN(" ")
  1. BAD IF $O(@SCBADTP@(0)) D
  1.  .D SETLN(" ")
  1.  .;;D SETLN("There has been NO new position reassignment for the following patients:")
  1.  .D SETLN("The following position reassignments did not complete processing:")
  1.  .S DFN=0
  1.  .F  S DFN=$O(@SCBADTP@(DFN)) Q:'DFN  D
  1.  ..S SCPTNM=$P(^DPT(DFN,0),U,1)
  1.  ..D PID^VADPT6
  1.  ..S ^TMP("SCTP MAIL LST",$J,SCTP,2,DFN)=(" "_SCPTNM_" ("_$G(VA("PID"))_")")
  1.  ..S ^TMP("SCTP MAIL LST",$J,SCTP,3,DFN)=" "_@SCBADTP@(DFN)
  1.  ..S ^TMP("SCTP MAIL LST",$J,SCTP,2,"B",SCPTNM,DFN)=""
  1.  .S SCPTNM=""
  1.  .F  S SCPTNM=$O(^TMP("SCTP MAIL LST",$J,SCTP,2,"B",SCPTNM)) Q:SCPTNM']""  D
  1.  ..S DFN=0
  1.  ..F  S DFN=$O(^TMP("SCTP MAIL LST",$J,SCTP,2,"B",SCPTNM,DFN)) Q:'DFN  D
  1.  ...S SCDETAIL=$G(^TMP("SCTP MAIL LST",$J,SCTP,2,DFN)) Q:SCDETAIL']""  D SETLN(SCDETAIL)
  1.  ...S SCDETAIL=$G(^TMP("SCTP MAIL LST",$J,SCTP,3,DFN)) Q:SCDETAIL']""  D SETLN(SCDETAIL)
  1.  S XMDUZ="PCMM Reassignment"
  1.  K XMY S XMY(DUZ)=""
  1.  S SCX=$O(^SD(404.91,"B",0))_","
  1.  I +SCX S XMY("G."_$$GET1^DIQ(404.91,SCX,804))=""
  1.  D ^XMD
  1. QTMULT  K:$G(SCDELTEM) ^TMP("SCTP MAIL LST",$J,SCTP)
  1.  K ^TMP($J,"SCTPXM")
  1.  Q
  1.  ;
  1.  ;----------------------------- subs ------------------------------------
  1.  ;
  1. SETLN(TEXT)     ;
  1.  Q:$G(TEXT)=""
  1.  ; increments SCLNCNT, adds text to scTPxm(sclncnt)
  1.  S SCLNCNT=SCLNCNT+1
  1.  S ^TMP($J,"SCTPXM",SCLNCNT)=TEXT
  1.  Q
  1.  ;
  1. TEXT(SCFILE,SCNODE,SCPC,SCSPACE,SCLAB)  ;returns fldname & external value
  1.  ;returns fldname & external value
  1.  ;   Note- Only works for non wp fields of standard numbering conventions
  1.  ;   SCFLILE =FILENUM
  1.  ;   SCNODE  = 0 NODE
  1.  ;   SCPC    = piece of node
  1.  ;   SCSPACE = 80 SPACES
  1.  ;   SCLAB = 1 if print field name
  1.  N SCX,SCINT,SCFLD
  1.  S SCX=""
  1.  S SCINT=$P(SCNODE,U,SCPC)
  1.  G:SCINT="" QTTXT
  1.  S SCFLD=SCPC*.01
  1.  ;;;
  1.  IF $G(SCLAB) D
  1.  .S SCX=$$DDNAME^SCMCRU(SCFILE,SCFLD)_":"
  1.  .S:$G(SCLAB)=1 SCX=SCX_$E(SCSPACE,1,(27-$L(SCX)))
  1.  .S:$G(SCLAB)=2 SCX=SCX_$E(SCSPACE,1,(52-$L(SCX)))
  1.  S:SCINT]"" SCX=SCX_$$EXTERNAL^DILFD(SCFILE,SCFLD,"",SCINT)
  1. QTTXT   Q SCX
  1.  ;
  1. DDNAME(FILE,FIELD)      ;return the fieldname
  1.  N SCX
  1.  D FIELD^DID(FILE,FIELD,"","LABEL","SCX")
  1.  Q $G(SCX("LABEL"))
  1.  ;
  1. POSNAME(SCX) ; return position external name
  1.  Q $P($G(^SCTM(404.57,+SCX,0)),U)
  1.  ;
  1. TMNAME(SCX) ; return team external name
  1.  Q $P($G(^SCTM(404.51,+$P($G(^SCTM(404.57,+SCX,0)),U,2),0)),U)
  1.  ;
  1.