Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: VAFCQRY

VAFCQRY.m

Go to the documentation of this file. 
  1. VAFCQRY ;BIR/DLR-Query for patient demographics ;10/18/2000
  1.  ;;5.3;Registration;**428,575,627,707,1015**;Aug 13, 1993;Build 21
  1.  ;   
  1. IN ;process in the patient query
  1.  N IEN,HLA,VAFCCNT,ICN,CLAIM,SG,VAFCER,VAFC,DFN,STATE,CITY,SUBCOMP,COMP,REP,LVL,LVL2,VAFC,SSN
  1.  S VAFCCNT=1,VAFCER=1
  1.  F VAFC=1:1 X HLNEXT Q:HLQUIT'>0  S SG=$E(HLNODE,1,3) D:$T(@SG)]"" @SG
  1.  D CHKID^VAFCQRY2(.ICN,.SSN,.DFN)
  1.  I $G(DFN)'>0 S VAFCER="-1^Unknown ICN#"_$G(ICN)_" and SSN#"_$G(SSN)
  1.  S ^TMP("HLA",$J,VAFCCNT)="MSA"_HL("FS")_"AA"_HL("FS")_HL("MID")_HL("FS")_$S(+$G(VAFCER)'>0:$P(VAFCER,"^",2),1:""),VAFCCNT=VAFCCNT+1
  1.  S ^TMP("HLA",$J,VAFCCNT)=VAFCQRD,VAFCCNT=VAFCCNT+1
  1.  I $G(VAFCER)>0 D BLDRSP(DFN,.VAFCCNT)
  1.  D LINK^HLUTIL3(SITE,.VAFC) S IEN=$O(VAFC(0)) S HLL("LINKS",1)="^"_VAFC(IEN)
  1.  D GENACK^HLMA1(HL("EID"),HLMTIENS,HL("EIDS"),"GM",1,.HLRESLTA,"",.HL)
  1.  K VAFCER,VAFCID,COMP,SITE,VAFCFS,VAFCRCV,VAFCQRD,^TMP("HLA",$J)
  1.  Q
  1. RESP ;Response processing initiated from the MPI.
  1.  Q
  1. ROUTE ;Routine logic initiated from the MPI.
  1.  Q
  1. BLDRSP(DFN,VAFCCNT) ;
  1.  N EVN,PID,PD1,SEQ,ERR,CNT,X,PV2,RADE,LABE,PRES
  1.  ;construct EVN (for TF Event Type AND Last Treatment Date)
  1.  S SEQ="1,2" D BLDEVN(DFN,.SEQ,.EVN,.HL,"A19",.ERR) S ^TMP("HLA",$J,VAFCCNT)=EVN(1) S VAFCCNT=VAFCCNT+1
  1.  ;construct PID
  1.  S SEQ="ALL" D BLDPID(DFN,1,.SEQ,.PID,.HL,.ERR) S ^TMP("HLA",$J,VAFCCNT)=PID(1) S X=1,CNT=1 F  S X=$O(PID(X)) Q:'X  I $D(PID(X)) S ^TMP("HLA",$J,VAFCCNT,CNT)=PID(X),CNT=CNT+1
  1.  S VAFCCNT=VAFCCNT+1
  1.  ;construct PD1 **707
  1.  ;S SEQ="3" D BLDPD1(DFN,.SEQ,.PD1,.HL,.ERR) S ^TMP("HLA",$J,VAFCCNT)=PD1(1)
  1.  S PD1=$$PD1^VAFCSB I PD1'="" S ^TMP("HLA",$J,VAFCCNT)=PD1,VAFCCNT=VAFCCNT+1 ;**707
  1.  S PV1=$$PV1^VAFCSB I PV1'="" S ^TMP("HLA",$J,VAFCCNT)=PV1,VAFCCNT=VAFCCNT+1 ;**707
  1.  S PV2=$$PV2^VAFCSB I PV2'="" S ^TMP("HLA",$J,VAFCCNT)=PV2,VAFCCNT=VAFCCNT+1 ;**707
  1.  S PRES=$$PHARA^VAFCSB I PRES'="" S ^TMP("HLA",$J,VAFCCNT)=PRES,VAFCCNT=VAFCCNT+1 ;**707
  1.  S LABE=$$LABE^VAFCSB I LABE'="" S ^TMP("HLA",$J,VAFCCNT)=LABE,VAFCCNT=VAFCCNT+1 ;**707
  1.  S RADE=$$RADE^VAFCSB I RADE'="" S ^TMP("HLA",$J,VAFCCNT)=RADE,VAFCCNT=VAFCCNT+1 ;**707
  1.  ;** PATCH 575
  1.  ;construct ZPD segment
  1.  S SEQ="1,17,21,34" ;**707 Added 1, 21 and 34 to ZPD fields
  1.  S ^TMP("HLA",$J,VAFCCNT)=$$EN1^VAFHLZPD(DFN,SEQ)
  1.  S VAFCCNT=VAFCCNT+1
  1.  Q
  1. MSH ;process MSH segment
  1.  S VAFCFS=HL("FS")
  1.  S HLQ=HL("Q"),HLFS=HL("FS"),HLECH=HL("ECH")
  1.  S VAFCID=HL("MID")
  1.  S COMP=$E(HL("ECH"),1)
  1.  S REP=$E(HL("ECH"),2)
  1.  S SUBCOMP=$E(HL("ECH"),4)
  1.  S SITE=$$LKUP^XUAF4($P($P(HLNODE,HL("FS"),4),COMP))
  1.  Q
  1. QRD ;process QRD segment
  1.  N QRD,X,IDS,WSF,ID,QRDAA,QRDNTC
  1.  S VAFCQRD=HLNODE
  1.  S VAFCRCV=$P(VAFCQRD,HL("FS"),5)
  1.  S IDS=$P(VAFCQRD,HL("FS"),9)
  1.  F X=1:1:$L(IDS,REP) S WSF=$P(IDS,REP,X) D
  1.  . ;get id, assigning authority, and name type code
  1.  . S ID=$P(WSF,COMP),QRDAA=$P($P(WSF,COMP,9),SUBCOMP),QRDNTC=$P(WSF,COMP,10)
  1.  . ;check assigning authority(0363) AND name type code(0203)
  1.  . I QRDAA="USVHA" D
  1.  .. I QRDNTC="NI" S ICN=ID  ;National unique individual identifier
  1.  .. I QRDNTC="PI" S DFN=ID  ;Patient internal identifier
  1.  . I QRDAA="USSSA" D
  1.  .. I QRDNTC="SS" S SSN=ID  ;Social Security number
  1.  Q
  1. BLDEVN(DFN,SEQ,EVN,HL,EVR,ERR) ;build EVN for TF last treatment date and event reason
  1.  ; At this point only sequence one and two are supported
  1.  ; Variable list
  1.  ;  DFN - internal PATIENT (#2) number
  1.  ;  SEQ - variable consisting of sequence numbers delimited by commas
  1.  ;        that will be used to build the message
  1.  ;  EVN (passed by reference) - array location to place EVN segment result, the array can have existing values when passed.
  1.  ;   HL - array that contains the necessary HL variables (init^hlsub)
  1.  ;  EVR - event reason that triggered this message
  1.  ;  ERR - array that is used to return an error
  1.  ;
  1.  D BLDEVN^VAFCQRY2(DFN,SEQ,.EVN,.HL,EVR,.ERR)
  1.  Q
  1. BLDPD1(DFN,SEQ,PD1,HL,ERR) ;
  1.  ; At this point only sequence 3 is supported
  1.  ; Variable list
  1.  ;  DFN - internal PATIENT (#2) number
  1.  ;  SEQ - variable consisting of sequence numbers delimited by commas
  1.  ;        that will be used to build the message
  1.  ;  PD1 (passed by reference) - array location to place PD1 segment result, the array can have existing values when passed.
  1.  ;   HL - array that contains the necessary HL variables (init^hlsub)
  1.  ;  ERR - array that is used to return an error
  1.  ;
  1.  D BLDPD1^VAFCQRY2(DFN,SEQ,.PD1,.HL,.ERR)
  1.  Q
  1. BLDPID(DFN,CNT,SEQ,PID,HL,ERR) ;build PID from File #2
  1.  ;The required sequences 3 and 5 will be returned and at this point
  1.  ;sequences 1-3,5-8,10-14,16,17,19,22-24 and 29 are supported
  1.  ;
  1.  ; At this point only sequence one and two are supported
  1.  ; Variable list
  1.  ;  DFN - internal PATIENT (#2) number
  1.  ;  CNT - value to be place in PID seq#1 (SET ID)
  1.  ;  SEQ - variable consisting of sequence numbers delimited by commas
  1.  ;        that will be used to build the message
  1.  ;  PID (passed by reference) - array location to place PID segment
  1.  ;        result, the array can have existing values when passed.
  1.  ;   HL - array that contains the necessary HL variables (init^hlsub)
  1.  ;  ERR - array that is used to return an error
  1.  ;
  1.  ;if this is a mismatch a null or """" should be passed in, so that
  1.  ;the ICN will be removed at the site
  1.  ;
  1.  D BLDPID^VAFCQRY1(DFN,CNT,SEQ,.PID,.HL,.ERR)
  1.  Q