Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: VENPCCID

VENPCCID.m

Go to the documentation of this file. 
  1. VENPCCID ; IHS/OIT/GIS - INSTALLATION TOOLS: ADD A NEW TEMPLATE FOR VER 2.5 ENTER/EDIT PCC+ CONFIG FILE ;
  1.  ;;2.6;PCC+;;NOV 12, 2007
  1.  ;
  1.  ; 
  1.  ;
  1.  N DIC,DIE,X,Y,Z,%,CIEN,FLD,DA,DR,CNM,SEP,RXFLAG
  1.  S SEP="-------------------"
  1.  S RXFLAG=0
  1.  S X=$O(^PSRX("AD",9999999),-1) I X,$$FMDIFF^XLFDT(DT,X)<7 S RXFLAG=1 ; PHARMACY PKG IS IN ACTIVE USE
  1.  S %=$O(^VEN(7.5,"AC",1,0)) I % S CIEN=%,CNM=$P($G(^VEN(7.5,CIEN,0)),U) W !!,"Editing the ",CNM," configuration...",!! G SYS
  1.  S DIC("B")="PRIMARY" S DIC("A")="Enter the name of the primary configuration set for PCC+: "
  1.  S DIC="^VEN(7.5,",DIC(0)="AEQL",DLAYGO=19707.5
  1.  D ^DIC I Y=-1 Q
  1.  S CIEN=+Y S CNM=$P(Y,U,2) W !!
  1. SYS ; SYSTEM PROPERTIES
  1.  W SEP,"  SYSTEM PROPERTIES  ",SEP,!!
  1.  S DIE="^VEN(7.5,",DA=CIEN
  1.  S DR=".07////1;.04RPMS Server OS (Winows or Unix);.05MUMPS OS (Cache or MSM);"
  1.  S DR=DR_".03Facility type (IHS or TRIBAL or 638);"
  1.  S DR=DR_"13.01Print Service (VER 2.2 or VER 2.5);.23Get allergies from ART Package;.19Always use expanded sigs;"
  1.  I RXFLAG S DR=DR_".16Apply chronic med filter to all templates;"
  1.  S DR=DR_".21Automatically clean out inactive data files"
  1.  D DIE
  1. DEF ; DEFAULT PATIENT AND PROVIDER
  1.  K DIC
  1.  W !!,SEP,"  DEFAULT PATIENT AND PROIVIDER  ",SEP
  1.  W !!,"Enter the name of the system-wide default provider.  When all else fails,"
  1.  W !,"this provider's ICD preferences will be used to populate the template.",!
  1.  S DIE="^VEN(7.5,",DA=CIEN
  1.  I $P($G(^VEN(7.5,CIEN,0)),U,13) S DR=".13Default provider" D DIE G DEF1
  1.  S DIC="^VA(200,",DIC(0)="AEQL",DLAYGO=200,DIC("DR")=""
  1.  D ^DIC I Y=-1 G DEF1
  1.  S DIE="^VEN(7.5,",DA=CIEN,DR=".13////"_+Y
  1.  D DIE
  1. DEF1 W !!,"Enter the name of the system-wide default patient.  This patient is used"
  1.  W !,"to test the features of PCC+ without creating a new visit.  The demo patient"
  1.  W !,"must have at least one visit in the system.",!
  1.  K DIC
  1.  I $P($G(^VEN(7.5,CIEN,0)),U,14) S DR=".14Default patient" D DIE G CKIN
  1.  E  S Z=$O(^DPT("B","DEMO,PATIENT",0))
  1.  I Z,$D(^AUPNVSIT("AC",Z)) S DIC("B")="DEMO,PATIENT"
  1.  S DIC="^DPT(",DIC(0)="AEQM"
  1.  D ^DIC I Y=-1 G CKIN
  1.  I '$D(^AUPNVSIT("AC",+Y)) W !,"Can't use this patient!  No visits in the system..." G DEF1
  1.  S DIE="^VEN(7.5,",DA=CIEN,DR=".14////"_+Y
  1.  D DIE
  1. CKIN ; CHECKIN PREFERENCES
  1.  W !!,SEP,"  PCC+ CHECK-IN PREFERENCES  ",SEP
  1.  W !!,"The following preferences are used to configure PCC+'s",!,"native check-in process...",!!
  1.  S DIE="^VEN(7.5,",DA=CIEN
  1.  S DR=".08Enable check in clerk to edit demographics;.09Ask about generating an outguide;"
  1.  S DR=DR_".1Always print health summary in Medical Records;4Enter site managers contact info"
  1.  D DIE
  1. PATH ; ENTER PATHS IP/SOCKET INFO
  1.  W !!,SEP,"  PATHS TO PCC+ FOLDERS AND IP/SOCKET PREFERENCES  ","-----"
  1.  W !!,"In Unix systems, the paths should look something like '/usr/pccplus/print/'"
  1.  W !,"In Windows systems, the paths should look something like 'c:\pccplus\print\'"
  1.  W !,"The default socket for PCC+ is 5143.",!,"Use this socket unless there is a good reason not to",!
  1.  S DIE="^VEN(7.5,",DA=CIEN
  1.  S DR="1Path to print folder;3Path to 'temp' folder;11.1IP address of Print Server 1;"
  1.  S DR=DR_"11.2IP address of print server 2;11.3Print Service socket"
  1.  D DIE
  1.  W !!,SEP,!!,"The primary configuration parameters have been successfully updated..."
  1. FIN D ^XBFMK
  1.  Q
  1.  ;
  1. DIE L +^VEN(7.5,DA):0 I $T D ^DIE L -^VEN(7.5,DA)
  1.  Q
  1.  ;