AQAOPOST.m

AQAOPOST ; IHS/ORDC/LJF - POST INIT ;

 ;;1.01;QAI MANAGEMENT;;OCT 05, 1995

 ;

 ;Main driver for QAI postinits.  This rtn installs sample entries for

 ;some of the QAI tables, then calls ^AQAOPOS1.

 ;

1 ; step 1 - install of sample entries

 W !!,"QAI POST-INIT",!!

 W !,"STEP 1 - INSTALL SAMPLE ENTRIES OF SOME QI FILES",!!

 F AQAOI=1:1:3 S X=$P($T(DATA1+AQAOI),";;",2) I ('$O(@X)) D

 .K DIR S DIR(0)="Y",DIR("B")="YES"

 .S DIR("A")="Would you like me to install sample "_$P($T(DATA1+AQAOI),";;",3)_" entries"

 .D ^DIR Q:Y<1

 .;

 .S AQAOX=0,AQAON=$P($T(DATA1+AQAOI),";;",4)

 .F  S AQAOX=$O(^AQAOX(AQAON,AQAOX)) Q:AQAOX=""  D

 ..S X=$G(^AQAOX(AQAON,AQAOX)) Q:X=""

 ..K DIC,DD,DO S DLAYGO=$P($T(DATA1+AQAOI),";;",5)\1

 ..S DIC("DR")=$G(^AQAOX(AQAON,AQAOX,"DR")) Q:DIC("DR")=""

 ..S DIC=$P($P($T(DATA1+AQAOI),";;",2),",")_",",DIC(0)="L" D FILE^DICN

 ..I Y=-1 W !!,"**ERROR** Can't add ",X," to file."

 ;

 ;

NEXT ; go to next rtn for more install procedures

 D ^AQAOPOS1,MAIL

 W !!,"POST-INIT COMPLETED.  Please see notes file for instructions"

 W !,"on what to do next.",!!

 ;

 ;

EXIT ; eoj

 D KILL^AQAOUTIL Q

 ;

MAIL ; -- SUBRTN to send mail message

 NEW AQAOI,AQAO,XMSUB,XMTEXT,XMY,X

 S XMSUB="QAI ENHANCEMENT #1 INSTALLED",XMTEXT="AQAO("

 F AQAOI=1:1:12 S AQAO(AQAOI)=$P($T(MSG+AQAOI),";;",2)

 S X=0

 F  S X=$O(^XUSEC("AQAOZMENU",X)) Q:X=""  S XMY(X)=""

 D ^XMD

 W !!,"Mail message sent to ALL QAI Users."

 Q

 ;

MSG ;;

 ;;*****************************************************************

 ;;                      Congratulations!

 ;;The QAI version 1.01 has just been installed on your computer

 ;;system. There are 2 main improvements. 1) You can now link CHS

 ;;providers to occurrences and 2) you can link your Clinical

 ;;Indicators to the JCAHO Dimensions of Performance.

 ;;*****************************************************************

 ;;

 ;;For your convenience all the changes are documented on-line for 

 ;;you. Use the option "HELP on Using QAI Package" and select choice

 ;;#3 for ENHANCEMENTS. It will tell you everything you wanted to know

 ;;and more.  Have fun!

 ;

 ;

DATA1 ;; data for step 1

 ;;^AQAO(6,0);;ACTION;;6;;9002168.8

 ;;^AQAO(8,0);;FINDING;;8;;9002168.8

 ;;^AQAO1(3,0);;OUTCOME;;13;;9002169.3

AQAOPOST  ; IHS/ORDC/LJF - POST INIT ;

 +1       ;;1.01;QAI MANAGEMENT;;OCT 05, 1995

 +2       ;

 +3       ;Main driver for QAI postinits.  This rtn installs sample entries for

 +4       ;some of the QAI tables, then calls ^AQAOPOS1.

 +5       ;

1         ; step 1 - install of sample entries

 +1        WRITE !!,"QAI POST-INIT",!!

 +2        WRITE !,"STEP 1 - INSTALL SAMPLE ENTRIES OF SOME QI FILES",!!

 +3        FOR AQAOI=1:1:3

               SET X=$PIECE($TEXT(DATA1+AQAOI),";;",2)

               IF ('$ORDER(@X))

                   Begin DoDot:1

 +4                    KILL DIR

                       SET DIR(0)="Y"

                       SET DIR("B")="YES"

 +5                    SET DIR("A")="Would you like me to install sample "_$PIECE($TEXT(DATA1+AQAOI),";;",3)_" entries"

 +6                    DO ^DIR

                       IF Y<1

                           QUIT 

 +7       ;

 +8                    SET AQAOX=0

                       SET AQAON=$PIECE($TEXT(DATA1+AQAOI),";;",4)

 +9                    FOR 

                           SET AQAOX=$ORDER(^AQAOX(AQAON,AQAOX))

                           IF AQAOX=""

                               QUIT 

                           Begin DoDot:2

 +10                           SET X=$GET(^AQAOX(AQAON,AQAOX))

                               IF X=""

                                   QUIT 

 +11                           KILL DIC,DD,DO

                               SET DLAYGO=$PIECE($TEXT(DATA1+AQAOI),";;",5)\1

 +12                           SET DIC("DR")=$GET(^AQAOX(AQAON,AQAOX,"DR"))

                               IF DIC("DR")=""

                                   QUIT 

 +13                           SET DIC=$PIECE($PIECE($TEXT(DATA1+AQAOI),";;",2),",")_","

                               SET DIC(0)="L"

                               DO FILE^DICN

 +14                           IF Y=-1

                                   WRITE !!,"**ERROR** Can't add ",X," to file."

                           End DoDot:2

                   End DoDot:1

 +15      ;

 +16      ;

NEXT      ; go to next rtn for more install procedures

 +1        DO ^AQAOPOS1

           DO MAIL

 +2        WRITE !!,"POST-INIT COMPLETED.  Please see notes file for instructions"

 +3        WRITE !,"on what to do next.",!!

 +4       ;

 +5       ;

EXIT      ; eoj

 +1        DO KILL^AQAOUTIL

           QUIT 

 +2       ;

MAIL      ; -- SUBRTN to send mail message

 +1        NEW AQAOI,AQAO,XMSUB,XMTEXT,XMY,X

 +2        SET XMSUB="QAI ENHANCEMENT #1 INSTALLED"

           SET XMTEXT="AQAO("

 +3        FOR AQAOI=1:1:12

               SET AQAO(AQAOI)=$PIECE($TEXT(MSG+AQAOI),";;",2)

 +4        SET X=0

 +5        FOR 

               SET X=$ORDER(^XUSEC("AQAOZMENU",X))

               IF X=""

                   QUIT 

               SET XMY(X)=""

 +6        DO ^XMD

 +7        WRITE !!,"Mail message sent to ALL QAI Users."

 +8        QUIT 

 +9       ;

MSG       ;;

 +1       ;;*****************************************************************

 +2       ;;                      Congratulations!

 +3       ;;The QAI version 1.01 has just been installed on your computer

 +4       ;;system. There are 2 main improvements. 1) You can now link CHS

 +5       ;;providers to occurrences and 2) you can link your Clinical

 +6       ;;Indicators to the JCAHO Dimensions of Performance.

 +7       ;;*****************************************************************

 +8       ;;

 +9       ;;For your convenience all the changes are documented on-line for 

 +10      ;;you. Use the option "HELP on Using QAI Package" and select choice

 +11      ;;#3 for ENHANCEMENTS. It will tell you everything you wanted to know

 +12      ;;and more.  Have fun!

 +13      ;

 +14      ;

DATA1     ;; data for step 1

 +1       ;;^AQAO(6,0);;ACTION;;6;;9002168.8

 +2       ;;^AQAO(8,0);;FINDING;;8;;9002168.8

 +3       ;;^AQAO1(3,0);;OUTCOME;;13;;9002169.3