SROATCM2.m

SROATCM2 ;BIR/MAM - CREATE MESSAGES ;03/22/06

 ;;3.0; Surgery ;**27,38,90,93,125,153**;24 Jun 93;Build 11

 S SHEMP=3,SRAMNUM=0 F I=0:0 S SRAMNUM=$O(^TMP("SRA",$J,SRAMNUM)) Q:'SRAMNUM  D MSG

STATUS ; update status

 S (SRAMNUM,SRASS)=0

 F I=0:0 S SRAMNUM=$O(^TMP("SRA",$J,SRAMNUM)) Q:'SRAMNUM  S SRACNT=0 F I=0:0 S SRACNT=$O(^TMP("SRA",$J,SRAMNUM,SRACNT)) Q:'SRACNT  S CURLEY=$E(^TMP("SRA",$J,SRAMNUM,SRACNT,0),13,14) I +CURLEY=1 D UPDATE

 I 'SRASS G END

 S X=$$ACTIVE^XUSER(DUZ) I '+X S XMDUZ=.5

 S XMSUB="CARDIAC ASSESSMENT TRANSMISSION COMPLETE"

 S XMY("G.RISK ASSESSMENT@"_^XMB("NETNAME"))=""

 D NOW^%DTC S Y=% D D^DIQ S SRATIME=$E($P(Y,"@",2),1,5)

 S ^TMP("SRAMSG",$J,1,0)="The Cardiac Surgery Risk Assessment Transmission was completed at "_SRATIME_".",^TMP("SRAMSG",$J,2,0)="A total of "_SRASS_$S(SRASS=1:" assessment was sent.",1:" assessments were sent.")

 S ^TMP("SRAMSG",$J,3,0)="  "

 S XMTEXT="^TMP(""SRAMSG"",$J," N I D ^XMD

END K ^TMP("SRA",$J),^TMP("SRAMSG",$J) D ^SRSKILL

 Q

MSG ; send message to G.CARDIAC RISK ASSESSMENTS at Denver

 S ISC=0,NAME=$G(^XMB("NETNAME")) I NAME["FORUM"!(NAME["ISC-")!($E(NAME,1,3)="ISC")!(NAME["ISC.")!(NAME["TST")!(NAME["FO-") S ISC=1

 I ISC S XMY("G.RISK ASSESSMENT@"_^XMB("NETNAME"))=""

 I 'ISC S (XMY("G.CARDIAC RISK ASSESSMENTS@DENVER.VA.GOV"),XMY("G.SRCARDIAC@ISC-CHICAGO.VA.GOV"))=""

 S SRATDATE=$E(DT,4,5)_"/"_$E(DT,6,7)_"/"_$E(DT,2,3)

 S X=$$ACTIVE^XUSER(DUZ) I '+X S XMDUZ=.5

 S XMSUB=$P($$SITE^SROVAR,"^",2)_": CICSP ("_SRAMNUM_" OF "_SRATOTM_")  "_SRATDATE,XMTEXT="^TMP(""SRA"",$J,"_SRAMNUM_"," N I D ^XMD

 Q

UPDATE ; change status to 'T'

 S MM=$E(^TMP("SRA",$J,SRAMNUM,SRACNT,0),5,11) F X=1:1 S EMILY=$P(MM," ",X) Q:EMILY

 N I D NOW^%DTC S SRNOW=$E(%,1,7)

 K DR S DA=EMILY,DR="260////"_SRNOW_";235///T",DIE=130 N I D ^DIE

 S SRASS=SRASS+1

 S DFN=$P(^SRF(EMILY,0),"^") D DEM^VADPT S SRANAME=$P(VADM(1),"^") K VADM S X=$P(^SRF(EMILY,0),"^",9),SRADT=$E(X,4,5)_"/"_$E(X,6,7)_"/"_$E(X,2,3)

 S SHEMP=SHEMP+1,^TMP("SRAMSG",$J,SHEMP,0)="ASSESSMENT: "_EMILY_"   "_$J(SRANAME,20)_"        OPERATION DATE: "_SRADT

 Q

SROATCM2  ;BIR/MAM - CREATE MESSAGES ;03/22/06

 +1       ;;3.0; Surgery ;**27,38,90,93,125,153**;24 Jun 93;Build 11

 +2        SET SHEMP=3

           SET SRAMNUM=0

           FOR I=0:0

               SET SRAMNUM=$ORDER(^TMP("SRA",$JOB,SRAMNUM))

               IF 'SRAMNUM

                   QUIT 

               DO MSG

STATUS    ; update status

 +1        SET (SRAMNUM,SRASS)=0

 +2        FOR I=0:0

               SET SRAMNUM=$ORDER(^TMP("SRA",$JOB,SRAMNUM))

               IF 'SRAMNUM

                   QUIT 

               SET SRACNT=0

               FOR I=0:0

                   SET SRACNT=$ORDER(^TMP("SRA",$JOB,SRAMNUM,SRACNT))

                   IF 'SRACNT

                       QUIT 

                   SET CURLEY=$EXTRACT(^TMP("SRA",$JOB,SRAMNUM,SRACNT,0),13,14)

                   IF +CURLEY=1

                       DO UPDATE

 +3        IF 'SRASS

               GOTO END

 +4        SET X=$$ACTIVE^XUSER(DUZ)

           IF '+X

               SET XMDUZ=.5

 +5        SET XMSUB="CARDIAC ASSESSMENT TRANSMISSION COMPLETE"

 +6        SET XMY("G.RISK ASSESSMENT@"_^XMB("NETNAME"))=""

 +7        DO NOW^%DTC

           SET Y=%

           DO D^DIQ

           SET SRATIME=$EXTRACT($PIECE(Y,"@",2),1,5)

 +8        SET ^TMP("SRAMSG",$JOB,1,0)="The Cardiac Surgery Risk Assessment Transmission was completed at "_SRATIME_"."

           SET ^TMP("SRAMSG",$JOB,2,0)="A total of "_SRASS_$SELECT(SRASS=1:" assessment was sent.",1:" assessments were sent.")

 +9        SET ^TMP("SRAMSG",$JOB,3,0)="  "

 +10       SET XMTEXT="^TMP(""SRAMSG"",$J,"

           NEW I

           DO ^XMD

END        KILL ^TMP("SRA",$JOB),^TMP("SRAMSG",$JOB)

           DO ^SRSKILL

 +1        QUIT 

MSG       ; send message to G.CARDIAC RISK ASSESSMENTS at Denver

 +1        SET ISC=0

           SET NAME=$GET(^XMB("NETNAME"))

           IF NAME["FORUM"!(NAME["ISC-")!($EXTRACT(NAME,1,3)="ISC")!(NAME["ISC.")!(NAME["TST")!(NAME["FO-")

               SET ISC=1

 +2        IF ISC

               SET XMY("G.RISK ASSESSMENT@"_^XMB("NETNAME"))=""

 +3        IF 'ISC

               SET (XMY("G.CARDIAC RISK ASSESSMENTS@DENVER.VA.GOV"),XMY("G.SRCARDIAC@ISC-CHICAGO.VA.GOV"))=""

 +4        SET SRATDATE=$EXTRACT(DT,4,5)_"/"_$EXTRACT(DT,6,7)_"/"_$EXTRACT(DT,2,3)

 +5        SET X=$$ACTIVE^XUSER(DUZ)

           IF '+X

               SET XMDUZ=.5

 +6        SET XMSUB=$PIECE($$SITE^SROVAR,"^",2)_": CICSP ("_SRAMNUM_" OF "_SRATOTM_")  "_SRATDATE

           SET XMTEXT="^TMP(""SRA"",$J,"_SRAMNUM_","

           NEW I

           DO ^XMD

 +7        QUIT 

UPDATE    ; change status to 'T'

 +1        SET MM=$EXTRACT(^TMP("SRA",$JOB,SRAMNUM,SRACNT,0),5,11)

           FOR X=1:1

               SET EMILY=$PIECE(MM," ",X)

               IF EMILY

                   QUIT 

 +2        NEW I

           DO NOW^%DTC

           SET SRNOW=$EXTRACT(%,1,7)

 +3        KILL DR

           SET DA=EMILY

           SET DR="260////"_SRNOW_";235///T"

           SET DIE=130

           NEW I

           DO ^DIE

 +4        SET SRASS=SRASS+1

 +5        SET DFN=$PIECE(^SRF(EMILY,0),"^")

           DO DEM^VADPT

           SET SRANAME=$PIECE(VADM(1),"^")

           KILL VADM

           SET X=$PIECE(^SRF(EMILY,0),"^",9)

           SET SRADT=$EXTRACT(X,4,5)_"/"_$EXTRACT(X,6,7)_"/"_$EXTRACT(X,2,3)

 +6        SET SHEMP=SHEMP+1

           SET ^TMP("SRAMSG",$JOB,SHEMP,0)="ASSESSMENT: "_EMILY_"   "_$JUSTIFY(SRANAME,20)_"        OPERATION DATE: "_SRADT

 +7        QUIT