Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIURC

TIURC.m

Go to the documentation of this file. 
  1. TIURC ; SLC/JER - Additional Review screen actions ;02/25/10  08:52
  1.  ;;1.0;TEXT INTEGRATION UTILITIES;**1,4,36,48,67,79,58,100,182,232,250**;Jun 20, 1997;Build 14
  1.  ;
  1.  ; ICR #10018    - ^DIE Routine & DIE, DA, DR, DTOUT, & DUOUT Local Vars
  1.  ;     #10117    - EN^VALM, CLEAR^VALM1, & FULL^VALM1  Routines & VALM("ENTITY"),
  1.  ;                 VALMBCK, VALMY, & VALMY( Local Vars
  1.  ;     #10119    - EN^VALM2 Routine & XQORNOD(0) Local Var
  1.  ;
  1. VERIFY ; Verify Documents
  1.  N TIUCHNG,TIUDATA,TIUI,TIUY,Y,DIROUT,TIULST,TIUDAARY
  1.  I '$D(VALMY) D EN^VALM2(XQORNOD(0))
  1.  S TIUI=0
  1.  F  S TIUI=$O(VALMY(TIUI)) Q:+TIUI'>0  D  Q:$D(DIROUT)
  1.  . N TIU,TIUDATA,TIUDA,RSTRCTD
  1.  . S TIUDATA=$G(^TMP("TIURIDX",$J,TIUI))
  1.  . S TIUDA=+$P(TIUDATA,U,2) S RSTRCTD=$$DOCRES^TIULRR(TIUDA)
  1.  . I RSTRCTD D  Q
  1.  . . W !!,$C(7),"Ok, no harm done...",!
  1.  . . I $$READ^TIUU("EA","RETURN to continue...") ; pause
  1.  . S TIUDAARY(TIUI)=TIUDA
  1.  . S TIUCHNG=0
  1.  . D EN^VALM("TIU VERIFY")
  1.  . K ^TMP("TIUVIEW",$J)
  1.  . I +$G(TIUCHNG) D
  1.  . . S TIULST=$G(TIULST)_$S($G(TIULST)]"":",",1:"")_TIUI
  1.  ; -- Update or Rebuild list, restore video:
  1.  I $G(TIUCHNG("ADDM"))!$G(TIUCHNG("DELETE")) S TIUCHNG("RBLD")=1
  1.  E  S TIUCHNG("UPDATE")=1
  1.  D UPRBLD^TIURL(.TIUCHNG,.VALMY) K VALMY
  1.  S VALMBCK="R"
  1.  D VMSG^TIURS1($G(TIULST),.TIUDAARY,"verified/unverified")
  1.  Q
  1. VERIFY1 ; Single record verify
  1.  ; Receives TIUDA
  1.  N DA,DIE,DR,TIUTYP,TIUQUIT,TIUT0,TIUTNM,TIUVERX
  1.  S TIUTYP=+$G(^TIU(8925,+TIUDA,0)),TIUT0=$G(^TIU(8925.1,+TIUTYP,0))
  1.  S TIUTNM=$$PNAME^TIULC1(+TIUTYP)
  1.  S TIUTYP(1)="1^"_+TIUTYP_U_TIUTNM_U
  1.  I $$DADORKID^TIUGBR(TIUDA) D  Q
  1.  . W !!,$C(7),"This ",TIUTNM," is an interdisciplinary entry.",!,"ID entries must be verified prior to attaching.",!
  1.  . I $$READ^TIUU("EA","Press RETURN to continue...") W ""
  1.  I +$P($G(^TIU(8925,+TIUDA,15)),U)!+$P($G(^(15)),U,7) D  Q
  1.  . W !!,$C(7),"This ",TIUTNM," is already signed.",!
  1.  . I $$READ^TIUU("EA","Press RETURN to continue...") W ""
  1.  ; -- Can't verify admin closed docmts (P182):
  1.  I +$P($G(^TIU(8925,+TIUDA,16)),U,6) D  Q
  1.  . W !!,$C(7),"This ",TIUTNM," is already closed.",!
  1.  . I $$READ^TIUU("EA","Press RETURN to continue...") W ""
  1.  I +$P($G(^TIU(8925,+TIUDA,13)),U,5) D  Q
  1.  . W !!,"This ",TIUTNM," is already verified."
  1.  . S TIUY=$$READ^TIUU("YO","Do you want to UNVERIFY this "_TIUTNM,"NO","^D UNVER^TIUDIRH")
  1.  . I TIUY W !,TIUTNM," UNVERIFIED" D
  1.  . . S DA=TIUDA,DIE=8925,DR=".05///UNVERIFIED;1305///@;1306///@" D ^DIE
  1.  . . W "." S TIUCHNG=1
  1.  . . D ALERTDEL^TIUALRT(TIUDA)
  1.  N DUOUT,DIROUT,DTOUT
  1.  S TIUY=$$READ^TIUU("YO","Do you want to edit this "_TIUTNM,"NO")
  1.  I +TIUY D
  1.  . ;VMP/ELR ADDED NEXT 2 LINES TO PROHIBIT EDIT OF SURGERY WHILE VERIFYING
  1.  . NEW TIUMSG S TIUMSG=$$CANDO^TIULP(TIUDA,"EDIT RECORD") I +TIUMSG'>0 D  Q
  1.  . . W !!,$C(7),$P(TIUMSG,U,2),!
  1.  . D GETTIU^TIULD(.TIU,TIUDA),CLEAR^VALM1
  1.  . D DIE^TIUEDI4(TIUDA,.TIUQUIT) ; **100**
  1.  . I $S(+$G(TIUQUIT):1,$D(DUOUT):1,$D(DIROUT):1,$D(DTOUT):1,1:0) Q
  1.  . D RELEASE^TIUT(TIUDA)
  1.  I +TIUY'>0,$S(+$G(TIUQUIT):1,$D(DUOUT):1,$D(DIROUT):1,$D(DTOUT):1,1:0) Q
  1.  S TIUY=$$READ^TIUU("YO","VERIFY this "_TIUTNM,"NO","^D VER^TIUDIRH")
  1.  I 'TIUY W !,TIUTNM," NOT VERIFIED." Q
  1.  S DA=TIUDA,DIE=8925,DR=".05///UNSIGNED;1305////"_$$NOW^TIULC_";1306////"_$G(DUZ) D ^DIE
  1.  S TIUCHNG=1,TIUVERX=$$VERIFY^TIULC1(+$G(^TIU(8925,+TIUDA,0)))
  1.  I TIUVERX]"" X TIUVERX
  1.  I +DA W !,TIUTNM," VERIFIED." D MAIN^TIUPD(DA,"V"),SEND^TIUALRT(DA)
  1.  Q
  1. ADD ; Add Document
  1.  N TIUONCE,TIUNDA,TIUCLASS,TIUCREAT,TIUITEM,LINENO,VALMY,TIUCHNG,RSTRCTD
  1.  ; OK to new TIUCHNG here, this is not used in browse.
  1.  S TIUONCE=1
  1.  S TIUCLASS=$S($G(VALM("ENTITY"))="Progress Note":3,$G(VALM("ENTITY"))="Discharge Summary":244,1:38)
  1.  D FULL^VALM1
  1.  I +$G(DFN) D  Q:+$G(RSTRCTD)
  1.  . S RSTRCTD=$$PTRES^TIULRR(DFN)
  1.  . I RSTRCTD D  Q
  1.  . . W !!,$C(7),"Ok, no harm done...",!
  1.  . . I $$READ^TIUU("EA","RETURN to continue...") ; pause
  1.  ; -- MAIN^TIUEDIT looks like:
  1.  ;    MAIN(TIUCLASS,SUCCESS,DFN,TIUTITLE,EVNTFLAG,NOSAVE,
  1.  ;         TIUNDA,TIUSNGL,TIUCHNG)
  1.  ;    i.e. TIUTITLE,EVNTFLAG,NOSAVE,TIUSNGL are null
  1.  D MAIN^TIUEDIT(TIUCLASS,.TIUCREAT,+$G(DFN),"","","",.TIUNDA,"",.TIUCHNG)
  1.  I $G(TIUCHNG("DELETE"))!$G(TIUCHNG("ADDM"))!$G(TIUCHNG("EXIST"))!$G(TIUCHNG("AVAIL")) S TIUCHNG("RBLD")=1
  1.  I +$O(TIUNDA(0))'>0 S TIUCHNG("REFRESH")=1 G ADDX
  1.  ; -- If in TIU OE/RR REVIEW PN, rebuild list and quit:
  1.  I $G(^TMP("TIUR",$J,"RTN"))="TIUROR" S TIUCHNG("RBLD")=1 G ADDX
  1.  ; -- If in Review Notes by Patient (no review screen),
  1.  ;    or rebuilding, don't add elements to end of screen:
  1.  I '$D(^TMP("TIUR",$J,"RTN")) G ADDX
  1.  I $G(TIUCHNG("RBLD")) G ADDX
  1.  ; -- If in an integrated docmts option, add one line
  1.  ;    to screen for each new docmt, refresh list, and quit:
  1.  S TIUNDA=0
  1.  F  S TIUNDA=$O(TIUNDA(TIUNDA)) Q:+TIUNDA'>0  D
  1.  . S TIUITEM=+$G(^TMP("TIUR",$J,0))
  1.  . ; -- Don't add if editing existing docmt which is already in list:
  1.  . S LINENO=$O(^TMP("TIUR",$J,"IEN",TIUNDA,0))
  1.  . I LINENO D  Q
  1.  . . S VALMY(LINENO)="",TIUCHNG("UPDATE")=1
  1.  . D ADDELMNT^TIUR2(TIUNDA,+TIUITEM,1)
  1.  S TIUCHNG("REFRESH")=1
  1. ADDX D UPRBLD^TIURL(.TIUCHNG,.VALMY)
  1.  Q
  1. COPY1 ; -- Call to COPY1 for backward compatibility
  1.  G COPY1^TIURC1
  1.  Q