Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: AUM91ENV

AUM91ENV.m

Go to the documentation of this file. 
  1. AUM91ENV ;IHS/ASDST/DMJ,SDR,GTH - SCB UPDATE FOR FY 2009 ; [ 09/17/2002  12:40 PM ]
  1.  ;;9.1;TABLE MAINTENANCE;**4**;SEP 17,2008
  1.  ;AUM*9.1*4 8.20.2009 IHS/OIT/FCJ MODIFIED INTRO TEXT
  1.  ;
  1.  I '$G(DUZ) W !,"DUZ UNDEFINED OR 0." D SORRY(2) Q
  1.  ;
  1.  I '$L($G(DUZ(0))) W !,"DUZ(0) UNDEFINED OR NULL." D SORRY(2) Q
  1.  ;
  1.  S X=$P(^VA(200,DUZ,0),U)
  1.  W !!,$$CJ^XLFSTR("Hello, "_$P(X,",",2)_" "_$P(X,","),IOM)
  1.  W !!,$$CJ^XLFSTR("Checking Environment for "_$P($T(+2),";",4)_" V "_$P($T(+2),";",3)_".",IOM)
  1.  ;
  1.  I $$VCHK("XU","8.0",2)
  1.  I $$VCHK("DI","22.0",2)
  1.  ;I $$VCHK("AUM","7.1",2)
  1.  I $$VCHK("AUM","9.1",2)  ;aum*9.1*1
  1.  ;
  1.  NEW DA,DIC
  1.  S X="AUM",DIC="^DIC(9.4,",DIC(0)="",D="C"
  1.  D IX^DIC
  1.  I Y<0,$D(^DIC(9.4,"C","AUM")) D
  1.  . W !!,*7,*7,$$CJ^XLFSTR("You Have More Than One Entry In The",IOM),!,$$CJ^XLFSTR("PACKAGE File with an ""AUM"" prefix.",IOM)
  1.  . W !,$$CJ^XLFSTR("One entry needs to be deleted.",IOM)
  1.  . D SORRY(2)
  1.  .Q
  1.  ;
  1.  I $G(XPDQUIT) W !,$$CJ^XLFSTR("FIX IT! Before Proceeding.",IOM),!!,*7,*7,*7 Q
  1.  ;
  1.  W !!,$$CJ^XLFSTR("ENVIRONMENT OK.",IOM)
  1.  D HELP^XBHELP("INTROE","AZHBENV")
  1.  ;
  1.  I $G(XPDENV)=1 D
  1.  . ; The following line prevents the "Disable Options..." and "Move
  1.  . ; Routines..." questions from being asked during the install.
  1.  . S (XPDDIQ("XPZ1"),XPDDIQ("XPZ2"))=0
  1.  . D HELP^XBHELP("INTROI","AZHBENV")
  1.  .Q
  1.  ;
  1.  I '$$DIR^XBDIR("E","","","","","",1) D SORRY(2)
  1.  Q
  1.  ;
  1. SORRY(X) ;
  1.  KILL DIFQ
  1.  S XPDQUIT=X
  1.  W *7,!,$$CJ^XLFSTR("Sorry....FIX IT!",IOM)
  1.  Q
  1.  ;
  1. VCHK(AUMPRE,AUMVER,AUMQUIT) ; Check versions needed.
  1.  ;  
  1.  NEW AUMV
  1.  S AUMV=$$VERSION^XPDUTL(AUMPRE)
  1.  W !,$$CJ^XLFSTR("Need at least "_AUMPRE_" v "_AUMVER_"....."_AUMPRE_" v "_AUMV_" Present",IOM)
  1.  I AUMV<AUMVER KILL DIFQ S XPDQUIT=AUMQUIT D SORRY(AUMQUIT) Q 0
  1.  Q 1
  1.  ;
  1. INTROE ; Intro text during KIDS Environment check.
  1.  ;;This is the update to the standard code book tables.  There are modifications
  1.  ;;and additions to the following files:  Community, State, County, Facility, Tribe,
  1.  ;;Reservation, Clinic Stop, Service Unit, Provider class and Railroad Prefix.  The
  1.  ;;entire Community and County files are being sent.
  1.  ;;
  1.  ;;The install message will report updates and failed updates to the Facility, Tribe, 
  1.  ;;Reservation, Clinic Stop, Service Unit, Provider Class and Railroad Prefix files.
  1.  ;;The failed updates and updates to the Community and County file will be included in
  1.  ;;the install message, but entries that are not updated will not be included in the 
  1.  ;;message.  You will need to refer to the web page IHS Standard Code Book tables for
  1.  ;;a complete list of County and Communities due to the volume of records being sent.
  1.  ;;###
  1.  ;
  1. INTROI ; Intro text during KIDS Install.
  1.  ;;If you run interactively, results will be displayed on your screen,
  1.  ;;and recorded in the entry in the INSTALL file.
  1.  ;;If you queue to TaskMan, remember not to Q to the HOME device.
  1.  ;;###
  1.  ;