Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XMPH

XMPH.m

Go to the documentation of this file. 
  1. XMPH ;(WASH ISC)/THM/CAP-PackMan Load Routines/Print Msg ;12/04/2002  13:48
  1.  ;;8.0;MailMan;**10**;Jun 28, 2002
  1.  ; Entry points used by MailMan options (not covered by DBIA):
  1.  ; LOAD   XMPROU - Load routines
  1.  ;USER ENTRY LIST OF ROUTINES
  1.  Q
  1. DEV ;GET OUTPUT DEVICE / QUEUE PACKMAN PRINT
  1.  N I,ZTSAVE
  1.  F I="DIE","XMZ","XMDUZ","XMV(","XMP2","XMR","XCF" S ZTSAVE(I)=""
  1.  D EN^XUTMDEVQ("ZTSK^XMPH","MailMan: PackMan Print",.ZTSAVE)
  1.  Q
  1. ZTSK ;QUEUED PRINT COMES HERE
  1.  N XMSUBJ,XMZSTR
  1.  I XCF=3 D
  1.  . D TOP^XMPC
  1.  E  I $E($G(IOST),1,2)'="C-" D
  1.  . N XMPARM,XMZREC
  1.  . S XMZREC=$G(^XMB(3.9,XMZ,0))
  1.  . W $$EZBLD^DIALOG($S($P(XMZREC,U,7)["K":34076,1:34077)) ; KIDS Build / PackMan message
  1.  . W $S(XMP2="T":" text print for ",1:" print for "),XMV("NAME")
  1.  . S XMPARM(1)=^XMB("NETNAME"),XMPARM(2)=$$MMDT^XMXUTIL1($$NOW^XLFDT)
  1.  . W !,$$EZBLD^DIALOG(34503,.XMPARM) ; Printed at |1| |2|
  1.  . Q:XMP2="S"
  1.  . S XMSUBJ=$$EZBLD^DIALOG(34536,$$SUBJ^XMXUTIL2(XMZREC)) ; Subj: |1|
  1.  . S XMZSTR=$$EZBLD^DIALOG(34537,XMZ) ; [#|1|]
  1.  . W !,XMSUBJ
  1.  . D W^XMJMP1("  ",XMZSTR)
  1.  . D W^XMJMP1(" ",$$DATE^XMXUTIL2(XMZREC))
  1.  . D WL^XMJMP1($$EZBLD^DIALOG(34538,$$NAME^XMXUTIL($P(XMZREC,U,2),1))) ; From:
  1.  . D W^XMJMP1(" ",$$EZBLD^DIALOG(34541)) ; Page 1
  1.  . D LINE^XMJMP1
  1.  . W !
  1.  D S^XMP2
  1.  I $D(ZTQUEUED) S ZTREQ="@"
  1.  Q
  1. LOAD ;LOAD ROUTINE FROM <X> INTO GLOBAL <DIF>_I_",0)"
  1.  ;
  1.  ;DIFROM NEEDS A MESSAGE NUMBER
  1.  ;
  1.  S (DIE,DIF)="^XMB(3.9,XMZ,2,"
  1.  I $D(DIFROM) W !!,"Please enter the names of the routines you wish to load into this message.",!!,"Only routines will be loaded."
  1.  I  W !!,"INITs, will be sent automatically.",!!
  1.  ;K ^UTILITY($J#256)
  1.  X ^%ZOSF("RSEL") Q:$O(^UTILITY($J,0))=""
  1.  S X=0 S:'$D(XCNP) XCNP=0
  1.  F  S X=$O(^UTILITY($J,X)) Q:X=""  D LL
  1.  K ^UTILITY($J)
  1.  Q
  1. LL N XMHOLD S XMHOLD=XCNP
  1.  W !,"Loading ",X S DIF=DIE,XCNP=XCNP+1,@(DIF_XCNP_",0)")="$ROU "_X
  1.  X ^%ZOSF("LOAD") S $P(@(DIF_"0)"),U,3,4)=XCNP_U_XCNP
  1.  S @(DIF_XCNP_",0)")="$END ROU "_X
  1.  ;
  1.  ;Check for control characters in text
  1.  F XMHOLD=XMHOLD:1:XCNP I $G(@(DIF_XMHOLD_",0)"))?.E1C.E D  S XQCH="HALT" G H^XUS
  1.  . W !!,$C(7),"Errored out loading routine ",X," - control character in text."
  1.  . W !,"Use ^XINDEX to identify it, then remove from routine and try again.",!!
  1.  . D KILLMSG^XMXUTIL(XMZ)
  1.  Q
  1.  ;
  1. PACK ;LOAD ENTIRE PACKAGE (ROUTINES ONLY)
  1.  ;
  1.  S:'$D(XCNP) XCNP=0
  1.  I '$D(DIFROM) S DIC="^DIC(9.4,",DIC(0)="AEQM" D ^DIC Q:Y<0  S DA=+Y
  1.  S XMROU="^DIC(9.4,"_DA_",2,""B"","
  1. P S (XMA0,XMB0)="",(DIE,DIF)="^XMB(3.9,"_XMZ_",2,"
  1.  G P9:'$D(^%ZOSF("TEST")) S XMB=^("TEST")
  1. P1 S XMA0=$O(@(XMROU_"XMA0)")) I $L(XMA0) D TST G P1
  1.  G ER:XMB0
  1. P9 S XMA0=$O(@(XMROU_"XMA0)")) G Q:XMA0="" S X=XMA0 D LL G P9
  1.  ;
  1. XMROU ;LOAD ROUTINES (FROM XMD)
  1.  ;
  1.  S XCNP=XCNP+1,$P(^XMB(3.9,XMZ,2,0),U,3,4)=XCNP_U_XCNP,^(XCNP,0)="$END TXT"
  1.  S XMROU="XMROU(" G P
  1.  ;
  1. TST S X=XMA0 X XMB Q:$T  S XMB0=1 W !,"Program ",X," does not exist." Q
  1. ER W !!,"<< Correct the errors listed above.",!,"Then you may try again.",!
  1. Q K XMA0,XMB0,XMB,XMROU,DIE,DIF Q