XINDX10 ;ISC/GRK - assemble DD executable code ;11/12/2002 11:40
;;7.3;TOOLKIT;**20,27,66,68,132**;Apr 25, 1995;Build 14
; Per VHA Directive 2004-038, this routine should not be modified.
ASK ;Ask for Build, Install, or Package file.
N X,Y,P,V,RN
S DA=0,Y=-1,INP(11)=""
S:$D(^DD(9.6,0)) P=9.6,Y=$$BUILD^XTRUTL1 Q:$D(DUOUT) D:Y>0 I Y<0 S:$D(^DD(9.7,0)) P=9.7,Y=$$INSTALL^XTRUTL1 D:Y>0
. S INP(10)=P,DA=+Y,X=$P(Y,"^",2),V=$$VER^XTRUTL1(X)
. S INP(11)="I $P(LIN,"";"",3)'["""_V_""" D E^XINDX1(44)",INP(11.1)=V
. I $L($P(X,"*",3)) S INP(12)="I $P(LIN,"";"",5)'?.E1P1"""_$P(X,"*",3)_"""1P.E S ERR=56,ERR(1)=INP(12.1) D E^XINDX1(.ERR)",INP(12.1)=$P(X,"*",3)
. Q
K DIC Q:$D(DUOUT)
I $D(^DD(9.4,0)),'DA S DIC="^DIC(9.4,",DIC(0)="AEQMZ" D ^DIC S INP(10)=9.4,DA=+Y
Q
;
START ;called from SETUP^XINDX7
G PKG:INP(10)=9.4,NEXT:INP(10)=9.7
;Get routines and other code from BUILD.
W !,"The BUILD file Data Dictionaries are being processed.",!
F J=0:0 S J=$O(^XPD(9.6,DA,4,J)) Q:J'>0 I $D(^(J,0)) S INDFN=+^(0),INDRN="|dd"_INDFN D XPD
G NEXT
PKG W !,"The package file Data Dictionaries are being processed.",!
F J=0:0 S J=$O(^DIC(9.4,DA,4,J)) Q:J'>0 I $D(^(J,0)) S INDFN=+^(0),INDRN="|dd"_INDFN,(INDF,INDL)=0 D INSERT
NEXT D ^XINDX11,REMCOMP:'INP(9) K A,B,C,C9,G,H,INDD,INDEL,INDF,INDFN,INDID,INDL,INDN,INDRN,INDSB,INDX,INDXN,INDXRF,DA,DIC,J,INDLC,INDC
Q
XPD ;Check if Full/Partial DD
N IND1,IND222,J2,J3 S IND222=$G(^XPD(9.6,DA,4,J,222))
S (INDF,INDL)=0 I $P(IND222,"^",3)="f" K IND222 D INSERT Q
;Each entry at the J2 level is a new file/sub-file.
F J2=0:0 S J2=$O(^XPD(9.6,DA,4,J,2,J2)) Q:J2'>0 S IND1=^(J2,0) D
. S INDFN=J2,INDRN="|dd"_INDFN,INDLC=0 Q:'$$HDR()
. ;Each J3 is a field in the file.
. F J3=0:0 S J3=$O(^XPD(9.6,DA,4,J,2,J2,1,J3)) Q:J3'>0 S INDFN=J2,INDF=J3,INDL=0 D STRIP
. S ^UTILITY($J,1,INDRN,0,0)=INDLC
. Q
Q
HDR() ;Display Header and start faux routine build
I '$D(^DD(INDFN)) W !,"File # ",INDFN," is missing !",$C(7) Q 0
S ^UTILITY($J,INDRN)="",NRO=NRO+1 W !,INDFN," ",$O(^DD(INDFN,0,"NM",0))
S INDLC=0,INDC=INDRN_" ;"_$S($D(IND222):"Partial ",1:"")_"DD of the "_$O(^DD(INDFN,0,"NM",0))_$S(INDL:" sub-",1:" ")_"file"_$S(INDL:" of the "_$O(^DD(INDFN(1),0,"NM",0))_" (#"_INDFN(1)_") file.",1:"."),INDX="" D ADD
Q 1
INSERT ;Find executable code in this DD
Q:'$$HDR
ID S INDID=-1 F G=0:0 S INDID=$O(^DD(INDFN,0,"ID",INDID)) Q:INDID="" I $D(^(INDID))#2 S INDC="ID"_INDID_" ; IDENTIFIER CODE FOR "_INDID S INDX=$S(^(INDID)]"":^(INDID),1:"Q") D ADD
W I $D(^DD(INDFN,0,"W"))#2 S INDX=^("W"),INDC="W ; 'W' code ??" D ADD
FLD S INDF=$O(^DD(INDFN,INDF)) I INDF>0 D STRIP W "." G FLD
S ^UTILITY($J,1,INDRN,0,0)=INDLC Q
STRIP ;
S A=$P(^DD(INDFN,INDF,0),"^",2) I A D PUSH,INSERT,POP Q
I A'["W",A'["S" S INDX=$P(^(0),"^",5,99),INDC=INDF_" ; "_$P(^(0),"^",1) D ADD
I $D(^DD(INDFN,INDF,2))#2 S INDC=INDF_"OT ; OUTPUT TRANSFORM CODE",INDX=^(2) D ADD
I $D(^DD(INDFN,INDF,4))#2 S INDC=INDF_"HELP ; EXECUTABLE HELP CODE",INDX=^(4) D ADD
I $D(^DD(INDFN,INDF,12)) S INDC=INDF_"SCR ; "_$E(^(12),1,220) S INDX=$S($D(^(12.1))#2:^(12.1),1:"Q") D ADD
I $D(^DD(INDFN,INDF,7.5))#2 S INDC=INDF_"TPL ; TRANSFORM DONE PRIOR TO THE DIC LOOK-UP",INDX=^(7.5) D ADD
I $D(^DD(INDFN,INDF,"AX"))#2 S INDC=INDF_"AX ; EXECUTABLE AUDIT CHECK CODE",INDX=^("AX") D ADD
F INDEL=9.2:.1:9.9 I $D(^DD(INDFN,INDF,INDEL))#2 S INDC=INDF_"OF"_INDEL_" ; OVERFLOW CODE",INDX=^(INDEL) D ADD
S INDEL="" F S INDEL=$O(^DD(INDFN,INDF,"DEL",INDEL)) Q:INDEL="" I $D(^(INDEL,0))#2 S INDC=INDF_"DEL"_INDEL_" ; DELETE PROTECTION CODE",INDX=^(0) D ADD
S INDEL="" F G=0:0 S INDEL=$O(^DD(INDFN,INDF,"LAYGO",INDEL)) Q:INDEL="" I $D(^(INDEL,0))#2 S INDC=INDF_"LAYGO"_INDEL_" ; LAYGO CHECK CODE",INDX=^(0) D ADD
F INDXRF=0:0 S INDXRF=$O(^DD(INDFN,INDF,1,INDXRF)) Q:INDXRF'>0 S C=$P(^(INDXRF,0),"^",2) F G=0:0 S G=$O(^DD(INDFN,INDF,1,INDXRF,G)) Q:G'>0 D XREFS
Q
XREFS Q:('$D(^(G))#2)!(G=3) ;Node 3 is don't delete comment.
S INDC=INDF_"XRF"_INDXRF_$S(G=1:"S",G=2:"K",1:"n"_G)_" ; "_$S(G<2:"SET",G<3:"KILL",1:"OVERFLOW")_" LOGIC FOR '"_$S(C]"":C,1:INDXRF)_"' XREF",INDX=^(G) D ADD
Q
ADD ;Put code in UTILITY for processing
S INDLC=INDLC+1,^UTILITY($J,1,INDRN,0,INDLC,0)=INDC I INDX]"" S INDLC=INDLC+1,^UTILITY($J,1,INDRN,0,INDLC,0)=" "_INDX
Q
PUSH S INDL=INDL+1 F A="INDFN","INDF","INDLC","INDRN" S @(A_"(INDL)")=@A
S INDFN=+$P(^DD(INDFN,INDF,0),"^",2),INDRN="|dd"_INDFN,(INDLC,INDF)=0
Q
POP F A="INDFN","INDF","INDLC","INDRN" S @A=@(A_"(INDL)")
S INDL=INDL-1 Q
REMCOMP ;Remove compiled template routines from selected list
S %="|dd"
F J=1:1 S %=$O(^UTILITY($J,%)) Q:%'?1"|dd".NP S INDFN=+$E(%,4,999) I '$D(^DD(INDFN,0,"UP")) F F="^DIE(","^DIPT(" S F1=F_"""F"_INDFN_""",",%1="" F J=0:0 S %1=$O(@(F1_"%1)")) Q:%1="" F %2=0:0 S %2=$O(@(F1_"%1,%2)")) Q:%2'>0 D P
Q
P I $D(@(F_"%2,0)")) S R=$E($S($D(^("ROU")):^("ROU"),$D(^("ROUOLD")):^("ROUOLD"),1:""),2,999)
Q:R=""
I $D(^UTILITY($J,R)) K ^UTILITY($J,R)
S RN=R F J=0:0 S RN=$O(^UTILITY($J,RN)) Q:RN=""!(RN'?@("1"""_R_"""1N.N")) K ^UTILITY($J,RN)
Q
XINDX10 ;ISC/GRK - assemble DD executable code ;11/12/2002 11:40
+1 ;;7.3;TOOLKIT;**20,27,66,68,132**;Apr 25, 1995;Build 14
+2 ; Per VHA Directive 2004-038, this routine should not be modified.
ASK ;Ask for Build, Install, or Package file.
+1 NEW X,Y,P,V,RN
+2 SET DA=0
SET Y=-1
SET INP(11)=""
+3 IF $DATA(^DD(9.6,0))
SET P=9.6
SET Y=$$BUILD^XTRUTL1
IF $DATA(DUOUT)
QUIT
IF Y>0
Begin DoDot:1
+4 SET INP(10)=P
SET DA=+Y
SET X=$PIECE(Y,"^",2)
SET V=$$VER^XTRUTL1(X)
+5 SET INP(11)="I $P(LIN,"";"",3)'["""_V_""" D E^XINDX1(44)"
SET INP(11.1)=V
+6 IF $LENGTH($PIECE(X,"*",3))
SET INP(12)="I $P(LIN,"";"",5)'?.E1P1"""_$PIECE(X,"*",3)_"""1P.E S ERR=56,ERR(1)=INP(12.1) D E^XINDX1(.ERR)"
SET INP(12.1)=$PIECE(X,"*",3)
+7 QUIT
End DoDot:1
IF Y<0
IF $DATA(^DD(9.7,0))
SET P=9.7
SET Y=$$INSTALL^XTRUTL1
IF Y>0
Begin DoDot:1
End DoDot:1
+8 KILL DIC
IF $DATA(DUOUT)
QUIT
+9 IF $DATA(^DD(9.4,0))
IF 'DA
SET DIC="^DIC(9.4,"
SET DIC(0)="AEQMZ"
DO ^DIC
SET INP(10)=9.4
SET DA=+Y
+10 QUIT
+11 ;
START ;called from SETUP^XINDX7
+1 IF INP(10)=9.4
GOTO PKG
IF INP(10)=9.7
GOTO NEXT
+2 ;Get routines and other code from BUILD.
+3 WRITE !,"The BUILD file Data Dictionaries are being processed.",!
+4 FOR J=0:0
SET J=$ORDER(^XPD(9.6,DA,4,J))
IF J'>0
QUIT
IF $DATA(^(J,0))
SET INDFN=+^(0)
SET INDRN="|dd"_INDFN
DO XPD
+5 GOTO NEXT
PKG WRITE !,"The package file Data Dictionaries are being processed.",!
+1 FOR J=0:0
SET J=$ORDER(^DIC(9.4,DA,4,J))
IF J'>0
QUIT
IF $DATA(^(J,0))
SET INDFN=+^(0)
SET INDRN="|dd"_INDFN
SET (INDF,INDL)=0
DO INSERT
NEXT DO ^XINDX11
IF 'INP(9)
DO REMCOMP
KILL A,B,C,C9,G,H,INDD,INDEL,INDF,INDFN,INDID,INDL,INDN,INDRN,INDSB,INDX,INDXN,INDXRF,DA,DIC,J,INDLC,INDC
+1 QUIT
XPD ;Check if Full/Partial DD
+1 NEW IND1,IND222,J2,J3
SET IND222=$GET(^XPD(9.6,DA,4,J,222))
+2 SET (INDF,INDL)=0
IF $PIECE(IND222,"^",3)="f"
KILL IND222
DO INSERT
QUIT
+3 ;Each entry at the J2 level is a new file/sub-file.
+4 FOR J2=0:0
SET J2=$ORDER(^XPD(9.6,DA,4,J,2,J2))
IF J2'>0
QUIT
SET IND1=^(J2,0)
Begin DoDot:1
+5 SET INDFN=J2
SET INDRN="|dd"_INDFN
SET INDLC=0
IF '$$HDR()
QUIT
+6 ;Each J3 is a field in the file.
+7 FOR J3=0:0
SET J3=$ORDER(^XPD(9.6,DA,4,J,2,J2,1,J3))
IF J3'>0
QUIT
SET INDFN=J2
SET INDF=J3
SET INDL=0
DO STRIP
+8 SET ^UTILITY($JOB,1,INDRN,0,0)=INDLC
+9 QUIT
End DoDot:1
+10 QUIT
HDR() ;Display Header and start faux routine build
+1 IF '$DATA(^DD(INDFN))
WRITE !,"File # ",INDFN," is missing !",$CHAR(7)
QUIT 0
+2 SET ^UTILITY($JOB,INDRN)=""
SET NRO=NRO+1
WRITE !,INDFN," ",$ORDER(^DD(INDFN,0,"NM",0))
+3 SET INDLC=0
SET INDC=INDRN_" ;"_$SELECT($DATA(IND222):"Partial ",1:"")_"DD of the "_$ORDER(^DD(INDFN,0,"NM",0))_$SELECT(INDL:" sub-",1:" ")_"file"_$SELECT(INDL:" of the "_$ORDER(^DD(INDFN(1),0,"NM",0))_" (#"_INDFN(1)_") file.",1:".")
SET INDX=""
DO ADD
+4 QUIT 1
INSERT ;Find executable code in this DD
+1 IF '$$HDR
QUIT
ID SET INDID=-1
FOR G=0:0
SET INDID=$ORDER(^DD(INDFN,0,"ID",INDID))
IF INDID=""
QUIT
IF $DATA(^(INDID))#2
SET INDC="ID"_INDID_" ; IDENTIFIER CODE FOR "_INDID
SET INDX=$SELECT(^(INDID)]"":^(INDID),1:"Q")
DO ADD
W IF $DATA(^DD(INDFN,0,"W"))#2
SET INDX=^("W")
SET INDC="W ; 'W' code ??"
DO ADD
FLD SET INDF=$ORDER(^DD(INDFN,INDF))
IF INDF>0
DO STRIP
WRITE "."
GOTO FLD
+1 SET ^UTILITY($JOB,1,INDRN,0,0)=INDLC
QUIT
STRIP ;
+1 SET A=$PIECE(^DD(INDFN,INDF,0),"^",2)
IF A
DO PUSH
DO INSERT
DO POP
QUIT
+2 IF A'["W"
IF A'["S"
SET INDX=$PIECE(^(0),"^",5,99)
SET INDC=INDF_" ; "_$PIECE(^(0),"^",1)
DO ADD
+3 IF $DATA(^DD(INDFN,INDF,2))#2
SET INDC=INDF_"OT ; OUTPUT TRANSFORM CODE"
SET INDX=^(2)
DO ADD
+4 IF $DATA(^DD(INDFN,INDF,4))#2
SET INDC=INDF_"HELP ; EXECUTABLE HELP CODE"
SET INDX=^(4)
DO ADD
+5 IF $DATA(^DD(INDFN,INDF,12))
SET INDC=INDF_"SCR ; "_$EXTRACT(^(12),1,220)
SET INDX=$SELECT($DATA(^(12.1))#2:^(12.1),1:"Q")
DO ADD
+6 IF $DATA(^DD(INDFN,INDF,7.5))#2
SET INDC=INDF_"TPL ; TRANSFORM DONE PRIOR TO THE DIC LOOK-UP"
SET INDX=^(7.5)
DO ADD
+7 IF $DATA(^DD(INDFN,INDF,"AX"))#2
SET INDC=INDF_"AX ; EXECUTABLE AUDIT CHECK CODE"
SET INDX=^("AX")
DO ADD
+8 FOR INDEL=9.2:.1:9.9
IF $DATA(^DD(INDFN,INDF,INDEL))#2
SET INDC=INDF_"OF"_INDEL_" ; OVERFLOW CODE"
SET INDX=^(INDEL)
DO ADD
+9 SET INDEL=""
FOR
SET INDEL=$ORDER(^DD(INDFN,INDF,"DEL",INDEL))
IF INDEL=""
QUIT
IF $DATA(^(INDEL,0))#2
SET INDC=INDF_"DEL"_INDEL_" ; DELETE PROTECTION CODE"
SET INDX=^(0)
DO ADD
+10 SET INDEL=""
FOR G=0:0
SET INDEL=$ORDER(^DD(INDFN,INDF,"LAYGO",INDEL))
IF INDEL=""
QUIT
IF $DATA(^(INDEL,0))#2
SET INDC=INDF_"LAYGO"_INDEL_" ; LAYGO CHECK CODE"
SET INDX=^(0)
DO ADD
+11 FOR INDXRF=0:0
SET INDXRF=$ORDER(^DD(INDFN,INDF,1,INDXRF))
IF INDXRF'>0
QUIT
SET C=$PIECE(^(INDXRF,0),"^",2)
FOR G=0:0
SET G=$ORDER(^DD(INDFN,INDF,1,INDXRF,G))
IF G'>0
QUIT
DO XREFS
+12 QUIT
XREFS ;Node 3 is don't delete comment.
IF ('$DATA(^(G))#2)!(G=3)
QUIT
+1 SET INDC=INDF_"XRF"_INDXRF_$SELECT(G=1:"S",G=2:"K",1:"n"_G)_" ; "_$SELECT(G<2:"SET",G<3:"KILL",1:"OVERFLOW")_" LOGIC FOR '"_$SELECT(C]"":C,1:INDXRF)_"' XREF"
SET INDX=^(G)
DO ADD
+2 QUIT
ADD ;Put code in UTILITY for processing
+1 SET INDLC=INDLC+1
SET ^UTILITY($JOB,1,INDRN,0,INDLC,0)=INDC
IF INDX]""
SET INDLC=INDLC+1
SET ^UTILITY($JOB,1,INDRN,0,INDLC,0)=" "_INDX
+2 QUIT
PUSH SET INDL=INDL+1
FOR A="INDFN","INDF","INDLC","INDRN"
SET @(A_"(INDL)")=@A
+1 SET INDFN=+$PIECE(^DD(INDFN,INDF,0),"^",2)
SET INDRN="|dd"_INDFN
SET (INDLC,INDF)=0
+2 QUIT
POP FOR A="INDFN","INDF","INDLC","INDRN"
SET @A=@(A_"(INDL)")
+1 SET INDL=INDL-1
QUIT
REMCOMP ;Remove compiled template routines from selected list
+1 SET %="|dd"
+2 FOR J=1:1
SET %=$ORDER(^UTILITY($JOB,%))
IF %'?1"|dd".NP
QUIT
SET INDFN=+$EXTRACT(%,4,999)
IF '$DATA(^DD(INDFN,0,"UP"))
FOR F="^DIE(","^DIPT("
SET F1=F_"""F"_INDFN_""","
SET %1=""
FOR J=0:0
SET %1=$ORDER(@(F1_"%1)"))
IF %1=""
QUIT
FOR %2=0:0
SET %2=$ORDER(@(F1_"%1,%2)"))
IF %2'>0
QUIT
DO P
+3 QUIT
P IF $DATA(@(F_"%2,0)"))
SET R=$EXTRACT($SELECT($DATA(^("ROU")):^("ROU"),$DATA(^("ROUOLD")):^("ROUOLD"),1:""),2,999)
+1 IF R=""
QUIT
+2 IF $DATA(^UTILITY($JOB,R))
KILL ^UTILITY($JOB,R)
+3 SET RN=R
FOR J=0:0
SET RN=$ORDER(^UTILITY($JOB,RN))
IF RN=""!(RN'?@("1"""_R_"""1N.N"))
QUIT
KILL ^UTILITY($JOB,RN)
+4 QUIT
