Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: AUMSCB

AUMSCB.m

Go to the documentation of this file. 
  1. AUMSCB ;IHS/OIT/NKD - SCB UPDATE ENVIRONMENT CHECK/PRE/POST INSTALL 3/08/2013 ;
  1.  ;;19.0;TABLE MAINTENANCE;**1**;SEP 04,2018;Build 1
  1.  ; 03/12/14 - Removed use of AUMPRE for pre-install, changed to just remove AUMDATA entries
  1.  ; 12/16/14 - Removed old/unused code, added support for future environment checking
  1.  ; 03/11/15 - Modified environment checking display to write to screen
  1.  ; 12/04/17 - Removed confirmation prompt from environment checker
  1.  ;
  1.  I '$G(DUZ) W !,"DUZ UNDEFINED OR 0." D SORRY(2) Q
  1.  ;
  1.  I '$L($G(DUZ(0))) W !,"DUZ(0) UNDEFINED OR NULL." D SORRY(2) Q
  1.  ;
  1.  S X=$P(^VA(200,DUZ,0),U)
  1.  W !!,$$CJ^XLFSTR("Hello, "_$P(X,",",2)_" "_$P(X,","),IOM)
  1.  W !!,$$CJ^XLFSTR("Checking Environment for "_$P($T(+2),";",4)_" V "_$P($T(+2),";",3)_$S($L($P($T(+2),";",5))>4:" Patch "_$P($T(+2),";",5),1:"")_".",IOM),!
  1.  ;
  1.  S:'$$VCHK("XU","8.0") XPDQUIT=2
  1.  S:'$$VCHK("DI","22.0") XPDQUIT=2
  1.  S:'$$PCHK("AUM","18.0","4") XPDQUIT=2
  1.  S:'$$VCHK("AUT","98.1","27") XPDQUIT=2
  1.  ;
  1.  NEW DA,DIC
  1.  S X="AUM",DIC="^DIC(9.4,",DIC(0)="",D="C"
  1.  D IX^DIC
  1.  I Y<0,$D(^DIC(9.4,"C","AUM")) D
  1.  . W !!,*7,*7,$$CJ^XLFSTR("You Have More Than One Entry In The",IOM),!,$$CJ^XLFSTR("PACKAGE File with an ""AUM"" prefix.",IOM)
  1.  . W !,$$CJ^XLFSTR("One entry needs to be deleted.",IOM)
  1.  . D SORRY(2)
  1.  .Q
  1.  ;
  1.  I $G(XPDQUIT) W !,$$CJ^XLFSTR("FIX IT! Before Proceeding.",IOM),!!,*7,*7,*7 Q
  1.  ;
  1.  W !!,$$CJ^XLFSTR("ENVIRONMENT OK.",IOM)
  1.  ;
  1.  I $G(XPDENV)=1 D
  1.  . ; The following line prevents the "Disable Options..." and "Move
  1.  . ; Routines..." questions from being asked during the install.
  1.  . S (XPDDIQ("XPZ1"),XPDDIQ("XPZ2"))=0
  1.  .Q
  1.  ;
  1.  ;I '$$DIR^XBDIR("E","","","","","",1) D SORRY(2)  ;IHS/OIT/NKD AUM*18.0*1 REMOVED CONFIRMATION PROMPT
  1.  Q
  1.  ;
  1. SORRY(X) ;
  1.  KILL DIFQ
  1.  S XPDQUIT=X
  1.  W *7,!,$$CJ^XLFSTR("Sorry....FIX IT!",IOM)
  1.  Q
  1.  ;
  1. VCHK(AUMPRE,AUMVER,AUMPAT) ; Check patch level
  1.  N AUMV,AUMP
  1.  S AUMV=$$VERSION^XPDUTL(AUMPRE)
  1.  I (AUMV<AUMVER) K DIFQ D DISP(AUMPRE,AUMVER,$G(AUMPAT),AUMV,$G(AUMP),0) Q 0
  1.  I '$D(AUMPAT) D DISP(AUMPRE,AUMVER,$G(AUMPAT),AUMV,$G(AUMP),1) Q 1
  1.  S AUMP=+$$LAST(AUMPRE,AUMVER)
  1.  I (AUMP<AUMPAT) K DIFQ D DISP(AUMPRE,AUMVER,$G(AUMPAT),AUMVER,$G(AUMP),0) Q 0
  1.  D DISP(AUMPRE,AUMVER,$G(AUMPAT),AUMVER,$G(AUMP),1)
  1.  Q 1
  1.  ;
  1.  ; IHS/OIT/NKD AUM*15.0*1 ADDED FUTURE SUPPORT FOR GLOBAL/PATCH CHECKING - START NEW CODE
  1. GCHK(AUMGL,AUMMSG) ; Check for global
  1.  Q:'$L($G(AUMGL)) 0
  1.  N AUMS
  1.  S AUMS="Requires "_$S('$L($G(AUMMSG)):AUMGL,1:$G(AUMMSG))_"....."
  1.  S AUMS=AUMS_$S($D(@AUMGL):"Present",1:"Not found ***FIX IT***")
  1.  ;D MES^XPDUTL($$CJ^XLFSTR(AUMS,IOM))  ; IHS/OIT/NKD AUM*15.0*2 WRITE TO SCREEN
  1.  W !,$$CJ^XLFSTR(AUMS,IOM)
  1.  Q $S($D(@AUMGL):1,1:0)
  1.  ;
  1. PCHK(PKG,VER,PAT) ; Check specific patch
  1.  N PKGIEN,VERIEN,PATIEN,AUMS
  1.  S PKG=$G(PKG),VER=$G(VER),PAT=$G(PAT)
  1.  S AUMS="Requires "_PKG_" v"_VER_" p"_PAT_"....."
  1.  D
  1.  . S PKGIEN=+$O(^DIC(9.4,"C",PKG,"")) Q:'PKGIEN
  1.  . S VERIEN=+$O(^DIC(9.4,PKGIEN,22,"B",VER,"")) Q:'VERIEN
  1.  . S PATIEN=+$O(^DIC(9.4,PKGIEN,22,VERIEN,"PAH","B",PAT,""))
  1.  S AUMS=AUMS_$S(+$G(PATIEN):"Present",1:"Not found ***FIX IT***")
  1.  ;D MES^XPDUTL($$CJ^XLFSTR(AUMS,IOM))  ; IHS/OIT/NKD AUM*15.0*2 WRITE TO SCREEN
  1.  W !,$$CJ^XLFSTR(AUMS,IOM)
  1.  Q $S(+$G(PATIEN):1,1:0)
  1.  ; IHS/OIT/NKD AUM*15.0*1 END NEW CODE
  1.  ;
  1. DISP(AUMPRE,AUMVER,AUMPAT,AUMV,AUMP,AUMR) ; Display requirement checking results
  1.  ;
  1.  N AUMS
  1.  S AUMS="Need at least "_$G(AUMPRE)_" v"_$G(AUMVER)_$S($G(AUMPAT)]"":" p"_$G(AUMPAT),1:"")_"....."
  1.  S AUMS=AUMS_$G(AUMPRE)_" v"_$G(AUMV)_$S($G(AUMP)]"":" p"_$G(AUMP),1:"")_" Present"
  1.  S AUMS=AUMS_$S('AUMR:" ***FIX IT***",1:"")
  1.  W !,$$CJ^XLFSTR(AUMS,IOM)
  1.  Q
  1. LAST(PKG,VER) ; EP - returns last patch applied for a Package, PATCH^DATE
  1.  ;        Patch includes Seq # if Released
  1.  N PKGIEN,VERIEN,LATEST,PATCH,SUBIEN
  1.  I $G(VER)="" S VER=$$VERSION^XPDUTL(PKG) Q:'VER -1
  1.  S PKGIEN=$O(^DIC(9.4,"C",PKG,"")) Q:'PKGIEN -1
  1.  S VERIEN=$O(^DIC(9.4,PKGIEN,22,"B",VER,"")) Q:'VERIEN -1
  1.  S LATEST=-1,PATCH=-1,SUBIEN=0
  1.  F  S SUBIEN=$O(^DIC(9.4,PKGIEN,22,VERIEN,"PAH",SUBIEN)) Q:SUBIEN'>0  D
  1.  . I $P(^DIC(9.4,PKGIEN,22,VERIEN,"PAH",SUBIEN,0),U,2)>LATEST S LATEST=$P(^(0),U,2),PATCH=$P(^(0),U)
  1.  . I $P(^DIC(9.4,PKGIEN,22,VERIEN,"PAH",SUBIEN,0),U,2)=LATEST,$P(^(0),U)>PATCH S PATCH=$P(^(0),U)
  1.  Q PATCH_U_LATEST
  1.  ;
  1. PRE ; EP FR KIDS
  1.  ; IHS/OIT/NKD AUM*14.0*2 REMOVE DATA FROM AUMDATA W/O CLEANING UP CONTROL CHARS - START OLD CODE
  1.  ;CLEAN UP CONTROL CHAR AND REMOVE DATA FROM AUMDATA
  1.  ;D START^AUMPRE  ; IHS/OIT/NKD AUM*14.0*2 END OLD CODE - START NEW CODE
  1.  N AUMI
  1.  S AUMI=0 F  S AUMI=$O(^AUMDATA(AUMI)) Q:'AUMI  K ^AUMDATA(AUMI)
  1.  F AUMI=3,4 S $P(^AUMDATA(0),"^",AUMI)=0
  1.  ; IHS/OIT/NKD AUM*14.0*2 END NEW CODE
  1.  Q
  1.  ;
  1. POST ; EP FR KIDS
  1.  K ^TMP("AUM",$J)
  1.  D COUNT
  1.  D POST^AUMSCBD
  1.  K ^TMP("AUM",$J)
  1.  Q
  1.  ;
  1. COUNT ; COUNT THE NUMBER OF ENTRIES FOR EACH TABLE
  1.  N AUMI,AUMT,AUMA,AUMC
  1.  S AUMI=0 F  S AUMI=$O(^AUMDATA(AUMI)) Q:'AUMI  D
  1.  . S (AUMT,AUMA)=""
  1.  . S AUMT=$P(^AUMDATA(AUMI,0),U,2)
  1.  . F AUMC="ADD","INA","DEL","ALL" Q:$L(AUMA)>0  S:$E(AUMT,$L(AUMT)-2,$L(AUMT))=AUMC AUMA=$E(AUMT,$L(AUMT)-2,$L(AUMT)),AUMT=$E(AUMT,1,$L(AUMT)-3)
  1.  . S ^TMP("AUM",$J,"COUNT",AUMT)=$G(^TMP("AUM",$J,"COUNT",AUMT))+1
  1.  Q
  1.  ;