Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ACRFPAY7

ACRFPAY7.m

Go to the documentation of this file. 
  1. ACRFPAY7 ;IHS/OIRM/DSD/THL,AEF - CERTIFY AND EXPORT PAYMENT BATCH;  [ 09/23/2005  9:50 AM ]
  1.  ;;2.1;ADMIN RESOURCE MGT SYSTEM;**3,5,17,19**;NOV 05, 2001
  1.  ;;
  1. CASHREC ;EP;CASH RECONCILIAITON REPORT
  1.  D CREXIT
  1.  W !
  1.  D ^ACRFDATE
  1.  Q:$D(ACRQUIT)!$D(ACROUT)
  1.  Q:'$G(ACRBEGIN)!'$G(ACREND)
  1.  S (ACRRTN,ZTRTN)="CR^ACRFPAY7"
  1.  S ZTDESC="CASH RECONCILATION REPORT"
  1.  D ^ACRFZIS
  1. CREXIT K ACR,ACRQUIT,ACROUT,ACRBEGIN,ACREND,ACRJ,ACRTOT,ACRSCHD,ACRFYDA,ACRBATDA,ACRSEQDA,ACR
  1.  K ^TMP("ACRCR",$J)
  1.  Q
  1. CR ;EP;TO PRINT CASH RECONCILIATION REPORT
  1.  D CR1
  1.  D CREXIT
  1.  Q
  1. CR1 D CRHEAD
  1.  S ACR=ACRBEGIN-.1
  1.  F  S ACR=$O(^AFSLAFP("EXP",ACR)) Q:'ACR!(ACR>ACREND)  D
  1.  .N X,Y,Z
  1.  .S X=0
  1.  .F  S X=$O(^AFSLAFP("EXP",ACR,X)) Q:'X  D
  1.  ..S Y=0
  1.  ..F  S Y=$O(^AFSLAFP("EXP",ACR,X,Y)) Q:'Y  D
  1.  ...S Z=$$BATCH^ACRFPAYE(X,Y)                ;ACR*2.1*5.02
  1.  ...Q:Z="G"   ;ACR*2.1*5.02
  1.  ...S Z=$G(^AFSLAFP(X,1,Y,2))
  1.  ...Q:$P(Z,U,6)=""
  1.  ...S ^TMP("ACRCR",$J,$P(Z,U,6),X,Y)=""
  1.  S (ACRTOT,ACRJ)=0
  1.  S ACRSCHD=""
  1.  F  S ACRSCHD=$O(^TMP("ACRCR",$J,ACRSCHD)) Q:ACRSCHD=""!$D(ACRQUIT)  D
  1.  .S ACRFYDA=0
  1.  .F  S ACRFYDA=$O(^TMP("ACRCR",$J,ACRSCHD,ACRFYDA)) Q:'ACRFYDA!$D(ACRQUIT)  D
  1.  ..S ACRBATDA=0
  1.  ..F  S ACRBATDA=$O(^TMP("ACRCR",$J,ACRSCHD,ACRFYDA,ACRBATDA)) Q:'ACRBATDA!$D(ACRQUIT)  D
  1.  ...W !,ACRSCHD
  1.  ...W ?14,$P($G(^AFSLAFP(ACRFYDA,1,ACRBATDA,0)),U)
  1.  ...S Y=$P($G(^AFSLAFP(ACRFYDA,1,ACRBATDA,2)),U)
  1.  ...X ^DD("DD")
  1.  ...W ?24,Y
  1.  ...S ACRJ=ACRJ+1
  1.  ...S (ACRSEQDA,X)=0
  1.  ...F  S ACRSEQDA=$O(^AFSLAFP(ACRFYDA,1,ACRBATDA,1,ACRSEQDA)) Q:'ACRSEQDA  D
  1.  ....S Y=$$NET^ACRFSSU(ACRFYDA,ACRBATDA,ACRSEQDA)   ;ACR*2.1*5.02
  1.  ....S X=X+Y
  1.  ....S ACRTOT=ACRTOT+Y
  1.  ...W ?64,$J($FN(X,"P,",2),15)
  1.  ...I $Y+4>IOSL D PAUSE^ACRFWARN Q:$D(ACRQUIT)  D CRHEAD
  1.  W $$DASH^ACRFMENU
  1.  W !,"TOTAL",?24,"COUNT: ",ACRJ,?64,$J($FN(ACRTOT,"P,",2),15)
  1.  D PAUSE^ACRFWARN
  1.  Q
  1. CRHEAD ;CASH RECONCILIATION HEADER
  1.  W @IOF
  1.  W $$DASH^ACRFMENU
  1.  W !?20,"Export listing for comparison with the"
  1.  W !?20,"Treasury Confirmation Report"
  1.  S Y=DT
  1.  X ^DD("DD")
  1.  W !?20,"Report Date.....: ",Y
  1.  S Y=ACRBEGIN
  1.  X ^DD("DD")
  1.  W !?20,"Report Period FR: ",Y
  1.  S Y=ACREND
  1.  X ^DD("DD")
  1.  W !?20,"Report Period TO: ",Y
  1.  W $$DASH^ACRFMENU
  1.  W !,"SCHEDULE",?14,"BATCH",?24,"EXPORT",?72,"NET"
  1.  W !,"NUMBER",?14,"NUMBER",?24,"DATE",?72,"AMOUNT"
  1.  W $$DASH^ACRFMENU
  1.  Q
  1. APPROP ;EP;FOR APPROPRIATION REPORTS
  1.  D APPEXIT
  1.  F  D APP1 Q:$D(ACRQUIT)!$D(ACROUT)
  1. APPEXIT K ACROUT,ACRQUIT,ACR1,ACR1A,ACR2,ACR2A,ACRX,ACRXREF,ACRAPP,ACRFY,ACR,ACRDC,ACRFYDA,ACRBATDA,ACRSEQDA
  1.  K ^TMP("ACRAPPRP",$J)
  1.  Q
  1. APP1 W @IOF
  1.  W !!?10,"Appropriation Report"
  1.  S DIR(0)="SO^1:Sort by Batch within Appropriation;2:Sort by Schedule within Appropriation;3:Sort by Appropriation within Schedule"
  1.  S DIR("A")="Which one"
  1.  W !
  1.  D DIR^ACRFDIC
  1.  I $D(ACRQUIT)!$D(ACROUT)!'Y S ACRQUIT="" Q
  1.  I X=1 S ACR1="APPROPRIATION",ACR2="BATCH",ACRXREF="PROBAT"
  1.  I X=2 S ACR1="APPROPRIATION",ACR2="SCHEDULE",ACRXREF="PROSCH"
  1.  I X=3 S ACR1="SCHEDULE",ACR2="APPROPRIATION",ACRXREF="SCHPRO"
  1.  K ACRFYDA,ACRBATDA,ACRSEQDA
  1.  D FYBAT^ACRFPAY2
  1.  Q:$D(ACROUT)
  1.  I '$G(ACRBATDA) S (ACRBATNO,ACRBATDA)=""
  1.  N ACRBATDX
  1.  S ACRBATDX=ACRBATDA
  1.  S ACRBATDA=ACRBATDA-1
  1.  D APP
  1.  Q:$D(ACRQUIT)   ;ACR*2.1*3.17
  1.  S (ZTRTN,ACRRTN)="PAPP^ACRFPAY7"
  1.  S ZTDESC="PAYMENT APPROPRIATION REPORT"
  1.  D ^ACRFZIS
  1.  Q
  1. APP ;SELECT APPROPRIATION SORT RANGE
  1.  S DIC="^AUTTPRO("
  1.  S DIC(0)="AEMQZ"
  1.  S DIC("A")="Report for which APPROPRIATION: "
  1.  W !!,"Select an APPROPRIATION NO. to report for ONE Appropriation"
  1.  W !,"Press <ENTER> to report for all APPROPRIATIONs."
  1.  W !
  1.  D DIC^ACRFDIC
  1.  I X["^" S ACRQUIT="" Q
  1.  S ACRAPP=$P(Y,U,2)
  1.  I ACR1="APPROPRIATION" S ACR1A=ACRAPP
  1.  E  S ACR1A=""
  1.  S:ACRAPP]"" ACRAPP=$O(^AUTTPRO("B",ACRAPP),-1)
  1.  Q
  1. PAPP ;EP;TO PRINT APPROPRIATION REPORTS
  1.  K ^TMP("ACRAPPRP",$J)
  1.  D PAPPHEAD
  1.  S ACRBATDA=0
  1.  F  S ACRBATDA=$O(^AFSLAFP(ACRFYDA,1,ACRBATDA)) Q:'ACRBATDA!(ACRBATDX&(ACRBATDA'=ACRBATDX))  D
  1.  .N ACRBAT   ;ACR*2.1*5.02
  1.  .S ACRBAT=$$BATCH^ACRFPAYE(ACRFYDA,ACRBATDA)   ;ACR*2.1*5.02
  1.  .Q:ACRBAT="G"                                  ;ACR*2.1*5.02
  1.  .Q:ACRBAT=""                                   ;ACR*2.1*5.02
  1.  .S ACRSEQDA=0
  1.  .F  S ACRSEQDA=$O(^AFSLAFP(ACRFYDA,1,ACRBATDA,1,ACRSEQDA)) Q:'ACRSEQDA  D
  1.  ..N X,Y,Z
  1.  ..S X=$P($G(^AFSLAFP(ACRFYDA,1,ACRBATDA,0)),U)
  1.  ..S Y=$G(^AFSLAFP(ACRFYDA,1,ACRBATDA,1,ACRSEQDA,1))
  1.  ..S Z=$P(Y,U,21)
  1.  ..Q:X=""!(Y="")!(Z="")                           ;ACR*2.1*5.02
  1.  ..S Y=$$NET^ACRFSSU(ACRFYDA,ACRBATDA,ACRSEQDA)   ;ACR*2.1*5.02
  1.  ..I ACR1="APPROPRIATION",ACR2="BATCH" S ACR1X=Z,ACR2X=X
  1.  ..I ACR1="APPROPRIATION",ACR2="SCHEDULE" S ACR1X=Z,ACR2X=Y
  1.  ..I ACR1="SCHEDULE",ACR2="APPROPRIATION" S ACR1X=Y,ACR2X=Z
  1.  ..S ^TMP("ACRAPPRP",$J,ACR1X,ACR2X,ACRFYDA,ACRBATDA,ACRSEQDA)=""
  1.  S ACR1X=""
  1.  F  S ACR1X=$O(^TMP("ACRAPPRP",$J,ACR1X)) Q:ACR1X=""!$D(ACRQUIT)  D:ACR1X[ACR1A
  1.  .W !!,"FISCAL YEAR",?15,": ",ACRFY
  1.  .W !,ACR1,?15,": ",ACR1X
  1.  .N ACR1TOT
  1.  .S ACR1TOT=0
  1.  .S ACR2X=""
  1.  .F  S ACR2X=$O(^TMP("ACRAPPRP",$J,ACR1X,ACR2X)) Q:ACR2X=""!$D(ACRQUIT)  D
  1.  ..W !,ACR2,?15,": ",ACR2X,!
  1.  ..S ACRBATDA=0
  1.  ..F  S ACRBATDA=$O(^TMP("ACRAPPRP",$J,ACR1X,ACR2X,ACRFYDA,ACRBATDA)) Q:'ACRBATDA!$D(ACRQUIT)  D
  1.  ...S ACRBATNO=$P($G(^AFSLAFP(ACRFYDA,1,ACRBATDA,0)),U)
  1.  ...S ACRSEQDA=0
  1.  ...F  S ACRSEQDA=$O(^TMP("ACRAPPRP",$J,ACR1X,ACR2X,ACRFYDA,ACRBATDA,ACRSEQDA)) Q:'ACRSEQDA!$D(ACRQUIT)  D
  1.  ....D PDISP
  1.  ....I $Y+5>IOSL D PAUSE^ACRFWARN Q:$D(ACRQUIT)  D PAPPHEAD:$O(^TMP("ACRAPPRP",$J,ACR1X,ACR2X,ACRFYDA,ACRBATDA,ACRSEQDA))
  1.  ....I '$O(^TMP("ACRAPPRP",$J,ACR1X,ACR2X,ACRFYDA,ACRBATDA,ACRSEQDA)) D PAUSE^ACRFWARN
  1.  ...D APPSUM^ACRFPAY8
  1.  ..W $$DASH^ACRFMENU
  1.  D PAUSE^ACRFWARN
  1.  W @IOF
  1.  K ^TMP("ACRAPPRP",$J)
  1.  Q
  1. PAPPHEAD ;HEADER FOR APPROPRIATION REPORT
  1.  W @IOF
  1.  S ACRDC=$G(ACRDC)+1
  1.  W !?10,"Appropriation Report",?60,"PAGE ",ACRDC
  1.  W !?10,"Report Date: "
  1.  S Y=DT
  1.  X ^DD("DD")
  1.  W Y
  1.  W !?10,"Sort by....: ",ACR1
  1.  W !?10,"Then by....: ",ACR2
  1.  W $$DASH^ACRFMENU
  1.  Q
  1. PDISP ;APPROPRIATION DISPLAY
  1.  N X,Y,Z,XT
  1.  S X=$G(^AFSLAFP(ACRFYDA,1,ACRBATDA,1,ACRSEQDA,0))
  1.  S Y=$G(^AFSLAFP(ACRFYDA,1,ACRBATDA,1,ACRSEQDA,1))
  1.  S Z=$G(^AFSLAFP(ACRFYDA,1,ACRBATDA,1,ACRSEQDA,2))
  1.  S XT=$$NET^ACRFSSU(ACRFYDA,ACRBATDA,ACRSEQDA)   ;ACR*2.1*5.02
  1.  S ACR1TOT=ACR1TOT+XT                            ;ACR*2.1*5.02
  1.  W !,$P(X,U),?5,$P(X,U,20),?16,$P(X,U,5),?20,$P(X,U,21),?31,$P(X,U,6)   ;ACR*2.1*5.02
  1.  W ?35,ACRBATNO,?42,$P(Y,U,11)                   ;ACR*2.1*5.02
  1.  W ?50,$J($FN(XT,"P,",2),15)                     ;ACR*2.1*5.02
  1.  W !?5,$P($G(^AUTTCAN(+$P(X,U,7),0)),U),?13,$P($G(^AUTTOBJC(+$P(X,U,8),0)),U),?18,$P(X,U,15),?20,$P(Y,U,19),?22,$P(X,U,17),?27,$P(X,U,18)
  1.  I $P(X,U,10) W ?50,$P($G(^AUTTVNDR(+$P(X,U,10),0)),U)
  1.  ;E  I $P(X,U,24) W ?50,$P($G(^VA(200,+$P(X,U,24),0)),U)  ;ACR*2.1*19.02 IM16848
  1.  E  I $P(X,U,24) W ?50,$$NAME2^ACRFUTL1(+$P(X,U,24))  ;ACR*2.1*19.02 IM16848
  1.  W !?5,$P(Z,U,14)
  1.  Q
  1. PBDISP ;EP;BATCH DISPLAY
  1.  K ACRAPPN
  1.  D PBHEAD
  1.  S ACRSEQDA=0
  1.  F  S ACRSEQDA=$O(^AFSLAFP(ACRFYDA,1,ACRBATDA,1,ACRSEQDA)) Q:'ACRSEQDA!$D(ACRQUIT)  D
  1.  .N X
  1.  .S X=$G(^AFSLAFP(ACRFYDA,1,ACRBATDA,1,ACRSEQDA,0))
  1.  .Q:'$P(X,U,10)&'$P(X,U,24)
  1.  .I $P(X,U,10) S X=$P($G(^AUTTVNDR($P(X,U,10),0)),U)
  1.  .;E  S:$P(X,U,24) X=$P($G(^VA(200,$P(X,U,24),0)),U)  ;ACR*2.1*19.02 IM16848
  1.  .E  S:$P(X,U,24) X=$$NAME2^ACRFUTL1($P(X,U,24))  ;ACR*2.1*19.02 IM16848
  1.  .Q:X=""
  1.  .S ^TMP("ACRPBAT",$J,ACRFYDA,ACRBATDA,X,ACRSEQDA)=""
  1.  N ACRX
  1.  S ACRX=""
  1.  F  S ACRX=$O(^TMP("ACRPBAT",$J,ACRFYDA,ACRBATDA,ACRX)) Q:ACRX=""!$D(ACRQUIT)  D
  1.  .S ACRSEQDA=0
  1.  .F  S ACRSEQDA=$O(^TMP("ACRPBAT",$J,ACRFYDA,ACRBATDA,ACRX,ACRSEQDA)) Q:'ACRSEQDA!$D(ACRQUIT)  D PBD1
  1.  D APPSUM^ACRFPAY8
  1.  Q
  1. PBD1 ;EP; TO DISPLAY BATCH PAYMENT SUMMARY
  1.  N ACRACH,X,Y,Z
  1.  S X=$G(^AFSLAFP(ACRFYDA,1,ACRBATDA,1,ACRSEQDA,0))
  1.  S Y=$G(^AFSLAFP(ACRFYDA,1,ACRBATDA,1,ACRSEQDA,1))
  1.  S Z=$G(^AFSLAFP(ACRFYDA,1,ACRBATDA,1,ACRSEQDA,2))
  1.  W !,"DOCUMENT #: ",$P(X,U,5)," ",$P(X,U,20)
  1.  W ?30,"CAN....: ",$P($G(^AUTTCAN(+$P(X,U,7),0)),U)
  1.  W ?60,"OBJECT CODE: ",$P($G(^AUTTOBJC(+$P(X,U,8),0)),U)
  1.  W !,"OTHER DOC.: ",$P(X,U,6)," ",$P(X,U,21)
  1.  W ?30,"FORM #.: "
  1.  W ?60,"FED/NONFED.: ",$P(X,U,15)
  1.  I $P(X,U,10) D  I 1
  1.  .W !,"PAYEE.....: "
  1.  .W ?12,$P($G(^AUTTVNDR(+$P(X,U,10),0)),U)
  1.  .W ?60,"EIN: ",$P($G(^AUTTVNDR(+$P(X,U,10),11)),U,13)
  1.  .W !,"REMIT ADDR: "
  1.  .W ?12,$P(X,U,28)
  1.  .W !,"(PAYMENT",?12,$P(Y,U)," ",$P(Y,U,2),"  ",$P(Y,U,3)
  1.  .W !,"RECORD)",?12,"ATTN: ",$P(X,U,25)
  1.  .N ACRX,ACRY,ACRZ
  1.  .S ACRX=$G(^AUTTVNDR(+$P(X,U,10),13))
  1.  .S ACRY=$G(^AUTTVNDR(+$P(X,U,10),14))
  1.  .S ACRZ=$G(^AUTTVNDR(+$P(X,U,10),19))
  1.  .I $P(ACRZ,U)]"",$S($D(^XUSEC("ACRFZ EDIT EFT",DUZ)):1,$D(^XUSEC("ACRFZ VIEW EFT",DUZ)):1,1:0) W !?12,$P(ACRZ,U),"/",$P(ACRZ,U,2),"/",$P(ACRZ,U,3)
  1.  .W !,"REMIT ADDR: "
  1.  .W ?12,$P(ACRY,U)
  1.  .W:$P(ACRY,U,2)]"" !?12,$P(ACRY,U,2)
  1.  .W !,"(VENDOR",?12,$P(ACRY,U,3)," ",$P($G(^DIC(5,+$P(ACRY,U,4),0)),U,2),"  ",$P(ACRY,U,5)
  1.  .W !,"FILE)",?12,"ATTN: ",$P(ACRY,U,6)
  1.  .W !,"MAIL ADDR.: "
  1.  .W ?12,$P(ACRX,U)
  1.  .W:$P(ACRX,U,10)]"" !?12,$P(ACRX,U,10)
  1.  .W !?12,$P(ACRX,U,2)," ",$P($G(^DIC(5,+$P(ACRX,U,3),0)),U,2),"  ",$P(ACRX,U,4)
  1.  .W !?12,"ATTN: ",$P(ACRX,U,5)
  1.  E  I $P(X,U,24) D
  1.  .W !,"PAYEE.....: "
  1.  .;W ?12,$P($G(^VA(200,+$P(X,U,24),0)),U)  ;ACR*2.1*19.02 IM16848
  1.  .W ?12,$$NAME2^ACRFUTL1(+$P(X,U,24))  ;ACR*2.1*19.02 IM16848
  1.  .S ACRZ=$G(^ACRAU(+$P(X,U,24),19))
  1.  .I $P(ACRZ,U)]"",$S($D(^XUSEC("ACRFZ EDIT EFT",DUZ)):1,$D(^XUSEC("ACRFZ VIEW EFT",DUZ)):1,1:0) W !?12,$P(ACRZ,U),"/",$P(ACRZ,U,2),"/",$P(ACRZ,U,3)
  1.  ;W !,"ACCT TECH.: ",$P($G(^VA(200,+$P(X,U,3),0)),U)  ;ACR*2.1*19.02 IM16848
  1.  W !,"ACCT TECH.: ",$$NAME2^ACRFUTL1(+$P(X,U,3))  ;ACR*2.1*19.02 IM16848
  1.  S ACRACH=$P($G(^AFSLAFP(ACRFYDA,1,ACRBATDA,2)),U,8)
  1.  ;W !,$S(ACRACH="C"!(ACRACH="N"):"PAID FOR..: ",1:"ACH ADDEN.: ") ;ACR*2.1*17.05 IM17132 
  1.  ;W:$P(Z,U,14)]"" $P(Z,U,14)," "              ;ACR*2.1*17.05 IM17132
  1.  ;W:$L($P(Z,U,2))>1 $P(Z,U,2)                 ;ACR*2.1*17.05 IM17132
  1.  I "NCG"[ACRACH W !,"PAID FOR..: ",$P(Z,U,14) ;ACR*2.1*17.05 IM17132
  1.  I "AB"[ACRACH W !,"ACH ADDEN.: ",$P(Z,U,2)   ;ACR*2.1*17.05 IM17132
  1.  S ACRBTYP=$P($G(^AFSLAFP(ACRFYDA,1,ACRBATDA,0)),U,4)
  1.  N XT                                            ;ACR*2.1*5.02
  1.  S XT=$$NET^ACRFSSU(ACRFYDA,ACRBATDA,ACRSEQDA)   ;ACR*2.1*5.02
  1.  W !,"PAY AMOUNT: ",$J($FN(XT,"P,",2),15)        ;ACR*2.1*5.02
  1.  W ?30,"FULL/PART: "
  1.  ;W ?60,"INT SEQ.: ",$P(Y,U,5)               ;ACR*2.1*17.11 IM17514
  1.  W ?59,"INT SEQ.: ",$P(Y,U,5)                ;ACR*2.1*17.11 IM17514
  1.  W !,"TRANS CODE: ",$P(X,U,18)
  1.  W ?30,"OTH TR CD: ",$P(X,U,19)
  1.  ;W ?60,"INT $AMT: ",$P(Y,U,6)                 ;ACR*2.1*17.11 IM17514
  1.  W ?59,"INT $AMT: ",$P(Y,U,6)                  ;ACR*2.1*17.11 IM17514
  1.  W !,"SCHED NO..: ",$P(Y,U,11)
  1.  W ?30,"PP-DUE...: "
  1.  ;W ?60,"INT DOC.: ",$P(Y,U,8)                 ;ACR*2.1*17.11 IM17514
  1.  W ?59,"INT DOC.: ",$P(Y,U,8)                  ;ACR*2.1*17.11 IM17514
  1.  W !,"APPROPRTN.: ",$P(Y,U,21)
  1.  W $$DASH^ACRFMENU
  1.  I $Y+10>IOSL D PAUSE^ACRFWARN Q:$D(ACRQUIT)  D PBHEAD:$O(^TMP("ACRPBAT",$J,ACRFYDA,ACRBATDA,ACRX,ACRSEQDA))!($O(^TMP("ACRPBAT",$J,ACRFYDA,ACRBATDA,ACRX))]"")
  1.  Q
  1. PBAT ;EP;TO PRINT BATCH PAYMENT LISTING
  1.  D PBEXIT
  1.  F  D PB1 Q:$D(ACRQUIT)!$D(ACROUT)
  1. PBEXIT K ACROUT,ACRQUIT,ACR1,ACR1A,ACR2,ACR2A,ACRX,ACRXREF,ACRAPP,ACRFY,ACR,ACRDC,ACRFYDA,ACRBATDA,ACRSEQDA
  1.  Q
  1. PB1 W @IOF
  1.  W !!?10,"Batch Payment Listing"
  1.  K ACRFYDA,ACRBATDA,ACRSEQDA
  1.  D FYBAT^ACRFPAY2
  1.  I '$G(ACRFYDA)!'$G(ACRBATDA) S ACRQUIT="" Q
  1.  Q:'$G(ACRBATDA)
  1.  S (ZTRTN,ACRRTN)="PBDISP^ACRFPAY7"
  1.  S ZTDESC="BATCH PAYMENT LISTING"
  1.  D ^ACRFZIS
  1.  Q
  1. PBHEAD ;EP;HEADER
  1.  W @IOF
  1.  S ACRDC=$G(ACRDC)+1
  1.  W !?10,"Batch Payment Listing",?60,"PAGE: ",ACRDC
  1.  W !?10,"Report Date: "
  1.  S Y=DT
  1.  X ^DD("DD")
  1.  W Y
  1.  W !?10,"Fiscal Year: ",$P(^AFSLAFP(ACRFYDA,0),U)
  1.  W !?10,"Batch......: ",ACRBATNO
  1.  W $$DASH^ACRFMENU
  1.  Q