Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SDAMA201

SDAMA201.m

Go to the documentation of this file. 
  1. SDAMA201 ;BPOIFO/ACS-Scheduling Replacement APIs ; 12/13/04 3:14pm
  1.  ;;5.3;Scheduling;**253,275,283,316,347,1015**;13 Aug 1993;Build 21
  1.  ;
  1.  ;GETAPPT  - Returns appointment information for a patient
  1.  ;NEXTAPPT - Returns next appointment information for a patient
  1.  ;
  1.  ;**   BEFORE USING THE APIS IN THIS ROUTINE, PLEASE SUBSCRIBE   **
  1.  ;**   TO DBIA #3859                                             **
  1.  ;
  1.  ;*****************************************************************
  1.  ;              CHANGE LOG
  1.  ;
  1.  ;  DATE      PATCH       DESCRIPTION
  1.  ;--------  ----------    -----------------------------------------
  1.  ;09/20/02  SD*5.3*253    ROUTINE COMPLETED
  1.  ;12/10/02  SD*5.3*275    ADDED PATIENT STATUS FILTER
  1.  ;07/03/03  SD*5.3*283    REMOVED 'NO ACTION TAKEN' EDIT
  1.  ;09/16/03  SD*5.3*316    CHANGED 'NEXTAPPT' TO START LOOKING 'NOW'
  1.  ;07/26/04  SD*5.3*347    NEW VARIABLES USED IN ^%DTC CALL.
  1.  ;                        NEXTAPPT TO GET DATA FROM SDAPI NOT VISTA.
  1.  ;                        GETAPPT WILL RETRIEVE APPT DATA THROUGH
  1.  ;                        SDAPI API.  PATIENT STATUS TO OVERWRITE 
  1.  ;                        APPOINTMENT STATUS OF "R" OR "R;I".
  1.  ;                        GETAPPT CALLS GETAPPT^SDAMA205.
  1.  ;
  1.  ;*****************************************************************
  1. GETAPPT(SDPATIEN,SDFIELDS,SDAPSTAT,SDSTART,SDEND,SDRESULT,SDIOSTAT) ;
  1.  ;*****************************************************************
  1.  ;
  1.  ;               GET APPOINTMENTS FOR PATIENT
  1.  ;
  1.  ;INPUT
  1.  ;  SDPATIEN     Patient IEN (required)
  1.  ;  SDFIELDS     Fields requested (optional)
  1.  ;  SDAPSTAT     Appointment Status Filter (optional)
  1.  ;  SDSTART      Start date/time (optional)
  1.  ;  SDEND        End date/time (optional)
  1.  ;  SDRESULT     Record count returned here (optional)
  1.  ;  SDIOSTAT     Patient Status filter (optional)
  1.  ;  
  1.  ;OUTPUT
  1.  ;  ^TMP($J,"SDAMA201","GETAPPT",X,Y)=FieldYdata
  1.  ;  where "X" is an incremental appointment counter and
  1.  ;  "Y" is the field number requested
  1.  ;  
  1.  ;*****************************************************************
  1.  ; Call API to Get Appointment(s) for Patient.
  1.  D GETAPPT^SDAMA205(.SDPATIEN,.SDFIELDS,.SDAPSTAT,.SDSTART,.SDEND,.SDRESULT,.SDIOSTAT)
  1.  Q
  1.  ;
  1. NEXTAPPT(SDPATIEN,SDFIELDS,SDAPSTAT,SDIOSTAT) ;
  1.  ;*****************************************************************
  1.  ;
  1.  ;               GET NEXT APPOINTMENT FOR PATIENT
  1.  ;
  1.  ; This API should be called with an EXTRINISIC call.  It will
  1.  ; return "-1" if an error occurs, "1" if a future appointment
  1.  ; exists, or "0" if no future appointment exists.  If the user
  1.  ; enters field numbers into the optional SDFIELDS parameter and a
  1.  ; next appointment is found, the requested fields for that next
  1.  ; appointment will be retrieved and put into: 
  1.  ; ^TMP($J,"SDAMA201","NEXTAPPT")
  1.  ;
  1.  ;INPUT
  1.  ;  SDPATIEN     Patient IEN (required)
  1.  ;  SDFIELDS     Fields requested (optional)
  1.  ;  SDAPSTAT     Appointment status filter (optional)
  1.  ;  SDIOSTAT     Patient status filter (optional)
  1.  ;
  1.  ;OUTPUT
  1.  ;  -1: error
  1.  ;   0: no future appointment
  1.  ;   1: future appointment exists
  1.  ;
  1.  ;  If "1" is returned and the user has requested fields in the 
  1.  ;  SDFIELDS  parameter, the following global is populated:
  1.  ;  ^TMP($J,"SDAMA201","NEXTAPPT",Y)=FieldYdata
  1.  ;  where "Y" is the field number requested
  1.  ;  
  1.  ;*****************************************************************
  1.  N SDAPINAM,SDRTNNAM,SDSTART,SDRESULT,%,%H,%I,X
  1.  S SDAPINAM="NEXTAPPT",SDRTNNAM="SDAMA201",SDRESULT=0
  1.  K ^TMP($J,SDRTNNAM,SDAPINAM)
  1.  ;
  1.  ;Validate input parameters
  1.  S SDRESULT=$$VALIDATE^SDAMA200(.SDPATIEN,.SDFIELDS,.SDAPSTAT,,,SDAPINAM,SDRTNNAM,.SDIOSTAT)
  1.  I SDRESULT=-1 Q -1
  1.  ;
  1.  ;Get current date/time
  1.  D NOW^%DTC
  1.  S SDSTART=$E(%,1,12)
  1.  ;GET NEXT APPOINTMENT DATA
  1.  ;If an appt was found and the user wants data returned, get fields requested
  1.  N SDICN,SDARRAY,SDCOUNT,SDAPLST,SDI,SDTMP,SDNUM,SDERR,SDFLDCNT,SDR,SDFLD,SD310
  1.  N SDAPT,SDCLN,SDFFLD,SDFS
  1.  S SDAPLST=""
  1.  ;
  1.  S SDARRAY(1)=SDSTART ; set searchpoint to current date/time
  1.  ; Translate and set up Appointment Status List
  1.  I $L($G(SDAPSTAT))>0 D
  1.  . ;Remove a leading and a trailing semicolon
  1.  . I $E(SDAPSTAT,$L(SDAPSTAT))=";" S SDAPSTAT=$E(SDAPSTAT,1,($L(SDAPSTAT)-1))
  1.  . I $E(SDAPSTAT)=";" S SDAPSTAT=$E(SDAPSTAT,2,$L(SDAPSTAT))
  1.  . ;IO/Appt Statuses have been validated by SDAMA200 to be I or O/R NT
  1.  . I $L($G(SDIOSTAT))=1 S SDAPLST=$S(SDIOSTAT="I":"I;",SDIOSTAT="O":SDAPSTAT_";")
  1.  . I $L($G(SDIOSTAT))'=1 D
  1.  .. ;Reset appointment status R=R;I C=CC;CP;CCR;CPR N=NS,NSR
  1.  .. S SDNUM=$L(SDAPSTAT,";") F SDI=1:1:SDNUM D
  1.  ... S SDTMP=$P(SDAPSTAT,";",SDI)
  1.  ... S SDTMP=$S(SDTMP="R":"R;I",SDTMP="C":"CC;CP;CCR;CPR",SDTMP="N":"NS;NSR",1:SDTMP)
  1.  ... S SDAPLST=SDAPLST_SDTMP_";"
  1.  . S SDARRAY(3)=$E(SDAPLST,1,($L(SDAPLST)-1)) ; Axe trailing semicolon
  1.  S SDARRAY(4)=SDPATIEN
  1.  S SDARRAY("MAX")=1
  1.  ; Must request at least 1 field, will ask for date/time which is field 1
  1.  S SDFIELDS=$G(SDFIELDS),(SDFFLD,SDFIELDS)=$S(SDFIELDS'="":SDFIELDS,1:1)
  1.  ; Strip out field 12 if it exists, replace with 3 if 3 is not already there
  1.  ; If we have both 3 and 12 in the field list, remove the 12 and a semicolon
  1.  I (";"_SDFIELDS_";")[";12;",((";"_SDFIELDS_";")[";3;") D
  1.  . S SDNUM=$L(SDFFLD,";"),SDI=$F(SDFFLD,12)
  1.  . I SDI=3 S SDFFLD=$E(SDFFLD,4,$L(SDFFLD)) Q
  1.  . S SDFFLD=$E(SDFFLD,1,(SDI-4))_$E(SDFFLD,SDI,$L(SDFFLD))
  1.  I ((";"_SDFIELDS_";")[";12;")&((";"_SDFIELDS_";")'[";3;") S SDNUM=$L(SDFFLD,";") D
  1.  . F SDI=1:1:SDNUM S SDR=$P(SDFFLD,";",SDI) I SDR=12 S $P(SDFFLD,";",SDI)=3 Q
  1.  ;
  1.  S SDARRAY("FLDS")=$S(SDFFLD'="":SDFFLD,1:1)
  1.  F SDI=1:1 S SDTMP=$P(SDFIELDS,";",SDI) Q:SDTMP=""  S SDFS(SDTMP)=SDI
  1.  ; Setup done, call SDAPI, quit if no appointment (SDCOUNT=0) and return 0
  1.  S SDCOUNT=$$SDAPI^SDAMA301(.SDARRAY) Q:SDCOUNT=0 0
  1.  ;If we have an appointment, process it
  1.  I SDCOUNT=1,SDFIELDS'="" S SDFLDCNT=$L(SDFIELDS,";") D:SDPATIEN'=""
  1.  . ;If malformed appointment data, set SDCOUNT to 0, quit
  1.  . S SDCLN=$O(^TMP($J,"SDAMA301",SDPATIEN,"")) I SDCLN="" S SDCOUNT=0 Q
  1.  . S SDAPT=$O(^TMP($J,"SDAMA301",SDPATIEN,SDCLN,"")) I SDAPT="" S SDCOUNT=0 Q
  1.  . S SD310=$G(^TMP($J,"SDAMA301",SDPATIEN,SDCLN,SDAPT)) I SD310="" S SDCOUNT=0 Q
  1.  . S SDTMP="" F SDI=1:1:SDFLDCNT S SDTMP=$O(SDFS(SDTMP)) Q:SDTMP=""  D
  1.  .. I "^1^5^9^11^"[(U_SDTMP_U) S ^TMP($J,"SDAMA201","NEXTAPPT",SDTMP)=$P(SD310,U,SDTMP) Q
  1.  .. I "^2^4^8^10^"[(U_SDTMP_U) S ^TMP($J,"SDAMA201","NEXTAPPT",SDTMP)=$TR($P(SD310,U,SDTMP),";","^") Q
  1.  .. I SDTMP=7 S ^TMP($J,"SDAMA201","NEXTAPPT",SDTMP)=$S($P(SD310,"^",SDTMP)="":"N",1:$P(SD310,"^",SDTMP)) Q
  1.  .. S SDFLD="FLD"_SDTMP
  1.  .. I "^3^6^12^"[(U_SDTMP_U) D @(SDFLD)
  1.  ;If err, set up err node
  1.  I SDCOUNT=-1 D
  1.  . S SDERR=$O(^TMP($J,"SDAMA301",""))
  1.  . S SDERR=$S(SDERR=101:101,SDERR=115:114,SDERR=116:114,1:117)
  1.  . D ERROR^SDAMA200(SDERR,"NEXTAPPT",0,"SDAMA201")
  1.  K ^TMP($J,"SDAMA301")
  1.  Q SDCOUNT
  1.  ;Xlate output from SDAPI as required
  1. FLD3 S SDR=$P($P(SD310,U,SDTMP),";",1)
  1.  S SDR=$S(SDR="I":"R",SDR?1(1"CC",1"CP",1"CPR"):"C",SDR?1(1"NS",1"NSR"):"N",1:SDR)
  1.  S ^TMP($J,"SDAMA201","NEXTAPPT",SDTMP)=SDR Q
  1. FLD6 S SDR=$G(^TMP($J,"SDAMA301",SDPATIEN,SDCLN,SDAPT,"C"))
  1.  S ^TMP($J,"SDAMA201","NEXTAPPT",SDTMP)=SDR Q
  1. FLD12 S SDR=$P($P(SD310,U,3),";",1)
  1.  S SDR=$S(SDR="I":"I",SDR="R":"O",SDR="NT":"O",1:"")
  1.  S ^TMP($J,"SDAMA201","NEXTAPPT",SDTMP)=SDR Q