Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ACRFBOIL

ACRFBOIL.m

Go to the documentation of this file. 
  1. ACRFBOIL ;IHS/OIRM/DSD/THL,AEF - DOCUMENT BOILER PLATE MANAGEMENT UTILITY; [ 11/01/2001   9:44 AM ]
  1.  ;;2.1;ADMIN RESOURCE MGT SYSTEM;;NOV 05, 2001
  1.  ;;ROUTINE USED FOR DOCUMENT BOILER PLATE MANAGEMENT
  1. EN ;EP;TO CREATE OR EDIT BOILER PLATE STATEMENTS
  1.  D STATE
  1. EXIT K ACR,ACRBPDA,ACRX,ACRI,ACRY
  1.  Q
  1. STATE ;EP;TO ADD NEW BOILER PLATE STATEMENTS
  1.  F  D BOIL Q:$D(ACRQUIT)!$D(ACROUT)
  1.  K ACRQUIT
  1.  Q
  1. BOIL ;SELECT AND EDIT STATEMENT
  1.  W @IOF
  1.  W !!?20,"DOCUMENT BOILER PLATE STATEMENTS"
  1.  S DIC="^ACRBP("
  1.  S DIC(0)="AEMLQZ"
  1.  S DIC("A")="BOILER PLATE STATEMENT: "
  1.  W !!
  1.  D DIC^ACRFDIC
  1.  I +Y<1 S ACRQUIT="" Q
  1.  S DA=+Y
  1.  S DIE="^ACRBP("
  1.  S DR="[ACR BOILER PLATE STATEMENT]"
  1.  D DIE^ACRFDIC
  1.  Q
  1. DOCBOIL ;EP;UTILITY TO SELECT BOILER PLATE STATEMENTS TO ADD TO DOCUMENT
  1.  K ACRQUIT
  1.  I $D(^ACRDOCBP("C",ACRDOCDA)) D DELBOIL
  1.  W !!?3,"Select BOILER PLATES Statements"
  1.  W !
  1.  S ACR=0
  1.  S ACRBP=""
  1.  F  S ACRBP=$O(^ACRBP("B",ACRBP)) Q:ACRBP=""  D
  1.  .S ACRBPDA=0
  1.  .F  S ACRBPDA=$O(^ACRBP("B",ACRBP,ACRBPDA)) Q:'ACRBPDA  D
  1.  ..I $D(^ACRBP(ACRBPDA,0)) D
  1.  ...S ACR=ACR+1
  1.  ...S ACR(ACR)=ACRBPDA
  1.  ...W !?10,ACR
  1.  ...W ?15,$P(^ACRBP(ACRBPDA,0),U)
  1.  S DIR(0)="LO^1:"_ACR
  1.  S DIR("A")="Which One(s)"
  1.  S DIR("?")="Indicate the number(s) of applicable Boiler Plate Statements."
  1.  W !
  1.  D DIR^ACRFDIC
  1.  I $D(ACRQUIT)!$D(ACROUT) K ACRQUIT Q
  1.  N ACRI,ACRX,ACRY
  1.  S ACRY=Y
  1.  F ACRI=1:1 S ACRX=$P(ACRY,",",ACRI) Q:ACRX=""  S (ACRBP,X)=ACR(ACRX) D
  1.  .I '$D(^ACRDOCBP("AC",ACRDOCDA,ACRBP)) D
  1.  ..S DIC="^ACRDOCBP("
  1.  ..S DIC(0)="L"
  1.  ..S DIC("DR")=".02////"_ACRDOCDA
  1.  ..D FILE^ACRFDIC
  1.  ..S ACRBPDA=+Y
  1.  ..D XY
  1.  .I $D(^ACRDOCBP("AC",ACRDOCDA,ACRBP)) S ACRBPDA=$O(^(ACRBP,0)) D
  1.  ..I ACRBPDA D
  1.  ...W !!,"You have added the ",$P(^ACRBP(ACRBP,0),U)," statement to this document."
  1.  ...S DIR(0)="YO"
  1.  ...S DIR("A")="Do you want to edit the statement"
  1.  ...S DIR("B")="NO"
  1.  ...D DIR^ACRFDIC
  1.  ...I Y=1 D
  1.  ....S DA=ACRBPDA
  1.  ....S DIE="^ACRDOCBP("
  1.  ....S DR=1
  1.  ....D DIE^ACRFDIC
  1.  Q
  1. XY ;SET STATEMENT FOR THE DOCUMENT EQUAL TO BOILER PLATE STATEMENT
  1.  S %X="^ACRBP("_ACR(ACRX)_",1,"
  1.  S %Y="^ACRDOCBP("_ACRBPDA_",1,"
  1.  D %XY^%RCR
  1.  K %X,%Y
  1.  Q
  1. BAPPEND ;EP;LIST BOILER PLATE STATMENTS APPENDED TO DOCUMENT AND ALLOW FOR
  1.  ;DELETION OR EDITING
  1.  Q:'$D(ACRDOCDA)
  1.  I '$D(^ACRDOCBP("C",ACRDOCDA)) W !!,"NO STATEMENTS APPENDED."
  1. DELBOIL N ACR,ACRI S ACR=0
  1.  F ACRI=1:1 S ACR=$O(^ACRDOCBP("C",ACRDOCDA,ACR)) Q:'ACR  D
  1.  .I ACRI=1 D
  1.  ..W !!?10,"STATEMENTS APPENDED:"
  1.  ..W !?10,"------------------------"
  1.  .I $D(^ACRDOCBP(ACR,0)) S ACRBP=+^(0) D:ACRBP
  1.  ..W !?10,ACRI
  1.  ..W ?15,$P(^ACRBP(ACRBP,0),U)
  1.  ..D D1
  1.  Q
  1. D1 ;
  1.  S DIR(0)="YO"
  1.  S DIR("A")="          Read Statement NO. "_ACRI_" "
  1.  S DIR("B")="NO"
  1.  D DIR^ACRFDIC
  1.  I Y=1 D
  1.  .S D0=ACR
  1.  .N DXS,DIP,DC,DN
  1.  .W @IOF
  1.  .W !
  1.  .D ^ACRBP
  1.  .D PAUSE^ACRFWARN
  1.  .W !
  1.  Q:$D(ACRREV)
  1.  S DIR(0)="SO^1:Edit Statement No. "_ACRI_";2:Delete Statement No. "_ACRI
  1.  W !
  1.  D DIR^ACRFDIC
  1.  Q:$D(ACRQUIT)!$D(ACROUT)!("12"'[Y)
  1.  I Y=1 D  Q
  1.  .S DA=ACR
  1.  .S DIE="^ACRDOCBP("
  1.  .S DR="[ACR BP STATEMENT]"
  1.  .W @IOF
  1.  .D DIE^ACRFDIC
  1.  I Y=2 D
  1.  .S DIR(0)="YO"
  1.  .S DIR("A")="Sure you want to delete Statement No. "_ACRI
  1.  .S DIR("B")="NO"
  1.  .W !
  1.  .D DIR^ACRFDIC
  1.  .Q:Y'=1
  1.  .S DA=ACR
  1.  .S DIK="^ACRDOCBP("
  1.  .K ^ACRDOCBP("C",ACRDOCDA,DA),^ACRDOCBP("AC",ACRDOCDA,ACRBP,DA)
  1.  .W !!,"Statement NO. "_ACRI_" deleted."
  1.  Q
  1. PBOIL ;EP;TO PRINT BOILER PLATE STATEMENT ATTACHED TO A DOCUMENT
  1.  Q:$D(ACROUT)
  1.  W:$O(^ACRDOCBP("C",ACRDOCDA,0)) @IOF
  1.  N ACR,D0
  1.  S ACR=0
  1.  F  S ACR=$O(^ACRDOCBP("C",ACRDOCDA,ACR)) Q:'ACR  D
  1.  .N DXS,DIP,DC,DN
  1.  .S D0=ACR
  1.  .I $E($G(IOST),1,2)="C-" D  Q:'$D(ACRSCREN)
  1.  ..N ACRFILE,ACRIEN,ACRFIELD,ACRTITLE
  1.  ..S ACRFILE=9002197.3
  1.  ..S ACRIEN=ACR
  1.  ..S ACRFIELD=1
  1.  ..S ACRTITLE="ARMS BOILER PLATE STATEMENT"
  1.  ..D WP^ACRFDIC
  1.  .K ACRSCREN
  1.  .D ^ACRBP
  1.  .S ACRX=+^ACRDOCBP(ACR,0)
  1.  .I $P(^ACRBP(ACRX,0),U,2),$D(^ACRAPVS("AB",ACRDOCDA)) D
  1.  ..N ACRAPVT
  1.  ..S ACRAPVT=5
  1.  ..D SIG^ACRFCERT
  1.  .I $E($G(IOST),1,2)["C-" D PAUSE^ACRFWARN
  1.  .W @IOF
  1.  Q