Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: APCM24E4

APCM24E4.m

Go to the documentation of this file. 
  1. APCM24E4 ;IHS/CMI/LAB - IHS MU;  ; 30 Jul 2013  8:15 AM
  1.  ;;1.0;IHS MU PERFORMANCE REPORTS;**5,6**;MAR 26, 2012;Build 65
  1.  ;;;;;;Build 3
  1. AL ;EP - CALCULATE ALLERY LIST
  1.  ;for each provider or for the facility find out if this
  1.  ;patient had a visit of A, O, R, S to this provider or facility
  1.  ;if so, then check to see if they any ALLERGIES OR NAA documented in report period
  1.  NEW APCMP
  1.  S (APCMD1,APCMN1)=0
  1.  I APCMRPTT=1 D  Q
  1.  .S APCMP=0 F  S APCMP=$O(APCMPRV(APCMP)) Q:APCMP'=+APCMP  D
  1.  ..Q:'$D(APCMHVTP(APCMP))  ;no visits to this provider for this patient so don't bother, the patient is not in the denominator
  1.  ..D AL1
  1.  ..Q
  1.  I APCMRPTT=2 D
  1.  .S APCMP=APCMFAC
  1.  .Q:'$D(APCMHVTP(APCMP))
  1.  .D AL1
  1.  .Q
  1.  Q
  1. AL1 ;
  1.  ;set denominator value into field
  1.  S F=$P(^APCM24OB(APCMIC,0),U,8)  ;denom field for this measure
  1.  D S^APCM24E1(APCMRPT,APCMIC,1,APCMP,APCMRPTT,APCMTIME,F)
  1.  S APCMVALU="VISIT: "_$$DATE^APCM1UTL(APCMHVTP(APCMP))
  1.  ;numerator?
  1.  S APCMEP=$$HASAL(DFN,APCMBDAT,APCMEDAT)
  1.  S APCMVALU=APCMVALU_"|||"_$P(APCMEP,U,2)_"|||"_$P(APCMEP,U,1)
  1.  S F=$P(^APCM24OB(APCMIC,0),U,9)
  1.  D S^APCM24E1(APCMRPT,APCMIC,$P(APCMEP,U,1),APCMP,APCMRPTT,APCMTIME,F)
  1.  D SETLIST^APCM24E1
  1.  Q
  1. HASAL(P,BD,ED) ;does patient have an allergy entered before end of report period
  1.  ;
  1.  NEW A,B,C,D,E,X
  1.  ;check in allergy tracking for a "drug" allergy ever
  1.  S E=""
  1.  S X=0 F  S X=$O(^GMR(120.8,"B",P,X)) Q:X'=+X!(E)  D
  1.  .S A=$$VAL^XBDIQ1(120.8,X,3.1)
  1.  .S D=$P($P(^GMR(120.8,X,0),U,4),".")
  1.  .I D>ED Q  ;after report period
  1.  .I A]"",A["DRUG" S E=1_U_"Allergy: "_$$VAL^XBDIQ1(120.8,X,.02)_" entered on "_$$DATE^APCM1UTL(D) Q
  1.  I E]"" Q E
  1.  ;now check for no known allergies
  1.  I $D(^GMR(120.86,P,0)),$P(^GMR(120.86,P,0),U,2)=0 D
  1.  .S D=$P($P(^GMR(120.86,P,0),U,4),".",1)
  1.  .Q:D>ED  ;after ed
  1.  .S E=1_U_"NKA noted on "_$$FMTE^XLFDT($P($P(^GMR(120.86,P,0),U,4),".",1))
  1.  I E]"" Q E
  1.  S D=$$LASTNAA^APCLAPI6(P,,ED,"D")
  1.  I D]"" S E="1^No Active Allergies on "_$$DATE^APCM1UTL(D)
  1.  Q E
  1. EPRES ;EP - CALCULATE EPRESCRIBING
  1.  G EPRES^APCM24EB
  1. VS ;EP - CALCULATE VITAL SIGNS
  1.  ;for each provider or for the facility find out if this
  1.  ;patient had a visit of A, O, R, S to this provider or facility
  1.  ;if so, then check to see if they have vital signs documented anytime before end of report period
  1.  NEW APCMP,APCMFIED,APCMFIEN
  1.  S APCMFIED=$P(^APCM24OB(APCMIC,0),U,8)
  1.  S APCMFIEN=$P(^APCM24OB(APCMIC,0),U,9)
  1.  S APCMBPON=0,APCMNOHW=0
  1.  S (APCMD1,APCMN1)=0
  1.  I APCMRPTT=1 D  Q
  1.  .S APCMP=0 F  S APCMP=$O(APCMPRV(APCMP)) Q:APCMP'=+APCMP  D
  1.  ..;S F=$P(^APCM24OB(APCMIC,0),U,18),APCMNP=$P(^DD(9001303.0311,F,0),U,4),N=$P(APCMNP,";"),P=$P(APCMNP,";",2)
  1.  ..;S APCME=$$V^APCM24ER(1,APCMRPT,N,P,APCMP,"I",APCMRPTT) Q:APCME="X"  ;don't bother as this one is excluded
  1.  ..;D S^APCM24E1(APCMRPT,APCMIC,1,APCMP,APCMRPTT,APCMTIME,F,1)
  1.  ..S APCMFIED=$P(^APCM24OB(APCMIC,0),U,8)
  1.  ..S APCMFIEN=$P(^APCM24OB(APCMIC,0),U,9)
  1.  ..S APCMBPON=0,APCMNOHW=0
  1.  ..I $G(APCMADDQ("ANS",APCMIC,24,APCMP))="Yes" D  Q
  1.  ...;SET EXCLUSION
  1.  ...S F=$P(^APCM24OB(APCMIC,0),U,11) D S^APCM24E1(APCMRPT,APCMIC,"Yes",APCMP,APCMRPTT,APCMTIME,F,1)
  1.  ...;SET SKIP
  1.  ...S F=$P(^APCM24OB(APCMIC,0),U,18)
  1.  ...D S^APCM24E1(APCMRPT,APCMIC,"X",APCMP,APCMRPTT,APCMTIME,F,1)
  1.  ...;set associated measures with skip "X"
  1.  ...S X=0 F  S X=$O(^APCM24OB(APCMIC,29,X)) Q:X'=+X  D
  1.  ....S Y=$P(^APCM24OB(APCMIC,29,X,0),U,1)
  1.  ....S Y=$O(^APCM24OB("B",Y,0))
  1.  ....S F=$P(^APCM24OB(Y,0),U,18)
  1.  ....D S^APCM24E1(APCMRPT,Y,"X",APCMP,APCMRPTT,APCMTIME,F,1)
  1.  ..I $G(APCMADDQ("ANS",APCMIC,25,APCMP))="Yes"!($G(APCMADDQ("ANS",APCMIC,27,APCMP))="Yes") D  G VSC
  1.  ...S Z=$O(^APCM24OB("B","S2.008.EP.2",0)),APCMFIED=$P(^APCM24OB(Z,0),U,8),APCMFIEN=$P(^APCM24OB(Z,0),U,9)
  1.  ...S APCMNOBP=1  ;no BP use S2.008.EP.2
  1.  ...F Z="S2.008.EP.1","S2.008.EP" S Y=$O(^APCM24OB("B",Z,0)) D
  1.  ....S F=$P(^APCM24OB(Y,0),U,18)
  1.  ....D S^APCM24E1(APCMRPT,Y,"X",APCMP,APCMRPTT,APCMTIME,F,1)
  1.  ....I Z="S2.008.EP" Q
  1.  ....S F=$P(^APCM24OB(Y,0),U,11)
  1.  ....D S^APCM24E1(APCMRPT,Y,"Yes",APCMP,APCMRPTT,APCMTIME,F,1)
  1.  ...S Y=$O(^APCM24OB("B","S2.008.EP.2",0))
  1.  ...S F=$P(^APCM24OB(Y,0),U,11)
  1.  ...D S^APCM24E1(APCMRPT,Y,"N/A",APCMP,APCMRPTT,APCMTIME,F,1)
  1.  ..I $G(APCMADDQ("ANS",APCMIC,28,APCMP))="Yes" D  G VSC
  1.  ...S APCMNOHW=1  ;no BP use S2.008.EP.1
  1.  ...S Z=$O(^APCM24OB("B","S2.008.EP.1",0)),APCMFIED=$P(^APCM24OB(Z,0),U,8),APCMFIEN=$P(^APCM24OB(Z,0),U,9)
  1.  ...F Z="S2.008.EP","S2.008.EP.2" S Y=$O(^APCM24OB("B",Z,0)) D
  1.  ....S F=$P(^APCM24OB(Y,0),U,18)
  1.  ....D S^APCM24E1(APCMRPT,APCMIC,"X",APCMP,APCMRPTT,APCMTIME,F,1)
  1.  ....I Z="S2.008.EP" Q
  1.  ....S F=$P(^APCM24OB(Y,0),U,11)
  1.  ....D S^APCM24E1(APCMRPT,Y,"Yes",APCMP,APCMRPTT,APCMTIME,F,1)
  1.  ...S Y=$O(^APCM24OB("B","S2.008.EP.1",0))
  1.  ...S F=$P(^APCM24OB(Y,0),U,11)
  1.  ...D S^APCM24E1(APCMRPT,Y,"N/A",APCMP,APCMRPTT,APCMTIME,F,1)
  1.  ..I $G(APCMADDQ("ANS",APCMIC,24,APCMP))="No" D  G VSC
  1.  ...F Z="S2.008.EP.1","S2.008.EP.2" S Y=$O(^APCM24OB("B",Z,0)) D
  1.  ....S F=$P(^APCM24OB(Y,0),U,18)
  1.  ....D S^APCM24E1(APCMRPT,APCMIC,"X",APCMP,APCMRPTT,APCMTIME,F,1)
  1. VSC ..;
  1.  ..Q:'$D(APCMHVTP(APCMP))  ;no visits to this provider for this patient so don't bother, the patient is not in the denominator
  1.  ..D VS1
  1.  .Q
  1.  I APCMRPTT=2 D
  1.  .S APCMP=APCMFAC
  1.  .Q:'$D(APCMHVTP(APCMP))
  1.  .D VS1
  1.  .Q
  1.  Q
  1. VS1 ;set denominator value into field
  1.  I $$AGE^AUPNPAT(DFN,APCMHVTP(APCMP))<3,$G(APCMADDQ("ANS",APCMIC,28,APCMP))="Yes" Q
  1.  S F=APCMFIED ;$P(^APCM24OB(APCMIC,0),U,8)  ;denom field for this measure
  1.  D S^APCM24E1(APCMRPT,APCMIC,1,APCMP,APCMRPTT,APCMTIME,F)
  1.  S APCMVALU="VISIT: "_$$DATE^APCM1UTL(APCMHVTP(APCMP))
  1.  ;numerator?
  1.  I APCMRPTT=1 S APCMEP=$$HASVSEP(DFN,$$DOB^AUPNPAT(DFN),APCMEDAT,APCMHVTP(APCMP))
  1.  I APCMRPTT=2 S APCMEP=$$HASVS(DFN,$$DOB^AUPNPAT(DFN),APCMEDAT,APCMHVTP(APCMP))
  1.  S APCMVALU=APCMVALU_"|||"_$P(APCMEP,U,2)_"|||"_$P(APCMEP,U,1)
  1.  S F=APCMFIEN ;$P(^APCM24OB(APCMIC,0),U,9)
  1.  D S^APCM24E1(APCMRPT,APCMIC,$P(APCMEP,U,1),APCMP,APCMRPTT,APCMTIME,F)
  1.  D SETLIST^APCM24E1
  1.  Q
  1. HASVS(P,BD,ED,VD) ;does patient have a problem entered before end of report period
  1.  ;
  1.  NEW A,B,C,D,E,HT,WT,BP
  1.  S C=0
  1.  S (HT,WT,BP)=""
  1.  S HT=$$LASTITEM^APCLAPIU(P,"HT","MEASUREMENT",BD,ED)
  1.  S WT=$$LASTITEM^APCLAPIU(P,"WT","MEASUREMENT",BD,ED)
  1.  S BP=$$LASTITEM^APCLAPIU(P,"BP","MEASUREMENT",BD,ED)
  1.  I BP]"" S BP="BP"
  1.  I BP="",$$AGE^AUPNPAT(P,VD)<3 S BP="N/A <3 yrs"
  1.  I HT]"",WT]"",BP]"" Q 1_U_"Has: HT, WT, "_BP
  1.  Q 0_U_"Has: "_$S(HT]"":"HT ",1:"")_$S(WT]"":"WT ",1:"")_$S(BP]"":"BP ",1:"")
  1. HASVSEP(P,BD,ED,VD) ;does patient have a HT/WT/BP entered before end of report period
  1.  ;
  1.  NEW A,B,C,D,E,HT,WT,BP,M
  1.  S M=$O(^APCM24OB("B","S2.008.EP",0))
  1.  S C=0
  1.  S (HT,WT,BP)=""
  1.  S HT=$$LASTITEM^APCLAPIU(P,"HT","MEASUREMENT",BD,ED)
  1.  S WT=$$LASTITEM^APCLAPIU(P,"WT","MEASUREMENT",BD,ED)
  1.  S BP=$$LASTITEM^APCLAPIU(P,"BP","MEASUREMENT",BD,ED)
  1.  I BP]"" S BP="BP"
  1.  I BP="",$$AGE^AUPNPAT(P,VD)<3 S BP="BP not relevant <3"
  1.  I $G(APCMADDQ("ANS",M,24,APCMP))="No",HT]"",WT]"",BP]"" Q 1_U_"Has: HT, WT, "_BP
  1.  I $G(APCMADDQ("ANS",M,25,APCMP))="Yes",HT]"",WT]"" Q 1_U_"Has: HT, WT, BP not relevant"
  1.  I $G(APCMADDQ("ANS",M,27,APCMP))="Yes",HT]"",WT]"" Q 1_U_"Has: HT, WT, BP not relevant"
  1.  I $G(APCMADDQ("ANS",M,28,APCMP))="Yes",BP]"" Q 1_U_"Has: BP, HT&WT not relevant"
  1.  I $G(APCMADDQ("ANS",M,24,APCMP))="Yes",HT]"",WT]"",BP]"" Q 1_U_"Has: HT, WT, BP"
  1.  Q 0_U_"Has: "_$S(HT]"":"HT ",1:"")_$S(WT]"":"WT ",1:"")_$S(BP]"":"BP ",1:"")
  1.  ;
  1.  ;
  1.  ;
  1. ST ;EP - CALCULATE SMOKING STATUS
  1.  ;for each provider or for the facility find out if this
  1.  ;patient had a visit of A, O, R, S to this provider or facility
  1.  ;if so, then check to see if they have SMOKING STATUS documented anytime before end of report period
  1.  NEW APCMP
  1.  S (APCMD1,APCMN1)=0
  1.  I APCMRPTT=1 D  Q
  1.  .S APCMP=0 F  S APCMP=$O(APCMPRV(APCMP)) Q:APCMP'=+APCMP  D
  1.  ..I $D(APCM24ON(APCMP,APCMTIME)) S F=$P(^APCM24OB(APCMIC,0),U,11) D S^APCM24E1(APCMRPT,APCMIC,"Provider is excluded from this measure as he/she did not see anyone over 13 during the EHR reporting period.",APCMP,APCMRPTT,APCMTIME,F,1) Q
  1.  ..Q:$$AGE^AUPNPAT(DFN,APCMBDAT)<13
  1.  ..Q:'$D(APCMHVTP(APCMP))  ;no visits to this provider for this patient so don't bother, the patient is not in the denominator
  1.  ..D ST1
  1.  I APCMRPTT=2 D
  1.  .S APCMP=APCMFAC
  1.  .I $D(APCM24ON(APCMP,APCMTIME)) S F=$P(^APCM24OB(APCMIC,0),U,11) D S^APCM24E1(APCMRPT,APCMIC,"Hospital is excluded from this measure as did not admit anyone over 13 during the EHR reporting period.",APCMP,APCMRPTT,APCMTIME,F,1) Q
  1.  .Q:$$AGE^AUPNPAT(DFN,APCMBDAT)<13
  1.  .Q:'$D(APCMHVTP(APCMP))
  1.  .D ST1
  1.  .Q
  1.  Q
  1. ST1 ;set denominator value into field
  1.  S F=$P(^APCM24OB(APCMIC,0),U,8)  ;denom field for this measure
  1.  D S^APCM24E1(APCMRPT,APCMIC,1,APCMP,APCMRPTT,APCMTIME,F)
  1.  S APCMVALU="VISIT: "_$$DATE^APCM1UTL(APCMHVTP(APCMP))
  1.  ;numerator?
  1.  S APCMEP=$$HASST(DFN,$$DOB^AUPNPAT(DFN),APCMEDAT)
  1.  S APCMVALU=APCMVALU_"|||"_$P(APCMEP,U,2)_"|||"_$P(APCMEP,U,1)
  1.  S F=$P(^APCM24OB(APCMIC,0),U,9)
  1.  D S^APCM24E1(APCMRPT,APCMIC,$P(APCMEP,U,1),APCMP,APCMRPTT,APCMTIME,F)
  1.  D SETLIST^APCM24E1
  1.  Q
  1. HASST(P,BD,ED) ;does patient have a SMOKING STATUS
  1.  ;
  1.  NEW A,B,C,D,E,HF
  1.  S C=0
  1.  S HF=""
  1.  ;S HF=$$LASTHF^APCLAPIU(P,"TOBACCO (SMOKING)",,ED,"A")
  1.  F A="F002","F004","F108","F109","F110","F111","F121","F122" S B=$$LASTITEM^APCLAPIU(P,A,"HEALTH",,ED,"A") I B]"" S D($P(B,U,1))=$P(B,U,2)
  1.  ;ZW D
  1.  I '$D(D) Q 0
  1.  S HF=$O(D(999999999),-1) Q 1_U_$$DATE^APCM1UTL(HF)_" "_$P(D(HF),U,1)
  1.  Q 0
  1. CS ;EP - CLINICAL SUMMARIES ON EACH VISIT
  1.  NEW APCMP
  1.  S (APCMD1,APCMN1)=0
  1.  I APCMRPTT=1 S APCMP=0 F  S APCMP=$O(APCMPRV(APCMP)) Q:APCMP'=+APCMP  D
  1.  .I $D(APCMOFFV(APCMP,APCMTIME)) S F=$P(^APCM24OB(APCMIC,0),U,11) D
  1.  ..D S^APCM24E1(APCMRPT,APCMIC,"Provider is excluded from this measure as he/she did not have any office visits during the EHR Reporting Period.",APCMP,APCMRPTT,APCMTIME,F,1) Q
  1.  .Q:'$D(APCMHVTP(APCMP))  ;no visits to this provider for this patient so don't bother, the patient is not in the denominator
  1.  .;set denominator value into field
  1.  .S APCMEP=$$HASCS(DFN,APCMP,APCMBDAT,APCMEDAT,.APCMVSTS)  ;RETURNS # OF VISIT^# THAT HAD CS GIVEN W/IN 3 BUS DAYS
  1.  .S F=$P(^APCM24OB(APCMIC,0),U,8)  ;denom field for this measure
  1.  .D S^APCM24E1(APCMRPT,APCMIC,$P(APCMEP,U),APCMP,APCMRPTT,APCMTIME,F)
  1.  .;S APCMVALU="VISIT: "_$$DATE^APCM1UTL(APCMHVTP(APCMP))
  1.  .I $P(APCMEP,U,1) S APCMVALU="# visits: "_$P(APCMEP,U,1)_" - # w/CS: "_$P(APCMEP,U,2)_"|||"_$P(APCMEP,U,3)_"|||"_$S('(+$P(APCMEP,U,1)):0,$P(APCMEP,U,1)=$P(APCMEP,U,2):1,1:0)
  1.  .;numerator?
  1.  .S F=$P(^APCM24OB(APCMIC,0),U,9)
  1.  .D S^APCM24E1(APCMRPT,APCMIC,$P(APCMEP,U,2),APCMP,APCMRPTT,APCMTIME,F)
  1.  .I APCMVALU]"" D SETLIST^APCM24E1
  1.  Q
  1. HASCS(P,R,BD,ED,VSTS) ;does patient have a SMOKING STATUS
  1.  ;
  1.  NEW A,B,C,D,E,X,Y,V,PWH,J,EDUC
  1.  ;LOOP THROUGH ALL VISITS AND COUNT VISIT AND PWH'S
  1.  S PWH="0^0"
  1.  ;RETURN 3RD PIECE AS LIST OF VISITS WITH A "PWH" or "No PWH"
  1.  S X=0 F  S X=$O(VSTS(X)) Q:X'=+X  D
  1.  .S G=0
  1.  .S V=$P(VSTS(X),U,5)
  1.  .I '$D(^AUPNVSIT(V,0)) Q
  1.  .I $P(^AUPNVSIT(V,0),U,11) Q  ;deleted
  1.  .I "AOSM"'[$P(^AUPNVSIT(V,0),U,7) Q  ;not correct service category/OFFICE VISIT
  1.  .S C=$$CLINIC^APCLV(V,"C")
  1.  .Q:C=30
  1.  .Q:C=77
  1.  .I C=76 Q  ;no lab
  1.  .I C=63 Q  ;no radiology
  1.  .I C=39 Q  ;no pharmacy
  1.  .S Y=0 F  S Y=$O(^AUPNVPRV("AD",V,Y)) Q:Y'=+Y!(G)  D
  1.  ..I $P($G(^AUPNVPRV(Y,0)),U)'=R Q
  1.  ..I $P($G(^AUPNVPRV(Y,0)),U,4)'="P" Q
  1.  ..S G=1
  1.  .Q:'G  ;not a visit to this provider
  1.  .S $P(PWH,U,1)=$P(PWH,U,1)+1
  1.  .;is there a yes in phr access field on or before visit date?
  1.  .S A=0,B="" F  S A=$O(^AUPNPAT(P,88,A)) Q:A'=+A!(A>$$VD^APCLV(V))  S B=A
  1.  .I B]"",$P(^AUPNPAT(P,88,B,0),U,2) D  Q  ;meets numerator as had phr access on visit date
  1.  ..S $P(PWH,U,2)=$P(PWH,U,2)+1
  1.  ..S $P(PWH,U,3)=$P(PWH,U,3)_$S($P(PWH,U,3)]"":";",1:"")_"VD: "_$$DATE^APCM1UTL($$VD^APCLV(V))_"-"_"PHR ACCESS YES on "_$$DATE^APCM1UTL(B)
  1.  .S E=$$BD($$VD^APCLV(V),1)
  1.  .;GET DATES OF PRINT AND MAKE SURE 1 IS ON OR BEFORE VALUE IN E
  1.  .S A=0,G=0 F  S A=$O(^APCCDPL(V,1,"B",A)) Q:A'=+A!(G)  D
  1.  ..S B=0 F  S B=$O(^APCCDPL(V,1,"B",A,B)) Q:B'=+B!(G)  D
  1.  ...I $P(A,".")>E Q  ;greater than 1 business days
  1.  ...I $P(A,".")<$$VD^APCLV(V)  ;before visit date??
  1.  ...Q:$P(^APCCDPL(V,1,B,0),U,4)'=1  ;CLINICAL SUMMARY ONLY
  1.  ...;Q:$P(^APCCDPL(V,1,B,0),U,2)'="P"  ;printed only
  1.  ...S G=1
  1.  ...S $P(PWH,U,2)=$P(PWH,U,2)+1
  1.  ...S $P(PWH,U,3)=$P(PWH,U,3)_$S($P(PWH,U,3)]"":";",1:"")_"VD: "_$$DATE^APCM1UTL($$VD^APCLV(V))_"-"_"Document printed on "_$$DATE^APCM1UTL($P(A,"."))
  1.  .Q:G
  1.  .;IF NONE OF THESE CHECK FOR REFUSAL ON VISIT DATE
  1.  .S A=0,G="" F  S A=$O(^AUPNPREF("AC",P,A)) Q:A'=+A!(G)  D
  1.  ..Q:$$GET1^DIQ(9000022,A,.01)'="SNOMED"
  1.  ..Q:$$GET1^DIQ(9000022,A,.03,"I")'=$$VD^APCLV(V)  ;must be refused on visit date
  1.  ..Q:$$GET1^DIQ(9000022,A,1301,"I")'=422735006
  1.  ..S G=1
  1.  .I G D
  1.  ..S $P(PWH,U,2)=$P(PWH,U,2)+1
  1.  ..S $P(PWH,U,3)=$P(PWH,U,3)_$S($P(PWH,U,3)]"":";",1:"")_"VD: "_$$DATE^APCM1UTL($$VD^APCLV(V))_"-"_"Declined CS on "_$$DATE^APCM1UTL($$VD^APCLV(V))
  1.  Q PWH
  1. BD(D,N) ;EP n business days from this date
  1.  NEW O,C,Q,R,T
  1.  S C=0,T=""
  1.  S O=D F  S O=$$FMADD^XLFDT(O,1) Q:C=N  D
  1.  .S Q=$$DOW^XLFDT(O,1)
  1.  .I Q=0 Q
  1.  .I Q=6 Q
  1.  .Q:$D(^HOLIDAY(O))
  1.  .S C=C+1,T=O
  1.  Q T
  1. BDB(D,N) ;EP - 3 business days from this date
  1.  NEW O,C,Q,R,T
  1.  S C=0,T=""
  1.  S O=D F  S O=$$FMADD^XLFDT(O,-1) Q:C=$P(N,"-",2)  D
  1.  .S Q=$$DOW^XLFDT(O,1)
  1.  .I Q=0 Q
  1.  .I Q=6 Q
  1.  .Q:$D(^HOLIDAY(O))
  1.  .S C=C+1,T=O
  1.  Q T