Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: AVA32P12

AVA32P12.m

Go to the documentation of this file. 
  1. AVA32P12 ;IHS/ASDST/GTH - AVA 93.2 PATCH 12 ; [ 02/13/2002   5:15 PM ]
  1.  ;;93.2;VA SUPPORT FILES;**12**;JUL 01, 1993;Build 12
  1.  ;
  1.  ; IHS/ASDST/GTH AVA*93.2*12 02/13/2002
  1.  ;
  1.  I '$G(DUZ) W !,"DUZ UNDEFINED OR 0." D SORRY(2) Q
  1.  ;
  1.  I '$L($G(DUZ(0))) W !,"DUZ(0) UNDEFINED OR NULL." D SORRY(2) Q
  1.  ;
  1.  S X=$P(^VA(200,DUZ,0),U)
  1.  W !!,$$CJ^XLFSTR("Hello, "_$P(X,",",2)_" "_$P(X,","),IOM)
  1.  W !!,$$CJ^XLFSTR("Checking Environment for "_$P($T(+2),";",4)_" V "_$P($T(+2),";",3)_" Patch "_$P($T(+2),";",5)_".",IOM)
  1.  ;
  1.  Q:'$$VCHK("AVA","93.2",2)
  1.  Q:'$$VCHK("DI","21.0",2)
  1.  Q:'$$VCHK("XU","8.0",2)
  1.  ;
  1.  NEW DA,DIC
  1.  S X="AVA",DIC="^DIC(9.4,",DIC(0)="",D="C"
  1.  D IX^DIC
  1.  I Y<0,$D(^DIC(9.4,"C","AVA")) D  Q
  1.  . W !!,*7,*7,$$CJ^XLFSTR("You Have More Than One Entry In The",IOM),!,$$CJ^XLFSTR("PACKAGE File with an ""AVA"" prefix.",IOM)
  1.  . W !,$$CJ^XLFSTR("One entry needs to be deleted.",IOM)
  1.  . W !,$$CJ^XLFSTR("FIX IT! Before Proceeding.",IOM),!!,*7,*7,*7
  1.  . D SORRY(2)
  1.  . I $$DIR^XBDIR("E")
  1.  .Q
  1.  W !,$$CJ^XLFSTR("No 'AVA' dups in PACKAGE file",IOM)
  1.  ;
  1.  I $G(XPDENV)=1 D
  1.  . ; The following line prevents the "Disable Options..." and "Move
  1.  . ; Routines..." questions from being asked during the install.
  1.  . S (XPDDIQ("XPZ1"),XPDDIQ("XPZ2"))=0
  1.  .Q
  1.  ;
  1.  I '(DUZ(0)["@") W !,"The dd updates require an '@' in your DUZ(0).",!,"Everything else looks OK!" D SORRY(2) Q
  1.  ;
  1.  W !!,$$CJ^XLFSTR("ENVIRONMENT OK.",IOM)
  1.  ;
  1.  I '$$DIR^XBDIR("E","","","","","",1) D SORRY(2) Q
  1.  Q
  1.  ;
  1. SORRY(X) ;
  1.  KILL DIFQ
  1.  S XPDQUIT=X
  1.  W:'$D(ZTQUEUED) *7,!,$$CJ^XLFSTR("Sorry....",IOM),$$DIR^XBDIR("E","Press RETURN")
  1.  Q
  1.  ;
  1. VCHK(AVAPRE,AVAVER,AVAQUIT) ; Check versions needed.
  1.  ;  
  1.  NEW AVAV
  1.  S AVAV=$$VERSION^XPDUTL(AVAPRE)
  1.  W !,$$CJ^XLFSTR("Need at least "_AVAPRE_" v "_AVAVER_"....."_AVAPRE_" v "_AVAV_" Present",IOM)
  1.  I AVAV<AVAVER KILL DIFQ S XPDQUIT=AVAQUIT W *7,!,$$CJ^XLFSTR("Sorry....",IOM) S AVAV=$$DIR^XBDIR("E","Press RETURN") Q 0
  1.  Q 1
  1.  ;
  1. PRE ;EP - From KIDS.
  1.  Q
  1.  D BMES^XPDUTL("Beginning pre-install routine (PRE^AVA32P12).")
  1.  D BMES^XPDUTL("Pre-install routine is complete.")
  1.  Q
  1.  ;
  1. POST ;EP - From KIDS.
  1.  NEW AVA
  1.  D BMES^XPDUTL("Beginning post-install routine (POST^AVA32P12).")
  1.  ;
  1.  D BMES^XPDUTL("Changing sub-file dictionary number in the 9999999.18 multiple...")
  1.  D SFDD
  1.  ;
  1.  D BMES^XPDUTL("Delivering AVA*93.2*12 install message to select users...")
  1.  D MAIL
  1.  ;
  1.  D BMES^XPDUTL("Post-install routine is complete.")
  1.  Q
  1.  ;
  1. SFDD ;
  1.  NEW I,P
  1.  S I=0,P=$P(^DD(200,9999999.18,0),U,2)
  1.  F  S I=$O(^VA(200,I)) Q:'(I=+I)  I $D(^VA(200,I,9999999.18,0)) S $P(^(0),U,2)=P
  1.  Q
  1.  ;
  1. MAIL ; Send install mail message.
  1.  NEW DIFROM,XMSUB,XMDUZ,XMTEXT,XMY
  1.  KILL ^TMP("AVAP12MS",$J)
  1.  S ^TMP("AVAP12MS",$J,1)=" --- AVA v 93.2, Patch 12, has been installed into this uci ---"
  1.  S %=0
  1.  F  S %=$O(^XTMP("XPDI",XPDA,"BLD",XPDBLD,1,%)) Q:'%   S ^TMP("AVAP12MS",$J,(%+1))=" "_^(%,0)
  1.  S XMSUB=$P($P($T(+1),";",2)," ",4,99),XMDUZ=$S($G(DUZ):DUZ,1:.5),XMTEXT="^TMP(""AVAP12MS"",$J,",XMY(1)="",XMY(DUZ)=""
  1.  F %="XUMGR","XUPROG","XUPROGMODE" D SINGLE(%)
  1.  D ^XMD
  1.  KILL ^TMP("AVAP12MS",$J)
  1.  Q
  1.  ;
  1. SINGLE(K) ; Get holders of a single key K.
  1.  NEW Y
  1.  S Y=0
  1.  Q:'$D(^XUSEC(K))
  1.  F  S Y=$O(^XUSEC(K,Y)) Q:'Y  S XMY(Y)=""
  1.  Q
  1.  ;