Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: AUM14EN

AUM14EN.m

Go to the documentation of this file. 
  1. AUM14EN ;IHS/OIT/NKD - ENVIRONMENT CHECK/PRE/POST-INSTALL FOR ICD 9 CODES FY2014 08/20/13 ; 
  1.  ;;14.0;TABLE MAINTENANCE;;AUG 20,2013;Build 1
  1.  ;
  1.  I '$G(DUZ) W !,"DUZ UNDEFINED OR 0." D SORRY(2) Q
  1.  ;
  1.  I '$L($G(DUZ(0))) W !,"DUZ(0) UNDEFINED OR NULL." D SORRY(2) Q
  1.  ;
  1.  S X=$P(^VA(200,DUZ,0),U)
  1.  W !!,$$CJ^XLFSTR("Hello, "_$P(X,",",2)_" "_$P(X,","),IOM)
  1.  W !!,$$CJ^XLFSTR("Checking Environment for "_$P($T(+2),";",4)_" V "_$P($T(+2),";",3)_".",IOM)
  1.  ;
  1.  S XPDQUIT=0,AUMQUIT=0
  1.  I $$VCHK("XU","8.0",2)
  1.  I $$VCHK("DI","22.0",2)
  1.  ;
  1.  I $$VCHK("AUM","13.0",2)
  1.  I $$VCHK2("BCSV","1.0.3",2)
  1.  ;
  1.  I XPDQUIT D SORRY(XPDQUIT) Q
  1.  ;
  1.  W !!,$$CJ^XLFSTR("ENVIRONMENT OK.",IOM)
  1.  ;
  1.  Q
  1.  ;
  1. SORRY(X) ;
  1.  KILL DIFQ
  1.  S XPDQUIT=X
  1.  W:'$D(ZTQUEUED) *7,!,$$CJ^XLFSTR("Sorry....",IOM),$$DIR^XBDIR("E","Press RETURN")
  1.  Q
  1.  ;
  1. VCHK(AUMPRE,AUMVER,AUMQUIT) ; Check version level
  1.  ;  
  1.  NEW AUMV
  1.  S AUMV=$$VERSION^XPDUTL(AUMPRE)
  1.  W !,$$CJ^XLFSTR("Need at least "_AUMPRE_" v "_AUMVER_"....."_AUMPRE_" v "_AUMV_" Present",IOM)
  1.  I AUMV<AUMVER KILL DIFQ S XPDQUIT=AUMQUIT D SORRY(AUMQUIT) Q 0
  1.  Q 1
  1. VCHK2(AUMPRE,AUMVER,AUMQUIT) ; Check patch level
  1.  NEW AUMV
  1.  S AUMV=$$VERSION^XPDUTL(AUMPRE)
  1.  S PTCH=+$$LAST(AUMPRE,AUMV) S:PTCH=-1 DPTCH="" S:PTCH'=-1 DPTCH="."_PTCH
  1.  W !,$$CJ^XLFSTR("Need at least "_AUMPRE_" v "_AUMVER_"....."_AUMPRE_" v "_AUMV_DPTCH_" Present",IOM)
  1.  I (AUMV<($P(AUMVER,".",1,2))) KILL DIFQ S XPDQUIT=AUMQUIT D SORRY(AUMQUIT) Q 0
  1.  I (AUMV=$P(AUMVER,".",1,2))&(PTCH<$P(AUMVER,".",3)) KILL DIFQ S XPDQUIT=AUMQUIT D SORRY(AUMQUIT) Q 0
  1.  Q 1
  1. PCHK(AUMPAT,AUMQUIT) ; Check specific patch
  1.  N AUMP
  1.  S AUMP=$$PATCH^XPDUTL(AUMPAT)
  1.  W !,$$CJ^XLFSTR("Patch "_AUMPAT_" is "_$S(AUMP<1:"*NOT* ",1:"")_"installed.",IOM)
  1.  I 'AUMP KILL DIFQ S XPDQUIT=AUMQUIT D SORRY(AUMQUIT) Q 0
  1.  Q 1
  1. LAST(PKG,VER) ; EP - returns last patch applied for a Package, PATCH^DATE
  1.  ;        Patch includes Seq # if Released
  1.  N PKGIEN,VERIEN,LATEST,PATCH,SUBIEN
  1.  I $G(VER)="" S VER=$$VERSION^XPDUTL(PKG) Q:'VER -1
  1.  S PKGIEN=$O(^DIC(9.4,"C",PKG,"")) Q:'PKGIEN -1
  1.  S VERIEN=$O(^DIC(9.4,PKGIEN,22,"B",VER,"")) Q:'VERIEN -1
  1.  S LATEST=-1,PATCH=-1,SUBIEN=0
  1.  F  S SUBIEN=$O(^DIC(9.4,PKGIEN,22,VERIEN,"PAH",SUBIEN)) Q:SUBIEN'>0  D
  1.  . I $P(^DIC(9.4,PKGIEN,22,VERIEN,"PAH",SUBIEN,0),U,2)>LATEST S LATEST=$P(^(0),U,2),PATCH=$P(^(0),U)
  1.  . I $P(^DIC(9.4,PKGIEN,22,VERIEN,"PAH",SUBIEN,0),U,2)=LATEST,$P(^(0),U)>PATCH S PATCH=$P(^(0),U)
  1.  Q PATCH_U_LATEST
  1.  ;
  1. RSLT(%,LINE) ; EP - INSTALL MESSAGES
  1.  I $D(LINE) D BMES^XPDUTL(%)
  1.  I '$D(LINE) D MES^XPDUTL(%)
  1.  Q
  1.  ;
  1. PRE ; EP - PRE-INSTALL
  1.  ; RE-XREF ^ICD9
  1.  S AUMK="^ICD9(""BA"")"
  1.  K @AUMK
  1.  S AUMK="^ICD9(""AB"")"
  1.  K @AUMK
  1.  D ^XBFMK
  1.  S DIK="^ICD9("
  1.  S DIK(1)=".01"
  1.  D ENALL^DIK
  1.  ; RE-XREF ^ICD0
  1.  S AUMK="^ICD0(""BA"")"
  1.  K @AUMK
  1.  S AUMK="^ICD0(""AB"")"
  1.  K @AUMK
  1.  D ^XBFMK
  1.  S DIK="^ICD0("
  1.  S DIK(1)=".01"
  1.  D ENALL^DIK
  1.  ; REMOVE PREVIOUS ^AUMDATA
  1.  S CNT=0 F  S CNT=$O(^AUMDATA(CNT)) Q:'CNT  K ^AUMDATA(CNT,0)
  1.  F CNT=3,4 S $P(^AUMDATA(0),"^",CNT)=0
  1.  ;
  1.  Q
  1. POST ; EP - POST-INSTALL
  1.  D UPDATE^AUM141
  1.  Q