Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ZTMKU

ZTMKU.m

Go to the documentation of this file. 
  1. ZTMKU ;SEA/RDS-Taskman: Option, ZTMWAIT/RUN/STOP ;01/05/09  16:07
  1.  ;;8.0;KERNEL;**118,127,275,355,518**;Jul 10, 1995;Build 15
  1.  ;Per VHA Directive 2004-038, this routine should not be modified.
  1.  N DIR,DTOUT,DUOUT
  1.  D TABLE ;Show taskman
  1.  S DTIME=$G(DTIME,300),DIR(0)="N^1:4",DIR("A",.1)=""
  1.  S DIR("A",1)=" 1. Remove from WAIT state.(RUN)",DIR("A",2)=" 2. Managers Update.",DIR("A",3)=" 3. Put into WAIT state."
  1.  S DIR("A",4)=" 4. STOP Taskman."
  1.  S DIR("A",99)="",DIR("A")="Select Option" D ^DIR
  1.  G RUN:Y=1,UPDATE:Y=2,WAIT:Y=3,STOP:Y=4
  1.  Q
  1.  ;
  1. RUN ;Remove Task Managers From WAIT State
  1.  D WS(0,"MGR"),WS(0,"SUB") K ^%ZTSCH("STOP") W !,"TaskMan removed from 'WAIT STATE'.",!
  1.  Q
  1.  ;
  1. UPDATE ;Have Managers Do an parameter Update
  1.  K ^%ZTSCH("UPDATE")
  1.  W !,"Managers will update parameters.",!
  1.  Q
  1.  ;
  1. WAIT ;Put Task Managers In WAIT State
  1.  D WS(1,"MGR") W !,"TaskMan now in 'WAIT STATE'",$C(7)
  1.  D QSUB
  1.  Q
  1.  ;
  1. STOP ;Shut Down Task Managers
  1.  N ZTX,ND,J
  1.  F  R !!,"Are you sure you want to stop TaskMan? NO// ",ZTX:$S($D(DTIME)#2:DTIME,1:60) S ZTX=$$UP(ZTX) Q:'$T!("^YES^NO"[ZTX)  W:ZTX'["?" $C(7) W !,"Answer YES to shut down all Task Managers on current the volume set."
  1.  I "^NO"[ZTX W !,"TaskMan NOT shut down." Q
  1.  W !,"Shutting down TaskMan." D GROUP("SMAN(NODE)")
  1.  D QSUB,ASKACT
  1.  Q
  1.  ;
  1. SSUB(NODE) ;Stop sub-managers
  1.  D SS(1,"SUB",NODE)
  1.  Q
  1. SMAN(NODE) ;stop managers
  1.  D SS(1,"MGR",NODE)
  1.  Q
  1.  ;
  1. SS(MD,GR,NODE) ;Set/clear STOP nodes.
  1.  S GR=$G(GR,"MGR") S:"MGR_SUB_"'[GR GR="MGR"
  1.  I MD=1 S ^%ZTSCH("STOP",GR,NODE)=$H D WS(0,GR)
  1.  I MD=0 K ^%ZTSCH("STOP",GR,NODE)
  1.  Q
  1.  ;
  1. WS(MD,GR) ;Set/Clear Wait state
  1.  S GR=$G(GR,"MGR") S:"MGR_SUB_"'[GR GR="MGR"
  1.  I MD=1 S ^%ZTSCH("WAIT",GR)=$H ;set wait state
  1.  I MD=0 K ^%ZTSCH("WAIT",GR) ;Clear wait
  1.  Q
  1.  ;
  1. GROUP(CALL) ;Do CALL for each node, use NODE as the parameter
  1.  N J,ND,NODE
  1.  ;Get the Managers
  1.  F J=0:0 S J=$O(^%ZTSCH("STATUS",J)) Q:J=""  S ND=$G(^(J)),NODE=$P(ND,"^",3) D @CALL
  1.  ;Get any remote Sub-Managers
  1.  S NODE="" F  S NODE=$O(^%ZTSCH("SUB",NODE)) Q:NODE=""  D @CALL
  1.  Q
  1.  ;
  1. OPT(MD) ;Disable/Enable option prosessing
  1.  I MD=1 S ^%ZTSCH("NO-OPTION")=""
  1.  I MD=0 K ^%ZTSCH("NO-OPTION")
  1.  Q
  1.  ;
  1. ASKACT ;Ask if active Tasks should be signaled to stop.
  1.  N ZTX,ND
  1.  F  R !!,"Should active jobs be signaled to stop? NO// ",ZTX:$G(DTIME,60) S ZTX=$$UP(ZTX) Q:'$T!("^YES^NO"[ZTX)  W:ZTX'["?" $C(7) W !,"Answer YES to set the STOP flag for active tasks.",!,"Tasks need to call $$S^%ZTLOAD to get the signal."
  1.  I "^NO"[ZTX W !,"Tasks NOT signaled to shut down." Q
  1.  W !!,"Signaling active Tasks to STOP."
  1.  D STPACT W !,"Done."
  1.  Q
  1.  ;
  1. STPACT ;Set the STOP flag for all ACTIVE Tasks.
  1.  N ZTI,ZT2
  1.  S ZTI=0
  1.  F  S ZTI=$O(^%ZTSCH("TASK",ZTI)) Q:'ZTI  S ZT2=$$ASKSTOP^%ZTLOAD(ZTI) W !,"TASK: ",ZTI," Stop status: ",ZT2
  1.  Q
  1.  ;
  1. QSUB N ZTX,ND
  1.  F  R !!,"Should active submanagers shut down after finishing their current tasks? NO// ",ZTX:$S($D(DTIME)#2:DTIME,1:60) Q:'$T!("^"[ZTX)!("YESyesNOno"[ZTX)  W:ZTX'["?" $C(7) W !,"Please answer YES or NO."
  1.  D:"YESyes"[ZTX&(ZTX]"") GROUP("SSUB(NODE)") W !,"Okay!",!
  1.  Q
  1.  ;
  1. QUERY ;Query Status Of A Task Manager
  1.  Q:$D(%ZTX)[0  Q:%ZTX=""  S %ZTY=0
  1.  I $D(^%ZTSCH("STATUS",%ZTX))#2 S %ZTY=^%ZTSCH("STATUS",%ZTX)
  1.  K %ZTX Q
  1.  ;
  1. NODES ;Return Task Manager Status Nodes
  1.  S %ZTX="" F %ZTY=0:0 S %ZTX=$O(^%ZTSCH("STATUS",%ZTX)) Q:%ZTX=""  S %ZTY=%ZTY+1,%ZTY(%ZTY)=%ZTX
  1.  K %ZTX Q
  1.  ;
  1. LIVE ;Return Whether A Task Manager Is Live
  1.  Q:$D(%ZTX)[0  Q:%ZTX=""  S %ZTY=0,U="^",%ZTX1=$H,%ZTX2=$P(%ZTX,U)
  1.  S %ZTX3=%ZTX1-%ZTX2*86400+$P(%ZTX1,",",2)-$P(%ZTX2,",",2)
  1.  I %ZTX3'<0 S %ZTY=$S($D(^%ZTSCH("RUN"))[0&(%ZTX'["WAIT"):0,%ZTX3<30:1,%ZTX3<120&(%ZTX["PAUSE"):1,1:0)
  1.  K %ZTX,%ZTX1,%ZTX2,%ZTX3 Q
  1.  ;
  1. TABLE ;Display Task Manager Table
  1.  W !,"JOB NUMBER",?15,"STATUS",?25,"DESCRIPTION",?55,"LAST UPDATED",?75,"LIVE"
  1.  W !,"----------",?15,"------",?25,"-----------",?55,"------------",?75,"----"
  1.  D NODES S %ZTZ=%ZTY,%ZTZ1=0,U="^",%H=$H D YMD^%DTC S DT=X
  1.  F %ZTI=1:1:%ZTZ S %ZTX=%ZTY(%ZTI) D QUERY I %ZTY'=0 W !,%ZTY(%ZTI),?15,$P(%ZTY,U,2),?25,$P(%ZTY,U,3),?55 S %ZTT=$P(%ZTY,U) D T S %ZTX=%ZTY D LIVE W ?75,$S(%ZTY:"YES",1:"NO") I %ZTY S %ZTZ1=%ZTZ1+1
  1.  W !?6,"Total:",$J(%ZTZ,3),!?6,"Live :",$J(%ZTZ1,3)
  1.  K %ZTI,%ZTT,%ZTY,%ZTZ Q
  1.  ;
  1. CLEAN ;Cleanup Status Node
  1.  K ^%ZTSCH("STATUS") W !,"Done!",! Q
  1. PURGE ;Purge the TASK list of running tasks.
  1.  N TSK S TSK=0
  1.  F  S TSK=$O(^%ZTSCH("TASK",TSK)) Q:TSK'>0  I '$D(^%ZTSCH("TASK",TSK,"P")) K ^%ZTSCH("TASK",TSK)
  1.  W !,"Done!",! Q
  1.  ;
  1. ZTM ;Return Number Of Live Task Managers
  1.  N %ZTI,%ZTZ,%ZTZ1
  1.  D NODES S %ZTZ=%ZTY,%ZTZ1=0 F %ZTI=1:1:%ZTZ S %ZTX=%ZTY(%ZTI) D QUERY I %ZTY'=0 S %ZTX=%ZTY D LIVE I %ZTY S %ZTZ1=%ZTZ1+1
  1.  S %ZTY=%ZTZ1 Q
  1.  ;
  1. UP(X) ;Convert to Uppercase
  1.  Q $TR(X,"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ")
  1.  ;
  1. T ;Print Informal-format Conversion Of $H-format Date ; Input: %ZTT, DT.
  1.  S %H=%ZTT D 7^%DTC W $S(DT=X:"TODAY",DT+1=X:"TOMORROW",1:$E(X,4,5)_"/"_$E(X,6,7)_"/"_$E(X,2,3))_" AT " S X=$P(%ZTT,",",2)\60,%H=X\60 W $E(%H+100,2,3)_":"_$E(X#60+100,2,3)
  1.  K %,%D,%H,%M,%Y,X Q  ; Output: %ZTT, DT.
  1.  ;