Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SDRRC15

SDRRC15.m

Go to the documentation of this file.
  1. SDRRC15 ;10N20/MAH - POST-INSTALL FOR PATCH SD*5.3*536 CONVERT TEAM FILE ; 3/01/2008 12:24pm
  1. ;;5.3;PIMS;**1016**;JUN 30, 2012;Build 20
  1. ;;SDRR-RECALL REMINDER
  1. Q
  1. ENV ;Environment check
  1. K ^XTMP("SDRRC15")
  1. S XPDABORT=""
  1. ;checks programmer variables
  1. D PROGCHK(.XPDABORT)
  1. ;check if install is running
  1. D ISRUNING(.XPDABORT)
  1. I XPDABORT="" K XPDABORT
  1. POST ;Check for Clinic Recall Teams file)
  1. I '$D(^DIZ(190004)) D Q
  1. . D NOFILE
  1. D TASK
  1. Q
  1. START ;Background job entry point
  1. N SDAIEN,SDANUSB,SDX,SDFDAIEN,SDARAY,SDERAY,SDSAVE,SDRRREC,SDRRFDA
  1. N SDTOT,SDTOT2,SDTOT3,SDENCPTR,SDCKCNT,SDRRSTOP,SDENT,SDFIL,DFN,TEAM,TOTAL
  1. S TOTAL=0
  1. D XTMP
  1. ;seed var's if Re-Run
  1. I $D(^XTMP("SDRRC15","TOT")) D
  1. . S SDTOT=+$G(^XTMP("SDRRC15","TOT"))
  1. . S (SDSAVE,SDAIEN)=+$G(^XTMP("SDRRC15","TEAM"))
  1. E D
  1. . S SDAIEN=0 F S SDAIEN=$O(^DIZ(190004,SDAIEN)) Q:SDAIEN<1 S SDRRREC=$G(^DIZ(190004,SDAIEN,0)) D
  1. ..S SDRRFDA(403.55,"+1,",.01)=$P(SDRRREC,U,1)
  1. ..S SDRRFDA(403.55,"+1,",1)=$P(SDRRREC,U,2)
  1. ..I $P($G(SDRRREC),U,3)'="" S SDRRFDA(403.55,"+1,",2)=$P($G(SDRRREC),U,3)
  1. ..I $P($G(SDRRREC),U,4)'="" S SDRRFDA(403.55,"+1,",3)=$P($G(SDRRREC),U,4)
  1. ..N NEWREC S NEWREC(1)=SDAIEN
  1. ..D UPDATE^DIE("","SDRRFDA","NEWREC")
  1. ..S TOTAL=TOTAL+1
  1. S ^XTMP("SDRRC15","COMPLETED")=$$NOW^XLFDT()
  1. S ^XTMP("SDRRC15","TOT")=TOTAL
  1. K ^XTMP("SDRRC15","RUNNING")
  1. D SENDMSG
  1. Q
  1. SENDMSG ;send MailMan msg to patch installer
  1. N DIFROM,SDMSG,SDTXT,SDLN,XMY,XMDUZ,XMSUB,XMTEXT,XMDUN,XMZ
  1. K ^TMP("SDRRC15",$J)
  1. S XMSUB="SD*5.3*536 OUTPATIENT CLINIC TEAM FILE CONVERSION REPORT"
  1. S XMTEXT="^TMP(""SDRRC15"",$J,",XMDUZ=.5,(XMY(DUZ),XMY(XMDUZ))=""
  1. S SDLN=0
  1. D ADD(.SDLN,"Patch: SD*5.3*536 RECALL REMINDER TEAM FILE CONVERSION PROCESSING")
  1. D ADD(.SDLN," "),ADD(.SDLN,"************")
  1. D ADD(.SDLN,"The existing Class III file called OUTPATIENT CLINIC RECALL TEAM (190004), ")
  1. D ADD(.SDLN,"which contains Clinic Recall Team Names have been converted to")
  1. D ADD(.SDLN,"a new Class I file called Recall Reminder Team (403.55)")
  1. D ADD(.SDLN,"which will provide the same functionality.")
  1. D ADD(.SDLN,"************"),ADD(.SDLN," "),ADD(.SDLN," ")
  1. D ADD(.SDLN,"SUMMARY OF PROCESSING RESULTS:")
  1. D ADD(.SDLN,"==============================")
  1. D ADD(.SDLN," ")
  1. D ADD(.SDLN,"<<< The Class III OUTPATIENT CLINIC RECALL TEAM File Conversion has "_$S(+$G(SDRRSTOP):"NOT ",1:"")_"Completed. >>>")
  1. I +$G(SDRRSTOP) D
  1. . D ADD(.SDLN," Please restart the post-install process from the following")
  1. . D ADD(.SDLN," programmer's prompt:")
  1. . D ADD(.SDLN," D POST^SDRRC15")
  1. D ADD(.SDLN," "),ADD(.SDLN," ")
  1. D ADD(.SDLN," DATE/TIME TASK STARTED: "_$$FMTE^XLFDT(+$G(^XTMP("SDRRC15","START")),"P"))
  1. D ADD(.SDLN,"DATE/TIME TASK COMPLETED: "_$$FMTE^XLFDT(+$G(^XTMP("SDRRC15","COMPLETED")),"P"))
  1. I $D(^XTMP("SDRRC15","LAST RUN")) D
  1. . D ADD(.SDLN," DATE/TIME LAST RUN: "_$$FMTE^XLFDT(+$G(^XTMP("SDRRC15","LAST RUN")),"P"))
  1. D ADD(.SDLN," "),ADD(.SDLN," ")
  1. D ADD(.SDLN," TOTAL RECORDS THAT HAVE BEEN CONVERTED: "_+$G(^XTMP("SDRRC15","TOT")))
  1. D ADD(.SDLN," <END OF REPORT> :")
  1. D ^XMD
  1. K ^TMP("SDRRC15",$J)
  1. Q
  1. ADD(SDLN,SDTXT) ;add line
  1. Q:$L(SDTXT)'>0
  1. S SDLN=$G(SDLN)+1
  1. S ^TMP("SDRRC15",$J,SDLN)=SDTXT
  1. Q
  1. PROGCHK(XPDABORT) ;checks programmer variables
  1. I '$G(DUZ)!($G(DUZ(0))'="@")!('$G(DT))!($G(U)'="^") D
  1. . D BMES^XPDUTL("******")
  1. . D MES^XPDUTL("Your programming variables are not set up properly.")
  1. . D MES^XPDUTL("Installation aborted.")
  1. . D MES^XPDUTL("******")
  1. . S XPDABORT=2
  1. Q
  1. ISRUNING(XPDABORT) ;check if running
  1. I +$G(^XTMP("SDRRC15","RUNNING")) D
  1. . D BMES^XPDUTL("******")
  1. . D MES^XPDUTL("This patch is currently being Installed. Try later.")
  1. . D MES^XPDUTL("Installation aborted...")
  1. . D MES^XPDUTL("******")
  1. . S XPDABORT=2
  1. Q
  1. NOFILE ;no File
  1. D BMES^XPDUTL("******")
  1. D MES^XPDUTL("The Class III Outpatient Clinic Recall Team File Conversion is NOT necessary because")
  1. D MES^XPDUTL("file (#190004) does not exist on this system.")
  1. D MES^XPDUTL("Post-Install process terminated...For conversion to Recall Reminder Team (#403.55)")
  1. D MES^XPDUTL("******")
  1. Q
  1. TASK ;run TaskMan
  1. N ZTSK,ZTDTH,ZTRTN,ZTDESC,ZTIO,ZTSAVE,ZTREQ,ZTSTOP,SDSTOP
  1. S SDSTOP=+$G(^XTMP("SDRRC15","STOPPED"))
  1. S ZTRTN="START^SDRRC15"
  1. S ZTDESC="SD*5.3*536 RECALL REMINDER TEAM FILE CONVERSION PROCESSING"
  1. S ZTIO="",ZTDTH=$H,ZTREQ="@",ZTSAVE("ZTREQ")=""
  1. D ^%ZTLOAD
  1. D BMES^XPDUTL("******")
  1. I '$D(ZTSK) D
  1. . D MES^XPDUTL("Unable to schedule TaskMan task to run the Class III (190004) File")
  1. . D MES^XPDUTL("Conversion.")
  1. . D BMES^XPDUTL("Please re-run Post-Install routine POST^SSDRRC15 from")
  1. . D MES^XPDUTL("the programmer prompt.")
  1. . ;
  1. E D
  1. . D MES^XPDUTL("Task "_ZTSK_" has been "_$S(+SDSTOP:"Re-",1:"")_"started to run the Class III (190004) File")
  1. . D MES^XPDUTL("Conversion.")
  1. . I SDSTOP D
  1. . . D MES^XPDUTL(" <<< The last task run was STOPPED on "_$$FMTE^XLFDT(SDSTOP,"P")_". >>>")
  1. . D BMES^XPDUTL("You will receive a MailMan message when this task is completed")
  1. . D MES^XPDUTL("or if it has been manually stopped.")
  1. D MES^XPDUTL("******")
  1. Q
  1. XTMP ;setup ^XTMP to control output for 90 days
  1. I $D(^XTMP("SDRRC15",0)) D
  1. . S ^XTMP("SDRRC15","LAST RUN")=$G(^XTMP("SDRRC15","START"))
  1. E D
  1. . N SDX
  1. . S SDX=$$FMADD^XLFDT($$NOW^XLFDT(),90)_U_$$NOW^XLFDT()
  1. . S SDX=SDX_"^SD*5.3*536 RECALL REMINDER TEAM FILE CONVERSION PROCESSING"
  1. . S ^XTMP("SDRRC15",0)=SDX
  1. S ^XTMP("SDRRC15","START")=$$NOW^XLFDT()
  1. S ^XTMP("SDRRC15","RUNNING")="1"
  1. Q
  1. UPXTMP(SDENCPTR,NODE,SDENT) ;add to ^XTMP
  1. ; Input:
  1. ; NODE - Unique subscript
  1. ; Output: none
  1. Q:'$G(SDENCPTR)
  1. I $G(NODE)="" S NODE="UNKNOWN"
  1. S ^XTMP("SDRRC15","TOT2",NODE,SDENCPTR)=$G(SDENT)
  1. Q