Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIUHL7U2

TIUHL7U2.m

Go to the documentation of this file. 
  1. TIUHL7U2 ; SLC/AJB - TIUHL7 Utilities; March 23, 2005
  1.  ;;1.0;TEXT INTEGRATION UTILITIES;**200**;Jun 20, 1997
  1.  Q
  1. MAKEADD(TIUDADD,TIUDA,TIUX,SUPPRESS) ; Create addendum
  1.  N DIE,DR,DA,DIC,X,Y,DLAYGO,TIUATYP,TIUCAN,TIUFPRIV,TIU S TIUFPRIV=1
  1.  N PTIEN,SUCCESS
  1.  S TIUCAN=$$CANDO^TIULP(TIUDA,"MAKE ADDENDUM",$G(PERSON))
  1.  I TIUCAN'>0 S TIUDADD=TIUCAN Q
  1.  S TIUATYP=+$$WHATITLE^TIUPUTU("ADDENDUM")
  1.  S (DIC,DLAYGO)=8925,DIC(0)="L",X=""""_"`"_TIUATYP_""""
  1.  D ^DIC
  1.  S TIUDADD=+Y
  1.  I +Y'>0 S TIUDADD=TIUDADD_"^Could not create addendum." Q
  1.  D GETTIU^TIULD(.TIU,TIUDA)
  1.  S TIU("DOCTYP")=TIUATYP_U_$$PNAME^TIULC1(TIUATYP)
  1.  S PTIEN=$P(^TIU(8925,TIUDA,0),U,2)
  1.  D STUFREC^TIUSRVP1(+TIUDADD,.TIUX,PTIEN,+$G(TIUDA),TIUATYP,.TIU)
  1.  K ^TIU(8925,+TIUDADD,"TEMP")
  1.  M ^TIU(8925,+TIUDADD,"TEMP")=TIUX("TEXT") K TIUX("TEXT")
  1.  D SETXT0^TIUSRVP(+TIUDADD)
  1.  D FILE^TIUSRVP(.SUCCESS,+TIUDADD,.TIUX,+$G(SUPPRESS))
  1.  I +SUCCESS'>0 D DIK^TIURB2(TIUDADD) S TIUDADD="-1^Could not create addendum." Q
  1.  I +$O(^TIU(8925,+TIUDADD,"TEMP",0)) D MERGTEXT^TIUEDI1(+TIUDADD,.TIU)
  1.  I '+$G(SUPPRESS) D RELEASE^TIUT(+TIUDADD,1)
  1.  K ^TIU(8925,+TIUDADD,"TEMP")
  1.  Q
  1. DOCPRM(TIUTYP,TIUDPRM,TIUDA) ; Get Document Parameters, support inheritance
  1.  N TIUI,TIUDAD
  1.  S (TIUDPRM(0),TIUDPRM(5))=""
  1.  I $P($G(^TIU(8925.1,+TIUTYP,0)),U)["ADDENDUM",+$G(TIUDA) S TIUTYP=+$G(^TIU(8925,+$P($G(^TIU(8925,+TIUDA,0)),U,6),0))
  1.  S TIUI=+$O(^TIU(8925.95,"B",+TIUTYP,0))
  1.  I +TIUI D  Q
  1.  . S TIUDPRM(0)=$G(^TIU(8925.95,+TIUI,0))
  1.  . I +$O(^TIU(8925.95,+TIUI,5,0)) D
  1.  . . N TIUJ S TIUJ=0
  1.  . . F  S TIUJ=$O(^TIU(8925.95,+TIUI,5,TIUJ)) Q:+TIUJ'>0  D
  1.  . . . S $P(TIUDPRM(5),U,TIUJ)=+$G(^TIU(8925.95,+TIUI,5,+TIUJ,0))
  1.  . . S TIUJ=0
  1.  . . F  S TIUJ=$O(^TIU(8925.95,+TIUI,4,TIUJ)) Q:+TIUJ'>0  D
  1.  . . . S $P(TIUDPRM(4),U,TIUJ)=+$G(^TIU(8925.95,+TIUI,4,+TIUJ,0))
  1.  S TIUDAD=$O(^TIU(8925.1,"AD",+TIUTYP,0))
  1.  I +TIUDAD D DOCPRM(TIUDAD,.TIUDPRM)
  1.  Q
  1. ES(DA,TIUES,TIUI,TIUESIG) ; ^DIE call for /es/
  1.  N SIGNER,DR,DIE,ESDT,TIUSTAT,TIUSTNOW,COSIGNER,SVCHIEF,CSREQ,TIUPRINT
  1.  N CSNEED,TIUTTL,TIUPSIG,TIUDPRM,DAO,TIUSTWAS,TIUSTIS,DAORIG,TIUCHNG
  1.  S TIUSTWAS=$P($G(^TIU(8925,DA,0)),U,5) S:'+$G(TIUESIG) TIUESIG=DUZ
  1.  D DOCPRM^TIULC1(+$G(^TIU(8925,+DA,0)),.TIUDPRM,DA)
  1.  S TIUSTAT=$P($G(^TIU(8925,+DA,0)),U,5),ESDT=$$NOW^TIULC
  1.  S SVCHIEF=+$$ISA^USRLM(TIUESIG,"CLINICAL SERVICE CHIEF")
  1.  S SIGNER=$P(^TIU(8925,+DA,12),U,4),COSIGNER=$P(^(12),U,8),CSREQ=0
  1.  S CSNEED=+$P($G(^TIU(8925,+DA,15)),U,6)
  1.  I +CSNEED,(TIUESIG'=COSIGNER),'+$G(SVCHIEF),(TIUSTAT'=6) S CSREQ=1
  1.  I TIUSTAT=5 D
  1.  . S DR=".05////"_$S(+CSREQ:6,1:7)_";1501////"_ESDT_";1502////"_+TIUESIG
  1.  . I '+$G(CSREQ),+CSNEED,$S(TIUESIG=COSIGNER:1,+$G(SVCHIEF):1,1:0) D
  1.  . . S DR=DR_";1506////0;1507////"_ESDT_";1508////"_+TIUESIG_";1509///^S X=$P(TIUES,U,2);1510///^S X=$P(TIUES,U,3);1511////E"
  1.  I TIUSTAT=6 S DR=".05////7;1506////0;1507////"_ESDT_";1508////"_+TIUESIG
  1.  Q:'$D(DR)
  1.  S DIE=8925 D ^DIE W:'$D(XWBOS) "."
  1.  I TIUSTAT=5 S DR="1503///^S X=$P(TIUES,U,2);1504///^S X=$P(TIUES,U,3);1505////E"
  1.  I TIUSTAT=6 D
  1.  . N TIUSBY S DR="",TIUSBY=$P($G(^TIU(8925,+DA,15)),U,2)
  1.  . I +TIUSBY>0 S DR="1503///^S X=$$SIGNAME^TIULS("_TIUSBY_");1504///^S X=$$SIGTITL^TIULS("_TIUSBY_");"
  1.  . S DR=$G(DR)_"1509///^S X=$P(TIUES,U,2);1510///^S X=$P(TIUES,U,3);1511////E"
  1.  S DIE=8925 D ^DIE W:'$D(XWBOS) "." S:'+$G(TIUCHNG) TIUCHNG=1
  1.  D SEND^TIUALRT(DA),SIGNIRT^TIUDIRT(+DA)
  1.  S DAORIG=DA
  1.  I +$$ISADDNDM^TIULC1(DA) S DA=+$P($G(^TIU(8925,+DA,0)),U,6)
  1.  I +$G(CSREQ)'>0 D MAIN^TIUPD(DA,"S") I 1
  1.  ;If 'Credit Stop Code on Completion' is Yes
  1.  I +$P(^TIU(8925,+DA,0),U,11) D
  1.  . ;If workload does not exist, process using TIU's interview otherwise
  1.  . ;process as an edit using PCE's interview
  1.  . I '$$CHKVST^TIUPXAP2(+DA) D  I 1
  1.  . . N TIUCONT,TIUPRMT
  1.  . . Q:$D(XWBOS)
  1.  . . I $P(+$P(^TIU(8925,+DA,0),U,7),".")>DT D  Q
  1.  . . . W !!
  1.  . . . D QUE^TIUPXAP1
  1.  . . . W:$$READ^TIUU("EA","Press RETURN to continue...") ""
  1.  . . W !!
  1.  . . ;Check if workload should be entered
  1.  . . I $$CHKWKL^TIUPXAP2(+DA,.TIUDPRM) D CREDIT^TIUVSIT(DA)
  1.  . E  D
  1.  . . ;Check if workload should be entered
  1.  . . I $$CHKWKL^TIUPXAP2(+DA,.TIUDPRM) D EDTENC^TIUPXAP2(DA)
  1.  . D REMFLAG^TIUVSIT(+DA)
  1.  ;If document does not have a visit and docmt is associated with
  1.  ;an event type visit or call is invoked by broker, check if
  1.  ;docmt can be linked to an existing visit or try and create a new
  1.  ;visit. (P179)
  1.  I $D(^TIU(8925,+DA,0)),$P(^(0),U,3)'>0,($P(^(0),U,13)="E"!($$BROKER^XWBLIB)) D
  1.  . N D0,DFN,TIU,TIUVSIT
  1.  . ;Try to link docmt to an existing visit, quit if successful
  1.  . I $$LNKVST^TIUPXAP3(DA,.TIUVSIT) Q
  1.  . ;Otherwise set TIU array and DFN to use TIU API which calls PCE
  1.  . ;to resolve multiple visits or creates a new visit
  1.  . D GETTIU^TIULD(.TIU,DA)
  1.  . S DFN=$P($G(^TIU(8925,+DA,0)),U,2)
  1.  . D QUE^TIUPXAP1
  1.  ; post-signature action
  1.  N TIUCONS S TIUCONS=-1
  1.  D ISCNSLT^TIUCNSLT(.TIUCONS,+$G(^TIU(8925,DA,0)))
  1.  I TIUCONS S DA=DAORIG
  1.  S TIUSTIS=$P($G(^TIU(8925,DA,0)),U,5)
  1.  S TIUTTL=+$G(^TIU(8925,+DA,0)),TIUPSIG=$$POSTSIGN^TIULC1(TIUTTL)
  1.  I +$L(TIUPSIG),'+$G(CSREQ) X TIUPSIG
  1.  I TIUCONS,TIUSTIS=7,TIUSTWAS<7,$$HASKIDS^TIUSRVLI(DA) D
  1.  . N SEQUENCE,TIUKIDS,TIUINT,TIUK
  1.  . S SEQUENCE="D",TIUKIDS="TIUKIDS",TIUINT=0,TIUK=0
  1.  . D SETKIDS^TIUSRVLI(TIUKIDS,DA,TIUINT)
  1.  . F  S TIUK=$O(TIUKIDS(TIUK)) Q:'TIUK  D
  1.  . . I $P(TIUKIDS(TIUK),U,7)="completed" X TIUPSIG
  1.  Q
  1. STRIP(X) ; Strip control characters
  1.  N I,Y
  1.  ; First replace TABS w/5 spaces
  1.  F I=1:1:$L(X) S:$A(X,I)=9 X=$E(X,1,(I-1))_"     "_$E(X,(I+1),$L(X))
  1.  ; Next, remove control characters
  1.  S Y="" F I=1:1:$L(X) S:$A(X,I)>31 Y=Y_$E(X,I)
  1.  Q Y