Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: VENPCC10

VENPCC10.m

Go to the documentation of this file. 
  1. VENPCC10 ; IHS/OIT/GIS - CREATE THE PCC+ ENCOUNTER FORM AND HEALTH SUMMARY ;
  1.  ;;2.6;PCC+;;NOV 12, 2007
  1.  ;
  1.  ; POINTS TO NEW DATA EXTRACTION METHODS FOR VER 2.2 AND 2.5
  1.  ; PATCH 4 INCLUDES SUPPORT FOR LABEL PRINTERS
  1.  ;
  1. PRINT(VISIT,VCN,DEPTIEN,PRV,DEFEF,DEFHS,APPT,VARS,EXT) ; EP-PRINT ENCOUNTER FORMS
  1.  ; VISIT=visit ien, VCN=visit control id, PRV=providerien, DEFEF=default enc form IEN, DEFHS=default health summary IEN
  1.  N X S X="MERR^VENPCC1",@^%ZOSF("TRAP") ; SET M ERROR TRAP FOR THIS BACKGROUND PROCESS
  1.  I $L($G(VARS)) S U="^" D UNPACK(VARS) K VARS
  1.  I $D(^VA(200,+$G(PRV),0)),$D(^VEN(7.95,+$G(DEPTIEN),0))
  1.  E  Q
  1.  I $G(JOB),'$G(MOJOFLAG) S %=$NA(^TMP("VEN MON")),@%@(JOB)="Monitoring the process...." H 3
  1. NEW N %,%1,%DT,%HELP,%Q,%T,%Y,CFIGIEN,DATE,DFN,ERR,PATH2,PIEN,POP
  1.  N STOP,TMP,UID,X,Y,MSG,FFIEN,FCIEN,PEIEN,VER25,HDR25,LPFLAG,FCIEN
  1. GO I '$D(VENDEBUG),'$D(^TMP("VEN TASK")) X ("J"_" ^VENPCCP") ; IF NECESSARY, START THE PRINT DEAMON
  1.  I VISIT[U S DFN=$P(VISIT,U,2),DATE=$P(VISIT,U,3),VISIT=$P(VISIT,U) N NOVISIT S NOVISIT=1 G CFG
  1.  S X=$G(^AUPNVSIT(VISIT,0)) I X="" D ERR1^VENPCC1 Q
  1.  S DATE=+X,DFN=$P(X,U,5)
  1.  I 'DATE D ERR3^VENPCC1 Q
  1.  I $G(VENDEMO) D NOW^%DTC S DATE=% K %,%H,%I
  1.  I '$D(^AUPNPAT(DFN)) D ERR3^VENPCC1 Q
  1.  S X=$G(^VEN(7.95,+$G(DEPTIEN),5)) I $P(X,U,3),$P(X,U,2),+X S LPFLAG=$P(X,U,1,2) ; LABEL PRINTER FLAG
  1. BEF I $G(DEFEF),$P($G(^VEN(7.41,DEFEF,0)),U,13) D ERR11^VENPCC1 Q  ; ENCOUNTER FORM TEMPORARILY BLOCKED
  1. CFG S CFIGIEN=$$CFG^VENPCCU I 'CFIGIEN D ERR8^VENPCC1 Q
  1.  I $G(HSONLY),'$G(OGFLAG),'$G(LPFLAG) X ("I 0") G HS ; JUST PRINT HS - NOTHING MORE
  1. EF S TMP="^TMP(""VEN PRNT"",$J)" K @TMP,STOP
  1.  S VER25=$P($G(^VEN(7.5,CFIGIEN,13)),U) ; NO HEADER FILE RED'Q IN VER 2.5
  1.  S HDR25=($P($G(^VEN(7.41,+$G(DEFEF),0)),U,2)=25)
  1.  I $D(DEMODATA) D HEAD25 ; IN VERSION 25, ONLY NEED TO SET TMP(9) GLOBAL IF IN DEMODATA MODE
  1.  I 'VER25,'$D(DEMODATA) D HEAD I $D(STOP) D ERR10^VENPCC1 Q  ; TEMPORARY HEADER GLOBAL
  1.  D DEMO^VENPCC1A(PRV,DFN,VCN,VISIT,DEPTIEN,$G(APPT)) I $G(STOP) D ERR5^VENPCC1 Q  ; DEMOPGRAPHICS
  1.  D SPEC^VENPCC1A(DFN) ; REPRO HX
  1.  D DX^VENPCC1G(PRV,DFN,DEFEF,DEPTIEN) I $G(STOP) D ERR6^VENPCC1 Q  ; DUAL CODES NEW VERSION
  1.  D PROB^VENPCC1H(DFN) ; PROBLEMS AND POVS FOR VER 2.5
  1.  D MED^VENPCC1H(PRV,DFN) I $G(STOP) D ERR6^VENPCC1 Q  ; VER 2.2 EXTENSION
  1.  I $L($G(EXT)) D EXT^VENPCC1B(EXT) ; PROCESS EXTERNAL DATA
  1.  D HDR(DEPTIEN) ; TEMPLATE HEADER
  1.  D SYS(DFN,+$G(DEFEF)) ; IMMUNIZATIONS, ORDRABLES AND REMINDERS
  1.  D ALLERG^VENPCC1C(DFN) ; ALLERGIES
  1.  D HX^VENPCC1F(DFN,DEFEF) ; HX OF SURG, FAMILY HX, PERSONAL HX, PODIATRY HX
  1.  N SPECHOLD I $D(^VEN(7.62,"AB",DEFEF)) D SPEC^VENPCC1C(DFN,DEFEF) ; LINK TO OCX OBJECTS ON PEDS FORM
  1.  S %=$G(^VEN(7.41,+$G(DEFEF),4)) I $L(%) X ("D "_%_"(DFN)") ; SPECIAL DATA MINING CODE FOR THIS TEMPLATE
  1. V22 I $L($T(VER22^VENPCC1G)) D VER22^VENPCC1G(DFN,PRV,VISIT,DEFEF,DEPTIEN) ; UPDATED VER 2.2 EXTENSIONS
  1. V25 I $L($T(VER25^VENPCC1L)) D VER25^VENPCC1L(DFN,PRV,VISIT,DEFEF,DEPTIEN) ; VER 2.5 EXTENSIONS
  1. ANMC I DUZ(2)=1665,$L($T(^VENPCCAK)) D ^VENPCCAK(DFN,DEFEF) ; CUSTOM PCC+ CODE FOR ALASKA
  1. FORM I $P($G(^VEN(7.41,+$G(DEFEF),21)),U),$L($T(FORM^VENPCC1S)) D FORM^VENPCC1S(DFN,VISIT,DEFEF) ; COMPONENT FRAMEWORK DATA
  1. MOJO I $D(MOJOFLAG),$L($T(MOJODATA^VENPCCW)) D  Q  ; SPECIAL EXTENSIONS FOR MOJO (VER 3.0)
  1.  . S @TMP@(1,"u100")=$P($G(^VEN(7.46,+$G(DEFEF),0)),U,2) I @TMP@(1,"u100")="" Q  ; NEW WAY TO GET THE FID FROM THE MOJO FORM FILE
  1.  . D MOJODATA^VENPCCW ; OUTPUTS DATA DIRECTLY TO MOJO ADO ARRAY
  1.  . Q
  1.  I $G(HSONLY),$G(OGFLAG) S OGONLY=1 D TXT^VENPCC1(DFN) K OGONLY,OGFLAG,@TMP X ("I 0") G HS ; HS ONLY WITH OUTGUIDE
  1. DATA D TXT^VENPCC1(DFN) I $D(STOP) Q  ; BUILD THE DATA FILE FOR THE CURRENT TEMPLATE
  1.  K @TMP
  1.  I $G(EFONLY)!($G(OGONLY))
  1. HS E  D HS^VENPCC2A(DFN,DEFHS,VISIT,DEPTIEN) ; BUILD THE HEALTH SUMMARY DATA FILE
  1.  I $G(JOB) K ^TMP("VEN MON",JOB)
  1.  Q
  1.  ;
  1. UNPACK(VARS) ; EP-FOR UNPACKING THE LOCAL VARIABLE LIST
  1.  I '$L($G(DUZ(0))) S %=$C(68,85,90),@%@(0)=$C(64)
  1.  N I,X,Y,%
  1.  F I=1:1:$L(VARS,U) S %=$P(VARS,U,I) I $L(%) S X=$P(%,"=",1),Y=$P(%,"=",2,99) X "S "_X_"="""_Y_""""
  1.  Q
  1.  ; 
  1.  ; TRADITIONAL WAY TO BUILD THE HEADER ARRAY
  1.  NEW F,I,X,Y,%
  1.  S PATH2=$G(^VEN(7.5,CFIGIEN,2))
  1.  I PATH2="" S STOP=1 D ERR7^VENPCC1 Q
  1.  S %=$$HEADER^VENPCCU(+$G(DEFEF))
  1.  S F=%_"header.txt"
  1.  S POP=$$OPN^VENPCCP(PATH2,F,"R","R X")
  1.  I POP S STOP=1 Q
  1.  F I=1:1:$L(X,U) S Y=$P(X,U,I),@TMP@(9,I)=Y
  1.  Q
  1.  ;
  1. HEAD25 ; EP - MAKE HEADER GLOBAL FOR VERSION 25
  1.  N HGIEN,HIEN,HDR,MN,CNT
  1.  S HGIEN=$O(^VEN(7.49,"B","25",0)) I 'HGIEN Q
  1.  S HIEN=0,CNT=0
  1.  F  S HIEN=$O(^VEN(7.49,HGIEN,1,HIEN)) Q:'HIEN  D
  1.  . S MN=$G(^VEN(7.49,HGIEN,1,HIEN,0)) I '$L(MN) Q
  1.  . S CNT=CNT+1
  1.  . S @TMP@(9,CNT)=MN
  1.  . Q
  1.  Q
  1.  ; 
  1. HDR(DEPTIEN) ; EP - HEADER LINES
  1.  NEW %,I,X
  1.  S X=$P($G(^VEN(7.95,DEPTIEN,0)),U) S %=$P($G(^(0)),U,4)
  1.  I % S %=$P($G(^DIC(40.7,%,0)),U,2) I $L(%) S X=X_" "_"("_%_")"
  1.  S @TMP@(1,"hdr")=X
  1.  Q
  1.  ; 
  1. MRP() ; EP-RETURN THE MEDICAL RECORDS PRINTER GROUP
  1.  N IEN,NAME
  1.  S IEN=$P($G(^VEN(7.95,+$G(DEPTIEN),2)),U,16)
  1.  I 'IEN S IEN=$O(^VEN(7.4,"AC",1,0)) I 'IEN Q ""
  1.  S NAME=$P($G(^VEN(7.4,IEN,0)),U)
  1.  Q NAME
  1.  ;
  1. SYS(DFN,DEFEF)  ; EP-NEW SYSTEM PREFERENCES
  1.  I '$D(^DPT(DFN,0)) Q
  1.  I '$D(^VEN(7.41,+$G(DEFEF),0)) Q
  1.  N MIEN,TYPE,MMF,PCE,CLASS,SS,HIEN,OSET,NEWSURV,NEWIMM
  1.  S CLASS=$$CLASS^VENPCC1C(DFN) I 'CLASS Q
  1.  S NEWSURV=0 I $P($G(^VEN(7.41,+$G(DEFEF),5)),U,1) S NEWSURV=1 ; USE NEW SURVEILLANCE LIST
  1.  S NEWIMM=0 X "I $L($T(IMMHX^BIRPC)),$L($T(BI^APCHS11C)),$$BI^APCHS11C S NEWIMM=1" ; USE IMMUNIZATION PKG 7.0
  1. CHKLST I $O(^VEN(7.41,+$G(DEFEF),17,0)),$L($T(POP^VENPCCC)),$P($G(^VEN(7.41,DEFEF,0)),U,17) D POP^VENPCCC(DEFEF,DFN) G TICK ; NEW CHECKLIST, VER 2.5
  1. ORD S OSET=$$OSET^VENPCC1C(+$G(DEFEF)),SS=7.93 ; CHECK ORDERABLES FILE AND GET ALL ORDERABLES FOR THIS DEMOG GRP
  1.  S HIEN=0 F  S HIEN=$O(^VEN(7.42,"AS",1,HIEN)) Q:'HIEN  D  ; ONLY  MM FIELDS FOR ORDERABLES ARE CHECKED
  1.  . S MMF=$P($G(^VEN(7.42,HIEN,0)),U) I '$L(MMF) Q  ; GET MAIL MERGE FIELD NAME
  1.  . S MIEN=0
  1. OSET . I $G(OSET) D  Q  ; IF ORDER SETS ARE DEFINED
  1.  .. F  S MIEN=$O(^VEN(7.93,"AS",OSET,MMF,MIEN)) Q:'MIEN  I $$XSET^VENPCC1C(SS,DFN,MIEN,MMF,CLASS,DEFEF) Q  ; FIND MM FIELD THAT MATCHES THE PATIENTS CLASS AND ASSIGN VALUE
  1.  .. Q
  1. NOOSET .. ; IF ORDER SETS NOT DEFINED
  1.  . F  S MIEN=$O(^VEN(7.93,"C",MMF,MIEN)) Q:'MIEN  I $$XSET^VENPCC1C(SS,DFN,MIEN,MMF,CLASS,DEFEF) Q  ; FIND MM FIELD THAT MATCHES THE PATIENTS CLASS AND ASSIGN VALUE
  1.  . Q
  1. TICK S SS=7.94 ; CHECK TICKLER FILE
  1. ROS S MMF="x" ; GET ROS DATA
  1.  F  S MMF=$O(^VEN(7.94,"C",MMF)) Q:MMF'["x"  D  ; L0OP THROUGH ALL THE "x" MAIL MERGE FIELDS IN TICKLER FILE
  1.  . S MIEN=0
  1.  . F  S MIEN=$O(^VEN(7.94,"C",MMF,MIEN)) Q:'MIEN  I $$XSET^VENPCC1C(SS,DFN,MIEN,MMF,CLASS,DEFEF) Q  ; FIND MM FIELD THAT MATCHES THE PATIENTS CLASS AND ASSIGN VALUE
  1.  . Q
  1. SURV ; GET HEALTH MAINT REMINDER DATA
  1.  I 'NEWSURV,'NEWIMM D OLDSURV Q  ; OLD SURVEILLANCE METHOD
  1.  I NEWSURV,NEWIMM D NEWSURV,NEWIMM Q  ; NEW SURVEILLANCE METHODS
  1.  D OLDSURV
  1.  I NEWIMM D IF^VENPCC1C Q
  1.  D ARR^VENPCC1E(+$G(DFN))
  1.  Q
  1.  ; 
  1. OLDSURV S MMF="h" ; GET HEALTH MAINT REMINDER DATA THE OLD WAY
  1.  F  S MMF=$O(^VEN(7.94,"C",MMF)) Q:MMF'["h"  D  ; L0OP THROUGH ALL THE "h" MAIL MERGE FIELDS IN TICKLER FILE
  1.  . S MIEN=0
  1.  . F  S MIEN=$O(^VEN(7.94,"C",MMF,MIEN)) Q:'MIEN  I $$XSET^VENPCC1C(SS,DFN,MIEN,MMF,CLASS,DEFEF) Q  ; FIND MM FIELD THAT MATCHES THE PATIENTS CLASS AND ASSIGN VALUE
  1.  . Q
  1.  Q
  1.  ;
  1. NEWSURV ; EP - NEW METHOD FOR GETTING HEALTH MAINT REMINDER DATA ; h26-h50
  1.  D ARR^VENPCC1E(+$G(DFN))
  1.  Q
  1.  ;
  1. NEWIMM ; EP - NEW METHOD FOR GETTING IMM HX ; h9-h25
  1.  D IF^VENPCC1C
  1.  Q
  1.  ;