Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIUSRVG

TIUSRVG.m

Go to the documentation of this file. 
  1. TIUSRVG ; SLC/JER - Silent Server Calls ;12/21/94  17:50
  1.  ;;1.0;TEXT INTEGRATION UTILITIES;**173**;Jun 20, 1997
  1. MULTIPLE(TIUY,TIUDA,TIUECHO) ; Get multiple records
  1.  N TIUI,TIUX,TIULAST S TIUI=0
  1.  K ^TMP("TIUVIEW",$J)
  1.  F  S TIUI=$O(TIUDA(TIUI)) Q:+TIUI'>0  D
  1.  . S TIUX=$G(TIUDA(TIUI)) D GET(.TIUY,TIUX,TIUI,+$G(TIUECHO),1)
  1.  Q
  1. GET(TIUY,TIUDA,TIUITEM,TIUECHO,TIUACCUM) ; Get a record
  1.  N DIC,DIQ,X,Y
  1.  N TIUI,TIUJ,TIUL,TIUREC S (TIUDADD,TIUI)=0
  1.  N DA,DIC,DIQ,DR,TIUFILE,TIUNAM
  1.  K:'+$G(TIUACCUM) ^TMP("TIUVIEW",$J)
  1.  S DA=TIUDA
  1.  I '$D(^TIU(8925,+TIUDA,0)) S VALMQUIT=1,TIUY="-1^NONEXISTENT RECORD" Q
  1.  S (TIUFILE,DIC)=8925,DIQ="TIUREC("
  1.  S DR=".01;.02;.05;.07:.1;1202;1204;1301;1302;1305;1306;1501;1502;1505;1506;1601:1604"
  1.  D EN^DIQ1
  1.  I $D(TIUREC)>9 D
  1.  . W:+$G(TIUECHO) !!,"Opening "_TIUREC(8925,+TIUDA,.01)_" record for review..."
  1.  . F TIUJ=1:1:3 S ^TMP("TIUVIEW",$J,TIUITEM,TIUJ,0)=$$SETREC(TIUJ)
  1.  . S (TIUJ,TIUL)=4,^TMP("TIUVIEW",$J,TIUITEM,TIUJ,0)=" "
  1.  D LOADREC(TIUDA,TIUITEM,.TIUJ,.TIUL)
  1.  I $L($G(TIUREC(8925,+TIUDA,1601))) D
  1.  . N TIUMODE
  1.  . S TIUJ=+$G(TIUJ)+1,^TMP("TIUVIEW",$J,TIUITEM,TIUJ,0)="",TIUL=+$G(TIUL)+1
  1.  . S TIUJ=+$G(TIUJ)+1
  1.  . S ^TMP("TIUVIEW",$J,TIUITEM,TIUJ,0)=$G(TIUREC(8925,TIUDA,1601))_"  AMENDMENT FILED:"
  1.  . S TIUL=+$G(TIUL)+1
  1.  . S TIUJ=+$G(TIUJ)+1,^TMP("TIUVIEW",$J,TIUITEM,TIUJ,0)="",TIUL=+$G(TIUL)+1
  1.  . S TIUJ=+$G(TIUJ)+1
  1.  . S TIUMODE=$S($G(TIUREC(8925,TIUDA,1603))]"":"/es/ ",1:"/chart/ ")
  1.  . S ^TMP("TIUVIEW",$J,TIUITEM,TIUJ,0)=TIUMODE_$G(TIUREC(8925,TIUDA,1602))
  1.  . S TIUL=+$G(TIUL)+1
  1.  . S TIUJ=+$G(TIUJ)+1
  1.  . ;S ^TMP("TIUVIEW",$J,TIUITEM,TIUJ,0)=$P(TIUPRM1,U,5)
  1.  . S TIUL=+$G(TIUL)+1
  1.  I +$G(TIUACCUM) D
  1.  . S TIUJ=+$G(TIUJ)+1
  1.  . S ^TMP("TIUVIEW",$J,TIUITEM,TIUJ,0)=" "
  1.  . S TIUL=+$G(TIUL)+1
  1.  . S TIUJ=+$G(TIUJ)+1
  1.  . S $P(^TMP("TIUVIEW",$J,TIUITEM,TIUJ,0),"=",79)=""
  1.  . S TIUL=+$G(TIUL)+1
  1.  ; S ^TMP("TIUVIEW",$J,TIUITEM,0)=$G(^TIU(8925,+TIUDA,"TEXT",0))
  1.  S TIUY="^TMP(""TIUVIEW"","_$J_")",TIUL=+$P($G(^TMP("TIUVIEW",$J,0)),U,3)+TIUL
  1.  S ^TMP("TIUVIEW",$J,0)="^^"_TIUL_U_TIUL_U_DT,VALMCNT=TIUL
  1.  Q
  1. LOADREC(TIUDA,TIUITEM,TIUJ,TIUL,TIUDAD) ; Load ^TMP
  1.  N TIUKID,TIUDADT,TIUI S TIUI=0
  1.  F  S TIUI=$O(^TIU(8925,+TIUDA,"TEXT",TIUI)) Q:+TIUI'>0  D
  1.  . S TIUJ=+$G(TIUJ)+1
  1.  . S ^TMP("TIUVIEW",$J,TIUITEM,TIUJ,0)=$G(^TIU(8925,+TIUDA,"TEXT",+TIUI,0))
  1.  . S TIUL=+$G(TIUL)+1
  1.  S TIUKID=0
  1.  F  S TIUKID=$O(^TIU(8925,"DAD",+TIUDA,TIUKID)) Q:+TIUKID'>0  D
  1.  . N TIUTYP S TIUTYP=$P($G(^TIU(8925.1,+$G(^TIU(8925,+TIUKID,0)),0)),U)
  1.  . I TIUTYP="ADDENDUM" D LOADADD(TIUKID,.TIUL) I 1
  1.  . E  D LOADREC(TIUKID,TIUITEM,.TIUJ,.TIUL,TIUDA)
  1.  Q
  1. LOADADD(TIUDADD,TIUL) ; Load addenda
  1.  N TIUDAUTH,TIUDATT,TIUJ,TIUSIG,TIUCSIG
  1.  ;I +$$CANSEE^TIULP(+TIUDADD)'>0 Q
  1.  S TIUJ=0,TIUI=+$G(TIUL)+1,^TMP("TIUVIEW",$J,TIUDADD,TIUI,0)=" "
  1.  S TIUDADT=$$DATE^TIULS($P(^TIU(8925,+TIUDADD,13),U),"MM/DD/YY")
  1.  S TIUI=TIUI+1,^TMP("TIUVIEW",$J,TIUDADD,TIUI,0)=TIUDADT_" ADDENDUM:"
  1.  F  S TIUJ=$O(^TIU(8925,+TIUDADD,"TEXT",TIUJ)) Q:+TIUJ'>0  D
  1.  . S (TIUI,TIUL)=+$G(TIUI)+1
  1.  . S ^TMP("TIUVIEW",$J,TIUDADD,TIUI,0)=$G(^TIU(8925,+TIUDADD,"TEXT",TIUJ,0))
  1.  S (TIUI,TIUL)=TIUL+1
  1.  S TIUSIG=$S(+$P(^TIU(8925,+TIUDADD,15),U)&($P(^(15),U,3)="E"):"/es/ ",1:"     ")_$$SIGNAME^TIULS($P(^TIU(8925,+TIUDADD,15),U,2))
  1.  S TIUCSIG=$S(+$P(^TIU(8925,+TIUDADD,15),U,5)&($P(^(15),U,7)="E"):"/es/ ",1:"     ")_$$SIGNAME^TIULS($P(^TIU(8925,+TIUDADD,15),U,6))
  1.  S TIUSIG=$$SETSTR^VALM1(TIUSIG,$G(TIUSIG),1,35)
  1.  S TIUSIG=$$SETSTR^VALM1(TIUCSIG,$G(TIUSIG),40,35)
  1.  S ^TMP("TIUVIEW",$J,TIUDADD,TIUI,0)=TIUSIG
  1.  S (TIUI,TIUL)=TIUL+1
  1.  S TIUDAUTH=$$SIGNAME^TIULS($P(^TIU(8925,+TIUDADD,12),U,2))
  1.  S TIUDATT=$$SIGNAME^TIULS($P(^TIU(8925,+TIUDADD,12),U,4))
  1.  S TIUDAUTH=$$SETSTR^VALM1($S(TIUSIG]"     "&(TIUSIG'[TIUDAUTH):"for  ",1:"     ")_TIUDAUTH,$G(TIUDAUTH),1,35)
  1.  S TIUDAUTH=$$SETSTR^VALM1($S(TIUCSIG]"     "&(TIUCSIG'[TIUDATT):"for  ",1:"     ")_TIUDATT,$G(TIUDAUTH),40,35)
  1.  S ^TMP("TIUVIEW",$J,TIUDADD,TIUI,0)=TIUDAUTH
  1.  Q
  1. SETREC(LINE) ; Calls $$SETSTR^VALM1 for each line of ^TMP("TIUVIEW",$J,
  1.  N Y
  1.  I LINE="HDR" D
  1.  . S Y=$$SETSTR^VALM1($$NAME^TIULS(TIU("PNM"),"LAST,FI MI"),$G(Y),1,15)
  1.  . S Y=$$SETSTR^VALM1(TIU("SSN"),$G(Y),16,12)
  1.  . S Y=$$SETSTR^VALM1($P(TIU("WARD"),U,2),$G(Y),30,20)
  1.  . I +TIU("DOCTYP")=1 D
  1.  . . S Y=$$SETSTR^VALM1("Adm: "_$$DATE^TIULS(+TIU("EDT"),"MM/DD/YY"),$G(Y),51,13)
  1.  . . S Y=$$SETSTR^VALM1("Dis: "_$$DATE^TIULS(+TIU("LDT"),"MM/DD/YY"),$G(Y),66,13)
  1.  . I +TIU("DOCTYP")'=1 D
  1.  . . S Y=$$SETSTR^VALM1("Visit Date: "_$$DATE^TIULS(+TIU("EDT"),"MM/DD/YY@HR:MIN"),$G(Y),53,26)
  1.  I LINE=1 D
  1.  . S Y=$$SETSTR^VALM1("DICT DATE: "_$G(TIUREC(8925,+TIUDA,1301)),$G(Y),3,39)
  1.  . S Y=$$SETSTR^VALM1("TRANSC DATE: "_$G(TIUREC(8925,+TIUDA,1201)),$G(Y),37,39)
  1.  I LINE=2 D
  1.  . S Y=$$SETSTR^VALM1("ATTENDING: "_$G(TIUREC(8925,+TIUDA,1204)),$G(Y),39,40)
  1.  . I +$G(^TIU(8925,+TIUDA,0))=$$CHKFILE^TIUADCL(8925.1,"OPERATION REPORT","I $P(^(0),U,4)=""DOC""") S Y=$$SETSTR^VALM1("SURGEON: "_$G(TIUREC(8925,+TIUDA,1202)),$G(Y),1,32) Q
  1.  . S Y=$$SETSTR^VALM1("DICTATED BY: "_$G(TIUREC(8925,+TIUDA,1202)),$G(Y),1,32)
  1.  I LINE=3 D
  1.  . S Y=$$SETSTR^VALM1("URGENCY: "_$G(TIUREC(8925,+TIUDA,.09)),$G(Y),5,36)
  1.  . S Y=$$SETSTR^VALM1("DOC STATUS: "_$G(TIUREC(8925,+TIUDA,.05)),$G(Y),38,41)
  1.  Q Y