Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ABSPECX1

ABSPECX1.m

Go to the documentation of this file. 
  1. ABSPECX1 ; IHS/FCS/DRS - JWS 03:35 PM 6 Jun 1995 ;   [ 09/12/2002  10:00 AM ]
  1.  ;;1.0;PHARMACY POINT OF SALE;**3,42**;JUN 21, 2001;Build 38
  1.  ;----------------------------------------------------------------------
  1.  ;Create new Claim ID for Claim Submission file (9002313.02)
  1.  ;
  1.  ;Input Variables:   NRDEFIEN  - NCPDP Record Definitions IEN
  1.  ;                               (9002313.92)
  1.  ;
  1.  ;Function Returns:  String:  C<YY>-<BBBBBB>-<NNNNN>
  1.  ;                         C can also be P or other ORIGIN code.
  1.  ;                         See remarks a few lines below about ORIGIN
  1.  ;                   Where:   <YY> is the year
  1.  ;                            <BBBBBB> is the BIN number of the payor
  1.  ;                            <NNNNN> is a 5-digit sequence number
  1.  ;----------------------------------------------------------------------
  1.  ; Also called from old Alaska Medicaid batch method,
  1.  ; regrettably still in use at one site, but we're going to
  1.  ; phase it out someday.
  1.  ;
  1.  ;  ORIGIN argument added 08/23/2000
  1.  ;     Can specify the leading character of the claim ID.
  1.  ;     Defaults to "C".
  1.  ;     Point of sale sends in "P"
  1.  ;   09/20/2000 - can override by setting ABSPECX1("PREFIX")=letter
  1.  ;     (Do this if you change the batch file to submit via POS)
  1.  ;
  1.  ;  Also changed 08/23/2000:  Sequence number is now 6 digits
  1.  ;  and the first number assigned is 100000.  As of yesterday, ANMC
  1.  ;  is already up to almost 40000.
  1.  ;  Can't change length in the middle of the year or the $O(,-1) is
  1.  ;  messed up.   So the code will adapt - if it finds 5-digit format
  1.  ;  already there, it will assign new numbers with 5 digits.
  1.  ;
  1. CLAIMID(NRDEFIEN,ORIGIN) ;EP - Called from ABSPOSCE from ABSPOSCA from ABSPOSQG from ABSPOSQ2
  1.  N BIN,SEQNUM,ROOT,LAST
  1.  I '$D(ORIGIN) S ORIGIN="C"
  1.  I $G(ABSPECX1("PREFIX"))?1U S ORIGIN=ABSPECX1("PREFIX")
  1.  ;IHS/OIT/CASSEVER/RAN patch 42 03/30/2011 For new claims process
  1.  ;Get and format BIN number for the electronic payor
  1.  I NRDEFIEN=1 S BIN=$P(^ABSPEI(ABSP("Insurer","IEN"),100),U,16)
  1.  ELSE  S BIN=$P($G(^ABSPF(9002313.92,NRDEFIEN,1)),U,1)
  1.  S BIN=$$NFF^ABSPECFM(BIN,6)
  1.  ;
  1.  ;Establish the root for the claim id number
  1.  S ROOT=ORIGIN_$E(DT,2,3)_"-"_BIN_"-" ; 11 characters long
  1.  ;
  1.  ;Get last claim id number with the same root
  1.  S LAST=$O(^ABSPC("B",ROOT_"Z"),-1)
  1.  ; Reversal claim ID?  Get rid of the suffix R#
  1.  ; ABSP*1.0T7*6    could be #>9, in which case the old logic fails!
  1.  ; ABSP*1.0T7*6    replaced the line that strips off the R#
  1.  ;I $L(LAST)>6,LAST?.E1"R"1N S LAST=$E(LAST,1,$L(LAST)-2) ;ABSP*1.0T7*6
  1.  I $L(LAST)>6,LAST?.E1"R"1.N S $P(LAST,"-",3)=+$P(LAST,"-",3) ;ABSP*1.0T7*6
  1.  ;
  1.  ;Set and format sequence number
  1.  S SEQNUM=$S($E(LAST,1,11)=ROOT:(+$P(LAST,"-",3))+1,1:0)
  1.  N SEQLEN
  1.  ;  5 or 6 digit numbers?  Depends on what's there already? 
  1.  ;  Six digits is what we really want, but upgrades will be trickier.
  1.  ; New installs and ANMC 2001 will have 6 digits.
  1.  ;
  1.  I SEQNUM=0 S SEQLEN=6,SEQNUM=100000
  1.  E  S SEQLEN=$L($P(LAST,"-",3))
  1.  I SEQLEN<5 D IMPOSS^ABSPOSUE("DB,P","TI",LAST,,"SEQLEN<5",$T(+0)) ; internal error
  1.  I SEQLEN>6 D IMPOSS^ABSPOSUE("DB,P","TI",LAST,,"SEQLEN>6",$T(+0)) ; internal error
  1.  I $L(SEQNUM)=SEQLEN,SEQNUM?."9" D
  1.  . D IMPOSS^ABSPOSUE("DB,P","T",LAST,,"OVERFLOWED!",$T(+0))
  1.  I SEQLEN=5 S SEQNUM=$TR($J(SEQNUM,SEQLEN)," ","0") ; pad w/leading 0s
  1.  I $L(SEQNUM)'=SEQLEN D  ; internal error
  1.  . D IMPOSS^ABSPOSUE("DB,P","TI",LAST,SEQLEN,"length",$T(+0))
  1.  ;
  1.  Q ROOT_SEQNUM