Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: AUM15

AUM15.m

Go to the documentation of this file. 
  1. AUM15 ;IHS/OIT/NKD - ENVIRONMENT CHECK/PRE/POST-INSTALL FOR ICD 9 CODES FY2015 09/09/14 ; 
  1.  ;;15.0;TABLE MAINTENANCE;;SEP 09,2014;Build 1
  1.  ;
  1.  I '$G(DUZ) W !,"DUZ UNDEFINED OR 0." D SORRY(2) Q
  1.  I '$L($G(DUZ(0))) W !,"DUZ(0) UNDEFINED OR NULL." D SORRY(2) Q
  1.  ;
  1.  S X=$P(^VA(200,DUZ,0),U)
  1.  W !!,$$CJ^XLFSTR("Hello, "_$P(X,",",2)_" "_$P(X,","),IOM)
  1.  W !!,$$CJ^XLFSTR("Checking Environment for "_$P($T(+2),";",4)_" V "_$P($T(+2),";",3)_$S($L($P($T(+2),";",5))>4:" Patch "_$P($T(+2),";",5),1:"")_".",IOM),!
  1.  ;
  1.  S:'$$VCHK("XU","8.0","1017") XPDQUIT=2
  1.  S:'$$VCHK("XT","7.3","1017") XPDQUIT=2
  1.  S:'$$VCHK("DI","22.0","1017") XPDQUIT=2
  1.  N AUMAICD S AUMAICD=$$VERSION^XPDUTL("AICD"),XPDQUIT=$S(AUMAICD>3.51:2,1:$G(XPDQUIT))
  1.  W !,$$CJ^XLFSTR("Need AICD v3.51.....AICD v"_AUMAICD_" Present"_$S(AUMAICD>3.51:" ***FIX IT***",1:""),IOM)
  1.  S:'$$VCHK("AUM","14.0") XPDQUIT=2
  1.  S:'$$VCHK("BCSV","1.0","3") XPDQUIT=2
  1.  ;
  1.  NEW DA,DIC
  1.  S X="AUM",DIC="^DIC(9.4,",DIC(0)="",D="C"
  1.  D IX^DIC
  1.  I Y<0,$D(^DIC(9.4,"C","AUM")) D
  1.  . W !!,*7,*7,$$CJ^XLFSTR("You Have More Than One Entry In The",IOM),!,$$CJ^XLFSTR("PACKAGE File with an ""AUM"" prefix.",IOM)
  1.  . W !,$$CJ^XLFSTR("One entry needs to be deleted.",IOM)
  1.  . D SORRY(2)
  1.  .Q
  1.  ;
  1.  I $G(XPDQUIT) W !,$$CJ^XLFSTR("FIX IT! Before Proceeding.",IOM),!!,*7,*7,*7 Q
  1.  W !!,$$CJ^XLFSTR("ENVIRONMENT OK.",IOM)
  1.  I '$$DIR^XBDIR("E","","","","","",1) D SORRY(2)
  1.  Q
  1.  ;
  1. SORRY(X) ;
  1.  KILL DIFQ
  1.  S XPDQUIT=X
  1.  W *7,!,$$CJ^XLFSTR("Sorry....FIX IT!",IOM)
  1.  Q
  1.  ;
  1. VCHK(AUMPRE,AUMVER,AUMPAT) ; Check patch level
  1.  N AUMV,AUMP
  1.  S AUMV=$$VERSION^XPDUTL(AUMPRE)
  1.  I (AUMV<AUMVER) K DIFQ D DISP(AUMPRE,AUMVER,$G(AUMPAT),AUMV,$G(AUMP),0) Q 0
  1.  I '$D(AUMPAT) D DISP(AUMPRE,AUMVER,$G(AUMPAT),AUMV,$G(AUMP),1) Q 1
  1.  S AUMP=+$$LAST(AUMPRE,AUMVER)
  1.  I (AUMP<AUMPAT) K DIFQ D DISP(AUMPRE,AUMVER,$G(AUMPAT),AUMVER,$G(AUMP),0) Q 0
  1.  D DISP(AUMPRE,AUMVER,$G(AUMPAT),AUMVER,$G(AUMP),1)
  1.  Q 1
  1. DISP(AUMPRE,AUMVER,AUMPAT,AUMV,AUMP,AUMR) ; Display requirement checking results
  1.  ;
  1.  N AUMS
  1.  S AUMS="Need at least "_$G(AUMPRE)_" v"_$G(AUMVER)_$S($G(AUMPAT)]"":" p"_$G(AUMPAT),1:"")_"....."
  1.  S AUMS=AUMS_$G(AUMPRE)_" v"_$G(AUMV)_$S($G(AUMP)]"":" p"_$G(AUMP),1:"")_" Present"
  1.  S AUMS=AUMS_$S('AUMR:" ***FIX IT***",1:"")
  1.  W !,$$CJ^XLFSTR(AUMS,IOM)
  1.  Q
  1. LAST(PKG,VER) ; EP - returns last patch applied for a Package, PATCH^DATE
  1.  ;        Patch includes Seq # if Released
  1.  N PKGIEN,VERIEN,LATEST,PATCH,SUBIEN
  1.  I $G(VER)="" S VER=$$VERSION^XPDUTL(PKG) Q:'VER -1
  1.  S PKGIEN=$O(^DIC(9.4,"C",PKG,"")) Q:'PKGIEN -1
  1.  S VERIEN=$O(^DIC(9.4,PKGIEN,22,"B",VER,"")) Q:'VERIEN -1
  1.  S LATEST=-1,PATCH=-1,SUBIEN=0
  1.  F  S SUBIEN=$O(^DIC(9.4,PKGIEN,22,VERIEN,"PAH",SUBIEN)) Q:SUBIEN'>0  D
  1.  . I $P(^DIC(9.4,PKGIEN,22,VERIEN,"PAH",SUBIEN,0),U,2)>LATEST S LATEST=$P(^(0),U,2),PATCH=$P(^(0),U)
  1.  . I $P(^DIC(9.4,PKGIEN,22,VERIEN,"PAH",SUBIEN,0),U,2)=LATEST,$P(^(0),U)>PATCH S PATCH=$P(^(0),U)
  1.  Q PATCH_U_LATEST
  1.  ;
  1. PRE ; EP - PRE-INSTALL
  1.  N AUMI
  1.  ; RE-XREF ^ICD9
  1.  D RSLT("ICD Diagnosis file cleanup"),^XBFMK W !
  1.  F AUMI=$NA(^ICD9("AB")),$NA(^ICD9("BA")) K @AUMI
  1.  S DIK="^ICD9(",DIK(1)=".01"
  1.  D ENALL^DIK
  1.  ; RE-XREF ^ICD0
  1.  D RSLT("ICD Operation/Procedure file cleanup"),^XBFMK W !
  1.  F AUMI=$NA(^ICD0("AB")),$NA(^ICD0("BA")) K @AUMI
  1.  S DIK="^ICD0(",DIK(1)=".01"
  1.  D ENALL^DIK
  1.  ; REMOVE PREVIOUS ^AUMDATA
  1.  S AUMI=0 F  S AUMI=$O(^AUMDATA(AUMI)) Q:'AUMI  K ^AUMDATA(AUMI)
  1.  F AUMI=3,4 S $P(^AUMDATA(0),"^",AUMI)=0
  1.  ;
  1.  Q
  1. POST ; EP - POST-INSTALL
  1.  N AUMDUP
  1.  D RSLT($J("",24)_"Resolving duplicate ICD entries",1),RSLT($J("",24)_$$REPEAT^XLFSTR("-",31))
  1.  D RSLT("Scan #1"),MAIN^AUM15DU
  1.  ;
  1.  S AUMDUP=+$O(^XTMP("AUM",""),-1),AUMDUP=+$G(^XTMP("AUM",AUMDUP,"COUNT"))
  1.  I AUMDUP D RSLT("Scan #2"),MAIN^AUM15DU
  1.  ;
  1.  S AUMDUP=+$O(^XTMP("AUM",""),-1),AUMDUP=+$G(^XTMP("AUM",AUMDUP,"COUNT"))
  1.  I AUMDUP D SEARCH^AUM15DU($NA(^TMP("AUM",$J,"SCAN"))) I +$G(^TMP("AUM",$J,"SCAN","COUNT")) D
  1.  . D RSLT($$REPEAT^XLFSTR("*",80),1)
  1.  . D RSLT($G(^TMP("AUM",$J,"SCAN","COUNT"))_" duplicate ICD entries remain!")
  1.  . D RSLT("Contact the OIT Help Desk for assistance")
  1.  . D RSLT($$REPEAT^XLFSTR("*",80))
  1.  ;
  1.  D RSLT($J("",24)_"Performing ICD full table update",1),RSLT($J("",24)_$$REPEAT^XLFSTR("-",32))
  1.  D MAIN^AUM15U
  1.  Q
  1. RSLT(%,LINE) ; EP - INSTALL MESSAGES
  1.  I $D(LINE) D BMES^XPDUTL(%)
  1.  I '$D(LINE) D MES^XPDUTL(%)
  1.  Q
  1.  ;