Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIUFLLM1

TIUFLLM1.m

Go to the documentation of this file. 
  1. TIUFLLM1 ; SLC/MAM - Library; LM Related: LINEUP(INFO,TEMPLATE), UPDATE(TMPLATE,SHIFT,LASTLIN,PINFO), AINUSE(LINENO), INUSEUP(FILEDA,LINENO) ;8/27/97  18:47
  1.  ;;1.0;TEXT INTEGRATION UTILITIES;**11**;Jun 20, 1997
  1.  ;
  1. LINEUP(INFO,TEMPLATE) ; Update Line +INFO.  Line must be updated, NOT added or deleted.
  1.  ; Requires INFO,TEMPLATE
  1.  N NODE0
  1.  D:$D(INFO)<10 PARSE^TIUFLLM(.INFO) D:$D(NODE0)<10 NODE0ARR^TIUFLF($P(INFO,U,2),.NODE0) G:$D(DTOUT) LINEX
  1.  D BUFENTRY^TIUFLLM2(.INFO,.NODE0,TEMPLATE)
  1.  D UPDATE(TEMPLATE,0,INFO-1)
  1. LINEX Q
  1.  ;
  1. UPDATE(TMPLATE,SHIFT,LASTLIN,PINFO) ; Update LM TMPLATE using Buffer Array.
  1.  ; TMPLATE lines may be inserted, deleted, or reset.  Resets 1 line;
  1.  ;inserts or deletes a continuous chunk of lines.
  1.  ; Lines to be inserted must be in buffer array ^TMP("TIUFB", starting
  1.  ;with line # LASTLIN+1 and running for SHIFT continuous lines.
  1.  ; Line to be reset must be in Buffer Array at line # LASTLIN+1,
  1.  ;with SHIFT = 0.
  1.  ; Lines to be deleted must be continuous lines starting with line #
  1.  ;LASTLIN+1 and running for -SHIFT lines, where SHIFT is negative.
  1.  ; Requires TMPLATE = LM Sub/Template H, A, I, T, D, O, or P; If TMPLATE 
  1.  ;                  = H (Hierarchy), then lines to be added/deleted
  1.  ;                    must all be items under the same parent.
  1.  ;          SHIFT is >0 for add; >0 for delete; =0 for reset.
  1.  ;          |SHIFT| is Length of addition/deletion;  a reset does not
  1.  ;            add or delete, so SHIFT is 0 for reset.
  1.  ;          LASTLIN = Line BEFORE Insertion/del/update point as above.
  1.  ;
  1.  ; Requires PINFO and PINFO array IF TMPLATE = "H" AND adding/deleting
  1.  ;          (but NOT resetting) lines AND LASTLIN'=0 (Clinical Documents
  1.  ;            HAS NO parent).
  1.  ;          PINFO = ^TMP("TIUF1IDX,$J,LINENO), where LINENO is LM
  1.  ;            Lineno of LM PARENT of lines added/deleted.
  1.  ;          PINFO Array is as set in PARSE^TIUFLLM for PINFO.
  1.  ;          PINFO is used to:
  1.  ;            Update ^TMP("TIUF*IDX" for ancestors of lines
  1.  ;              added/deleted (3rd piece, XPDLCNT);
  1.  ;            Update the + preceeding Name of parent
  1.  ;              of lines added/deleted.
  1.  ;          If PINFO is received, routine returns updated PINFO array.
  1.  ;            (Updates PINFO("XPDLCNT").
  1.  ; DOESN'T update VALMCNT. (Don't try it: may be updating template other than the one you're presently in.)
  1.  ;do I need "DAF" for all templates?;MAM
  1.  N LINENO,TIUI,TIUJ,OLDINFO,BEG,INC,END,BINFO,ARR,ARRIDX,ARRNO,VCNT
  1.  N INUSE,INUSE1,INUSECOL,PLINENO
  1.  S ARRNO=^TMP("TIUF",$J,"ARRNO"_TMPLATE)
  1.  S ARR="TIUF"_ARRNO,ARRIDX="TIUF"_ARRNO_"IDX"
  1.  I SHIFT'>0 D
  1.  . ;Delete lines to be deleted/updated
  1.  . S BEG=LASTLIN+1,END=$S(SHIFT=0:BEG,1:BEG-1-SHIFT)
  1.  . F TIUI=BEG:1:END D
  1.  . . S OLDINFO=^TMP(ARRIDX,$J,TIUI)
  1.  . . K ^TMP(ARR,$J,TIUI,0),^TMP(ARR,$J,"IDX",TIUI)
  1.  . . K ^TMP(ARRIDX,$J,"DAF",$P(OLDINFO,U,2),TIUI)
  1.  . . I TMPLATE="T" K ^TMP(ARRIDX,$J,"DA10",$P(OLDINFO,U,6),TIUI)
  1.  . . K ^TMP(ARRIDX,$J,TIUI)
  1.  . . Q
  1.  . Q
  1.  I SHIFT'=0 D
  1.  . ; Move lines starting w LASTLIN+1 down, creating gap to add entries 
  1.  . ; OR Move lines after deleted lines up to fill in gap.
  1.  . S VCNT=$O(^TMP(ARR,$J,1000000),-1)
  1.  . I SHIFT>0 S BEG=VCNT,INC=-1,END=LASTLIN+1
  1.  . E  S BEG=LASTLIN+1-SHIFT,INC=1,END=VCNT
  1.  . F LINENO=BEG:INC:END Q:INC>0&(BEG>END)  Q:INC<0&(BEG<END)  D
  1.  . . S ^TMP(ARR,$J,LINENO+SHIFT,0)=$$SETSTR^VALM1(LINENO+SHIFT,^TMP(ARR,$J,LINENO,0),1,5) ; SETFLD doesn't work since called by nontarget template.
  1.  . . I SHIFT>5!(SHIFT<-5) W "."
  1.  . . I ARR'="TIUF3" S ^TMP(ARR,$J,"IDX",LINENO+SHIFT,LINENO+SHIFT)=""
  1.  . . S OLDINFO=^TMP(ARRIDX,$J,LINENO)
  1.  . . S $P(OLDINFO,U)=LINENO+SHIFT
  1.  . . S PLINENO=$P(OLDINFO,U,5) I PLINENO>LASTLIN S $P(OLDINFO,U,5)=PLINENO+SHIFT
  1.  . . S ^TMP(ARRIDX,$J,"DAF",$P(OLDINFO,U,2),LINENO+SHIFT)=""
  1.  . . I TMPLATE="T" S ^TMP(ARRIDX,$J,"DA10",$P(OLDINFO,U,6),LINENO+SHIFT)=""
  1.  . . S ^TMP(ARRIDX,$J,LINENO+SHIFT)=OLDINFO
  1.  . . K ^TMP(ARR,$J,LINENO,0),^TMP(ARR,$J,"IDX",LINENO,LINENO)
  1.  . . K ^TMP(ARRIDX,$J,LINENO),^TMP(ARRIDX,$J,"DAF",$P(OLDINFO,U,2),LINENO)
  1.  . . I TMPLATE="T" K ^TMP(ARRIDX,$J,"DA10",$P(OLDINFO,U,6),LINENO)
  1.  . . Q
  1.  . Q
  1.  I SHIFT'<0 D
  1.  . ; Fill LM space with buffer array to add/update entries.
  1.  . S TIUJ=0 F  S TIUJ=$O(^TMP("TIUFB",$J,TIUJ)) Q:'TIUJ  D
  1.  . . S ^TMP(ARR,$J,TIUJ,0)=^TMP("TIUFB",$J,TIUJ,0)
  1.  . . I SHIFT>5 W "."
  1.  . . I ARR'="TIUF3" S ^TMP(ARR,$J,"IDX",TIUJ,TIUJ)=""
  1.  . . S BINFO=^TMP("TIUFBIDX",$J,TIUJ)
  1.  . . S ^TMP(ARRIDX,$J,"DAF",$P(BINFO,U,2),TIUJ)=""
  1.  . . I TMPLATE="T" S ^TMP(ARRIDX,$J,"DA10",$P(BINFO,U,6),TIUJ)=""
  1.  . . S ^TMP(ARRIDX,$J,TIUJ)=BINFO
  1.  . . Q
  1.  . K ^TMP("TIUFB",$J),^TMP("TIUFBIDX",$J)
  1.  . Q
  1.  I $G(PINFO),SHIFT,"HC"[TMPLATE D
  1.  . ; For Template H or C:
  1.  . ; Updates 3rd piece of ^TMP("TIUF1IDX",$J,LINENO) (XPDLCNT) for mutual
  1.  . ;   parent and ancestors of entries to be added/deleted;
  1.  . ; Updates PINFO, array PINFO;
  1.  . ; Updates + in front of parent for template H
  1.  . N ANCLNO,XPDLCNT,AINFO
  1.  . S ANCLNO=+PINFO
  1.  . F  S AINFO=$G(^TMP("TIUF1IDX",$J,ANCLNO)) Q:'AINFO  D
  1.  . . S XPDLCNT=$P(AINFO,U,3)+SHIFT,$P(^TMP("TIUF1IDX",$J,ANCLNO),U,3)=XPDLCNT
  1.  . . S ANCLNO=+$P(AINFO,U,5)
  1.  . S PINFO("XPDLCNT")=$P(PINFO,U,3)+SHIFT
  1.  . S $P(PINFO,U,3)=PINFO("XPDLCNT")
  1.  . I TMPLATE="H" S ^TMP("TIUF1",$J,+PINFO,0)=$$PLUSUP^TIUFLLM(.PINFO,^TMP("TIUF1",$J,+PINFO,0))
  1. UPDAX Q
  1.  ;