Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XQ61

XQ61.m

Go to the documentation of this file. 
  1. XQ61 ;SEA/AMF,MJM - BULK EDITORSHIP ASSIGNMENT ;9/28/92  16:21;5/13/93  11:44 AM [ 04/02/2003   8:29 AM ]
  1.  ;;8.0;KERNEL;**1002,1003,1004,1005,1007**;APR 1, 2003
  1.  ;;8.0;KERNEL;;Jul 10, 1995
  1. EN1 S XQAL=1 G INIT ; ENTRY POINT FOR ASSIGNMENT OF EDITORS
  1. EN2 S XQAL=0 ;        ENTRY POINT FOR DE-ASSIGNMENT OF EDITORS
  1. INIT ;
  1.  K XQHELP,XQEDTR S (XQHELP(0),XQEDTR(0))=0
  1.  ;
  1. HELP ;Get the list of help frames in question
  1.  W !!,$S($O(XQHELP(0))>0:"Another",1:"Select")," help frame: " R X:DTIME S:'$T X=U G:X[U OUT
  1.  I '$L(X) G:($O(XQHELP(0))="") OUT G EDITOR
  1.  I X["?" S XQH="XQHELP-ASSIGNEDITOR-H" D:X="?" EN^XQH D:X="??" LSTHELP D:X="???" ^XQ62 G HELP
  1.  S XQM=0 S:"-'"[$E(X,1) X=$E(X,2,999),XQM=1
  1.  S DIC=9.2,DIC(0)="EZ",DIC("S")="I (DUZ(0)=""@"")!($D(^XUSEC(""XUMGR"",DUZ)))!($D(^DIC(9.2,""AC"",DUZ,Y)))" D ^DIC K DIC I Y<0 W " ??",*7 G HELP
  1.  I XQM W $S($D(XQHELP(+Y)):"  Deleted",1:$C(7)_" ??  Help frame not on list") K XQHELP(+Y) G HELP
  1.  S XQHELP(+Y)="" G HELP
  1.  ;
  1. EDITOR ;Get the names of the users involved
  1.  W !!,$S($O(XQEDTR(0))>0:"Another editor: ",1:"Editor of help frame: ") R X:DTIME S:'$T X=U G:X[U OUT
  1.  I '$L(X) G:($O(XQEDTR(0))>0) OK W " ??",*7,!,"You have not yet selected any editors." G EDITOR
  1.  I X["?" S XQH="XQHELP-ASSIGNEDITOR-U" D:X="?" EN^XQH D:X="??" LSTEDT D:X="???" ^XQ62 G EDITOR
  1.  S XQM=0 S:"'-"[$E(X,1) X=$E(X,2,999),XQM=1
  1.  I $E(X,1,2)'="G." S DIC=200,DIC(0)="EMZ",DIC("S")="I $L($P(^(0),U,3))" D ^DIC K DIC W:(Y<0) " ??",*7 G:Y<0 EDITOR S XQI=+Y D EACH G EDITOR
  1.  S X=$E(X,3,999),XMDUZ=DUZ,DIC="^XMB(3.8,",DIC("S")="D:$P(^(0),U,2)=""PR"" CHK^XMA21",DIC(0)="EMZ" D ^DIC K DIC I Y<0 W " ??",*7 G EDITOR
  1.  S XQJ=0 F  S XQJ=$O(^XMB(3.8,+Y,1,XQJ)) Q:XQJ'>0  S XQI=+^(XQJ,0) W !,$P(^VA(200,XQI,0),U,1) D EACH
  1.  G EDITOR
  1. EACH I XQM W $S($D(XQEDTR(XQI)):"  Deleted",1:$C(7)_" ??  Editor not on list") K XQEDTR(XQI) Q
  1.  S XQEDTR(XQI)=""
  1.  Q
  1.  ;
  1. OK ;Show the list of help frams and users and get the OK to proceed
  1.  D LSTHELP,LSTEDT
  1. OK1 R !!,"Do you wish to proceed? YES// ",X:DTIME S:'$T X=U G:X=U OUT G:(X["N"!(X["n")) HELP I X["?" W !!,"'Y' means ",$S(XQAL:"assign",1:"remove")," the editor(s), 'N' means edit help frame or editor lists." G OK1
  1.  S:'$L(X) X="Y" I '(X["Y"!(X["y")) W *7," ??",!?10,"Please enter 'Y' or 'N', '^' to quit or '?' for help." G OK1
  1.  ;
  1. ACT ;Do the deed
  1.  S DIE=9.2,DA=0,DR(2,9.24)=.01 F  S DA=$O(XQHELP(DA)) Q:DA'>0  W !!,$P(^DIC(9.2,DA,0),U,1)," being ",$S(XQAL:"assigned to:",1:"taken away from:") D ACT1
  1.  ;
  1.  G OUT
  1. ACT1 ;
  1.  S XQJ=IOM\26,XQM=0 F  S XQM=$O(XQEDTR(XQM)) Q:XQM=""  D ACT2
  1.  Q
  1. ACT2 ;
  1.  S XQNM=$P(^VA(200,XQM,0),U,1) W !?5,XQNM G:'XQAL ACT3
  1.  I $D(^DIC(9.2,"AD",XQM,DA)) W ?30,"User already is editor of help frame - no action taken" Q
  1.  S DR="7///"_XQNM D ^DIE Q
  1. ACT3 I '$D(^DIC(9.2,"AD",XQM,DA)) W ?30,"User isn't editor of help frame no action taken" Q
  1.  S DR="7///"_XQNM,DR(2,9.24)=".01///@" D ^DIE Q
  1.  Q
  1.  ;
  1. LSTHELP ;Show the list of help frams concerned
  1.  I $O(XQHELP(0))="" W !!,"You have not yet selected any help frames." Q
  1.  W !!,"You've selected the following help frames: ",! S XQJ=0,XQI=IOM\15 F XQK=0:1 S XQJ=$O(XQHELP(XQJ)) Q:XQJ'>0  W:'(XQK#XQI) ! W ?(XQK#XQI*15),$P(^DIC(9.2,XQJ,0),U,1)
  1.  Q
  1.  ;
  1. LSTEDT ;Show the list of editors selected so far
  1.  I $O(XQEDTR(0))'>0 W !!,"You have not yet selected any editors." Q
  1.  W !!,"You've selected the following editors: ",! S XQJ=0,XQI=IOM\26 F XQK=0:1 S XQJ=$O(XQEDTR(XQJ)) Q:XQJ'>0  W:'(XQK#XQI) ! W ?(XQK#XQI*26),$P(^VA(200,XQJ,0),U,1)
  1.  Q
  1.  ;
  1. OUT ;Clean up and quit
  1.  K DA,DIC,DIE,DR,X,Y,XQAL,XQHELP,XQEDTR,XQH,XQI,XQJ,XQK,XQM,XQNM
  1.  Q