Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: AZXDFRDO

AZXDFRDO.m

Go to the documentation of this file. 
  1. ABMDFRDO ; IHS/ASDST/DMJ - Re-Print Selected Bills ;    [ 10/11/2002  10:54 AM ]
  1.  ;;2.5;IHS 3P BILLING SYSTEM;**2**;APR 05, 2002
  1.  ;Original;TMD;02/21/96 12:13 PM
  1.  ;
  1.  ; IHS/ASDS/LSL - 06/29/00 - V2.4 Patch 2 - NOIS XAA-0600-200091 V2.4
  1.  ;     Modified to allow reprint of new export modes (13,15,17)
  1.  ;
  1.  ; IHS/ASDS/LSL - 05/04/01 - V2.4 Patch 5 - NOIS HQW-0401-100014
  1.  ;     Modified to allow reprint of all new electronic exports for
  1.  ;     UB-92's and HCFA-1500's regardless of when they are added.
  1.  ;     Check UB's only once in code instead of 3 times.
  1.  ;
  1.  K ABMY,ABMP
  1.  S ABMP("XMIT")=0
  1.  S ABMY("TOT")="0^0^0"
  1.  W !!,"Re-Print Bills for:"
  1.  K DIR
  1.  S DIR(0)="SO^1:SELECTIVE BILL(S);2:ALL BILLS FOR AN EXPORT BATCH;3:UNPAID BILLS"
  1.  S DIR("A")="Select Desired Option"
  1.  D ^DIR
  1.  K DIR
  1.  G XIT:$D(DIRUT)!$D(DIROUT),SEL:Y=1,UNPD:Y=3
  1.  ;
  1. BATCH ;
  1.  W !
  1.  K DIC
  1.  S DIC="^ABMDTXST(DUZ(2),"
  1.  S DIC(0)="AEMQ"
  1.  S DIC("A")="Select EXPORT BATCH (Date): "
  1.  D ^DIC
  1.  K DIC("A")
  1.  G XIT:X=""!$D(DTOUT)!$D(DUOUT),BATCH:+Y<1
  1.  S (ABMY("BATCH"),ABMP("XMIT"))=+Y
  1.  I $P(^ABMDTXST(DUZ(2),+Y,0),U,2) S ABMY("FORM")=$P(^(0),U,2)_U_$P($G(^ABMDEXP($P(^(0),U,2),0)),U)
  1.  E  S ABMY("FORM")=$S($P(^ABMDTXST(DUZ(2),ABMY("BATCH"),0),U,2)="U":1,1:2)_U_$S($P(^(0),U,2)="U":"UB-82",1:"HCFA-1500A")
  1.  G ZIS
  1.  ;
  1. SEL ;
  1.  W !!
  1.  K DIC
  1.  S DIC="^ABMDBILL(DUZ(2),"
  1.  S DIC(0)="QZEAM"
  1.  S ABMY=$G(ABMY)+1
  1.  S ABM("E")=$E(ABMY,$L(ABMY))
  1.  S DIC("A")="Select "_ABMY_$S(ABMY>3&(ABMY<21):"th",ABM("E")=1:"st",ABM("E")=2:"nd",ABM("E")=3:"rd",1:"th")_" BILL to Re-Print: "
  1.  S DIC("S")="I $P(^(0),U)'=+^(0),""BTCP""[$P(^(0),""^"",4),$P(^(0),""^"",6)"
  1.  S:ABMY>1 DIC("S")=DIC("S")_",$P(ABMY(""FORM""),""^"",1)[$P(^(0),""^"",6)"
  1.  D BENT^ABMDBDIC
  1.  G XIT:$D(DUOUT)!$D(DTOUT)
  1.  I '$G(ABMP("BDFN")) G ZIS:ABMY>1,XIT
  1.  D CKMULT
  1.  I '$G(ABMP("BDFN")) S ABMY=ABMY-1 G SEL
  1.  S ABMY(ABMP("BDFN"))=""
  1.  G SEL:ABMY>1
  1.  S ABMY("FORM")=$P(^ABMDBILL(DUZ(2),ABMP("BDFN"),0),U,6)_U_$P($G(^ABMDEXP($P(^(0),U,6),0)),U)
  1.  G SEL
  1.  ;
  1. UNPD ;UN-PAID BILLS
  1.  D ^ABMDBRUN
  1.  S ABMY("TOT")="0^0^0"
  1.  W !!,"For the parameters specified, the"
  1.  W !,"           Number of Bills to Reprint: ",ABMP("CNT")
  1.  I '$O(ABMY(0)) W *7 G XIT
  1.  ;
  1. ZIS ;
  1.  S:$P(ABMY("FORM"),U,2)["UB-92-E" ABMY("FORM")="11^UB-92"
  1.  S:$P(ABMY("FORM"),U,2)["HCFA-1500-E" ABMY("FORM")="14^HCFA-1500 Y2K"
  1.  I +ABMY("FORM")=2,$P($G(^ABMDPARM(DUZ(2),1,2)),9)=2 D  G XIT:$D(DIRUT)
  1.  .W !!,"Forms Previously Printed on Old HCFA-1500.",!!
  1.  .K DIR
  1.  .S DIR(0)="Y"
  1.  .S DIR("B")="Y"
  1.  .S DIR("A")="Want to print the New Version of the HCFA-1500 (Y/N)"
  1.  .D ^DIR
  1.  .I Y S ABMY("FORM")=3_U_$P(^ABMDEXP(3,0),U)
  1.  S ABMP("EXP")=+ABMY("FORM")
  1.  W !!?15,"(NOTE: "
  1.  I $P($G(^ABMDEXP(ABMP("EXP"),1)),U,4) W "Plain Paper needs"
  1.  E  W $P(ABMY("FORM"),U,2)," forms need"
  1.  W " to be loaded in the printer.)"
  1.  W !!
  1.  S %ZIS("A")="Output DEVICE: "
  1.  S %ZIS="NPQ"
  1.  S %ZIS("B")=""
  1.  D ^%ZIS
  1.  G XIT:POP
  1.  I IO'=IO(0) D QUE2,HOME^%ZIS Q
  1.  I $D(IOPAR) S %ZIS("IOPAR")=IOPAR
  1.  U IO(0)
  1.  ;W !!,"Printing..."  ;*** TESTING - AEF *** COMMENTED OUT AND REPLACED BY LINE BELOW
  1.  I $E(IOST)="C" W !!,"Printing..." ;*** TESTING - AEF *** WRITE ONLY TO A TERMINAL SCREEN
  1.  S IOP=ION
  1.  D ^%ZIS
  1.  G ENT
  1.  ;
  1. QUE2 ;
  1.  I IO=IO(0) W !,"Cannot Queue to Screen or Slave Printer!",! G ZIS
  1.  S ZTRTN="TSK^ABMDFRDO"
  1.  S ZTDESC="3P Re-Print of Selective Bill."
  1.  F ABM="ZTRTN","ZTDESC","ABMP(","ABMY(" S ZTSAVE(ABM)=""
  1.  D ^%ZTLOAD
  1.  I $D(ZTSK) W !,"(Job Queued, Task Number: ",ZTSK,")"
  1.  G OUT
  1.  ;
  1. TSK ; Taskman Entry Point
  1.  S ABMP("Q")=""
  1.  ;
  1. ENT ;
  1.  I '$D(ABMY("BATCH")) D  G OUT
  1.  .S ABMY=0
  1.  .F  S ABMY=$O(ABMY(ABMY)) Q:'ABMY  D
  1.  ..S ABMP("BDFN")=ABMY
  1.  ..D FORMS
  1.  S ABMY=0
  1.  F  S ABMY=$O(^ABMDBILL(DUZ(2),"AX",ABMY("BATCH"),ABMY)) Q:'ABMY  D
  1.  .; Quit if bill status is Reviewed, Approved, or Cancelled
  1.  .Q:"RAX"[$P($G(^ABMDBILL(DUZ(2),ABMY,0)),U,4)
  1.  .S ABMP("BDFN")=ABMY
  1.  .D FORMS
  1.  G OUT
  1.  ;
  1. FORMS ; Reprint Forms
  1.  K ABMP("PAYED")  ; LSM/12-13-96
  1.  I ABMP("EXP")>2 D @("ENT^ABMDF"_+ABMY("FORM")) Q
  1.  ;
  1. UB82 ;
  1.  I +ABMY("FORM")=1 D  Q
  1.  .D ENT^ABMDF1,^ABMDF1X
  1.  .D:$D(ABMR)=10 UB82^ABMDF1
  1.  ;
  1. HCFA ;
  1.  D ENT^ABMDF2
  1.  I +$O(ABMR("")) S ABMR("MORE")=""
  1.  D ^ABMDF2X
  1.  D:+$O(ABMR("")) HCFA^ABMDF2
  1.  Q
  1.  ;
  1. OUT ;
  1.  D ^%ZISC
  1.  ;
  1. XIT ;
  1.  D WTOT^ABMDFUTL:$G(ABMY("TOT"))
  1.  K ABMP,ABMY,DIQ
  1.  Q
  1.  ;
  1. CKMULT ; check if form is used for multiple bills  
  1.  I $P($G(^ABMDEXP($P(^ABMDBILL(DUZ(2),ABMP("BDFN"),0),U,6),1)),U,3) D
  1.  .W !!,*7,"Bill Number "
  1.  .W $P(^ABMDBILL(DUZ(2),ABMP("BDFN"),0),U)
  1.  .W " was exported on a "
  1.  .W $P(^ABMDEXP($P(^ABMDBILL(DUZ(2),ABMP("BDFN"),0),U,6),0),U)
  1.  .W " form. Since this form may"
  1.  .W !,"include multiple bills, a single bill can not be individually reprinted."
  1.  .W !,"Thus, to reprint the bill you must reprint the entire export batch."
  1.  .K ABMP("BDFN")
  1.  Q