Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: AVAP11

AVAP11.m

Go to the documentation of this file. 
  1. AVAP11 ;IHS/ASDST/GTH - DISABLE AD XREF ON FILE 4 ; [ 05/08/1999  9:20 AM ]
  1.  ;;93.2;VA SUPPORT FILES;**11**;JUL 01, 1993;Build 12
  1.  ;
  1.  I '$G(DUZ) W !,"DUZ UNDEFINED OR 0." D SORRY Q
  1.  ;
  1.  I '$L($G(DUZ(0))) W !,"DUZ(0) UNDEFINED OR NULL." D SORRY Q
  1.  ;
  1.  D HOME^%ZIS,DT^DICRW
  1.  ;
  1.  S X=$T(+2)
  1.  W !,$$C^XBFUNC("--  "_$P(X,";",4)_" v "_$P(X,";",3)_" Patch "_$P(X,"*",3)_"  --")
  1.  ;
  1.  S X=$P(^VA(200,DUZ,0),U)
  1.  W !!,$$C^XBFUNC("Hello, "_$P(X,",",2)_" "_$P(X,",")),!!,$$C^XBFUNC("Checking Environment for Version "_$P($T(+2),";",3)_" of "_$P($T(+2),";",4)_".")
  1.  ;
  1.  S X="AVA",DIC="^DIC(9.4,",DIC(0)="",D="C"
  1.  D IX^DIC
  1.  I Y<0 D  Q
  1.  . W !!,$$C^XBFUNC("You Have More Than One Entry In The")
  1.  . W !,$$C^XBFUNC("PACKAGE File with an ""AVA"" prefix.")
  1.  . W !,$$C^XBFUNC("One entry needs to be deleted.")
  1.  . W !,$$C^XBFUNC("Please FIX IT! Before Proceeding."),!
  1.  . D SORRY
  1.  .Q
  1.  ;
  1.  S DA=+Y
  1.  W !!,$$C^XBFUNC("AVA version '"_$G(^DIC(9.4,DA,"VERSION"))_"' currently installed")
  1.  ;
  1.  S X=$G(^DD("VERSION"))
  1.  W !!,$$C^XBFUNC("Need at least FileMan 21.....FileMan "_X_" Present")
  1.  I X<21 D SORRY Q
  1.  ;
  1.  S X=$G(^DIC(9.4,$O(^DIC(9.4,"C","XU",0)),"VERSION"))
  1.  W !!,$$C^XBFUNC("Need at least Kernel 8.....Kernel "_X_" Present")
  1.  I X<8 D SORRY Q
  1.  ;
  1.  W !!,$$C^XBFUNC("ENVIRONMENT OK.")
  1.  ;
  1.  I '$$DIR^XBDIR("E","","","","","",1) Q
  1.  ;
  1.  D HELP("INTRO")
  1.  ;
  1.  G EOJ:'$$DIR^XBDIR("YO","Run patch 11","N")
  1.  ;
  1.  D WAIT^DICD
  1.  W !,"Disabling dd..."
  1.  ;
  1. UPDATEDD ;EP - From A9AVA11, for RPI, non-interactive update.
  1.  NEW AVAWRITE,DA
  1.  S AVAWRITE='$D(ZTQUEUED)
  1.  F %=1:1 Q:'$D(^DD(4,.01,1,%))  I $P(^(%,0),"^",2)="AD" S DA=% Q
  1.  I '$D(DA) W:AVAWRITE !,"X-REF 'AD' not found in File 4, Field .01.",!,"That's OK!!" G EOJ
  1.  ;
  1.  W:AVAWRITE !,"Disabling SET of x-ref 'AD'..."
  1.  I $E(^DD(4,.01,1,DA,1),1,4)'="Q  ;" S ^(1)="Q  ;"_^(1)
  1.  W:AVAWRITE "Done disabling SET."
  1.  ;
  1.  W:AVAWRITE !,"Disabling KILL of x-ref 'AD'..."
  1.  I $E(^DD(4,.01,1,DA,2),1,4)'="Q  ;" S ^(2)="Q  ;"_^(2)
  1.  W:AVAWRITE "Done disabling KILL."
  1.  ;
  1.  S ^DD(4,.01,"DT")=$$DT^XLFDT
  1.  KILL DA ;
  1.  W:AVAWRITE !,"dd update complete."
  1.  W:AVAWRITE !!,"Patch 11 to AVA 93.2 is complete.",!
  1.  ;
  1.  D MAIL^XBMAIL("XUMGR-XUPROGMODE","INTRO^AVAP11")
  1.  ;
  1. EOJ ;     
  1.  KILL DIC,DIR,DIE,DA,DR,X,Y
  1.  Q
  1.  ;
  1. INTRO ;
  1.  ;;This is Patch 11 to AVA 93.2.
  1.  ;;  
  1.  ;;The 'AD' x-ref on file 4, field .01, will be disabled.  The 'AD'
  1.  ;;x-ref was added by the VA to keep the LOCATION file in sync with
  1.  ;;file 4 (INSTITUTION) when additions were made to file 4 by the VA's
  1.  ;;PCE software.  This is unneeded by IHS since all additions of
  1.  ;;locations are made into the LOCATION file, which is DINUM'd to
  1.  ;;file 4.  Unfortunately, the 'AD' x-ref on file 4 causes an
  1.  ;;<UNDEF> to occur when IHS attempts to add locations into the
  1.  ;;LOCATION file.
  1.  ;; 
  1.  ;;This patch disables the 'AD' x-ref on file 4, field .01.
  1.  ;;  
  1.  ;;###
  1.  ;
  1. HELP(L) ;EP - Display text at label L.
  1.  W !
  1.  F %=1:1 W !?4,$P($T(@L+%),";",3) Q:$P($T(@L+%+1),";",3)="###"
  1.  Q
  1.  ;
  1. SORRY ;
  1.  W *7,!,$$C^XBFUNC("Sorry....")
  1.  D EOJ
  1.  Q
  1.  ;