Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: AZZDACK

AZZDACK.m

Go to the documentation of this file. 
  1. AZZDACK ; CHECK DATA FOR ALL REG PATIENTS AT SELECTED SITE;[ 01/02/90  1:50 PM ]
  1.  ; Mike Remillard, ISC/BAO
  1.  ; IHS/MFD changed description- active registration patients
  1. START ;
  1.  K ^AZZDA D ^AUKVAR,^%AUCLS
  1.  W ?6,"* * CHECK ALL ACTIVE PATIENTS FOR MISSING OR INVALID REG DATA * *"
  1.  ;-----> ASK LOCATION.
  1.  W !!!!,"Select a Location for the patient records you wish to scan.",!
  1.  S:'$D(IOSL) IOSL=24
  1.  S DIC="^AUTTLOC(",DIC(0)="QEMA",DIC("A")="Location: "
  1.  D ^DIC Q:Y=-1
  1.  S DUZ(2)=$P(Y,U),(AZZDA("ALL"),AZZDA("HERE"),AZZDA("BAD"),DFN)=0
  1.  S AZZDA("SITE")=$P(^DIC(4,DUZ(2),0),U)
  1.  D PROMPT Q:QQ=U
  1. SCAN ;-----> BEGIN SCAN.
  1.  D VARS,HEADER1 Q:QQ="^"  W !!
  1.  F  S DFN=$O(^DPT(DFN)) Q:'DFN  S AZZDA("ALL")=AZZDA("ALL")+1 D
  1.  .W:'(AZZDA("ALL")#1500) !!?12,"  *** STILL SCANNING ",AZZDA("SITE")," ***  ",!!
  1.  .;-----> CHECK IF DECEASED.
  1.  .I $D(^DPT(DFN,.35)) W "-" Q
  1.  .;-----> CHECK IF REG'D AT THIS SITE; ALSO, QUIT IF FILE IS INACTIVE.
  1.  .I $D(^AUPNPAT(DFN,41,DUZ(2))) Q:$P(^(DUZ(2),0),U,3)  S AZZDA("HERE")=AZZDA("HERE")+1 D ^AGDATCK W:AG("DTOT")=0 "." D:AG("DTOT")>0 STORE Q
  1.  .W "-"
  1.  D PROMPT1 D:QQ'=U TOTALS
  1.  D PROMPT D:QQ'=U PRINT
  1. EXIT ;
  1.  X ^%ZIS("C")
  1.  K AG,AZZDA,X,I,QQ,^AZZDA
  1.  Q
  1. STORE ;
  1.  ;-----> STORE DATA IN GLOBAL, TOTALS IN LOCAL VARIABLES.
  1.  S AZZDA("BAD")=AZZDA("BAD")+1 W "X"
  1.  S ^AZZDA(DFN)=$P(^DPT(DFN,0),"^",1)
  1.  S $P(^AZZDA(DFN),U,2)=$P(^AUPNPAT(DFN,41,DUZ(2),0),"^",2)
  1.  F I=1:1:12 S:$D(AG("ER",I)) $P(^AZZDA(DFN),U,(I+2))=1,AZZDA("AG",I)=AZZDA("AG",I)+1
  1.  Q
  1. TOTALS ;
  1.  ;-----> PRINT TOTAL STATISTICS ON SCAN FOR THIS LOCATION.
  1.  W !! S %ZIS="",%ZIS("A")="Select DEVICE to print statistics: " D ^%ZIS Q:POP  U IO
  1.  D HEADER3
  1.  F I=1:1:12 D:$Y>(IOSL-7) PROMPT Q:QQ=U  D:$Y>(IOSL-7) HEADER3 W:AZZDA("AG",I) !!?5,"Patients with ",AG(I),":",?55,$J(AZZDA("AG",I),10)
  1.  W !!,"   ----------------------------------------------",?55,"-----------"
  1.  D:$Y>(IOSL-8) PROMPT Q:QQ=U  D:$Y>(IOSL-8) HEADER3
  1.  W !?5,"Total patients at ",AZZDA("SITE")
  1.  W !?5,"with Missing or Invalid data: ",?55,$J(AZZDA("BAD"),10)
  1.  W !!?5,"Total patients in this database"
  1.  W !?5,"registered at ",AZZDA("SITE"),": ",?55,$J(AZZDA("HERE"),10)
  1.  W !!?5,"Total patients in the database: ",?55,$J(AZZDA("ALL"),10)
  1.  X ^%ZIS("C")
  1.  Q
  1. PRINT ;
  1.  ;-----> PRINT MISSING/INVALID DATA FOR EACH INDIVIDUAL PATIENT.
  1.  W !! S %ZIS="",%ZIS("A")="Select DEVICE to print individual errors: " D ^%ZIS Q:POP  U IO
  1.  S DFN=0 D HEADER2
  1.  F  S DFN=$O(^AZZDA(DFN)) Q:'DFN  D:$Y>(IOSL-10) PROMPT Q:QQ=U  D:$Y>(IOSL-10) HEADER2 D
  1.  .W !!,"PATIENT: ",$P(^AZZDA(DFN),U),!
  1.  .W "CHART #: ",$P(^AUPNPAT(DFN,41,DUZ(2),0),"^",2)
  1.  .W " at ",AZZDA("SITE")
  1.  .W !!?5,"Missing/Invalid data:"
  1.  .F I=1:1:12 W:$P(^AZZDA(DFN),U,(I+2)) ?28,"** ",AG(I),!
  1.  D:QQ'=U PROMPT
  1.  W @IOF X ^%ZIS("C")
  1.  Q
  1. VARS ;
  1.  ;-----> SET UP NECESSARY LOCAL VARIABLES.
  1.  S AG(1)="invalid NAME entry",AG(2)="invalid CHART NUMBER",AG(3)="missing DATE OF BIRTH",AG(4)="invalid SEX entry",AG(5)="missing TRIBE entry"
  1.  S AG(6)="missing INDIAN QUANTUM",AG(7)="missing CURRENT COMMUNITY",AG(8)="missing BENEFICIARY entry",AG(9)="invalid ELIGIBILITY entry"
  1.  S AG(10)="patient not eligible for BIC",AG(11)="missing SOCIAL SECURITY NUMBER",AG(12)="OLD (unused) TRIBE still use"
  1.  F I=1:1:12 S AZZDA("AG",I)=0
  1.  Q
  1. PROMPT ;
  1.  I IOSL>24 S QQ="" Q
  1.  F  W ! Q:$Y>17
  1. PROMPT1 R !!?23,"Press <return> to continue. ",QQ:DTIME
  1.  Q
  1. HEADER1 ;
  1.  D ^%AUCLS W "During the scanning processes the following symbols will be displayed:"
  1.  W !!?3,"""X"" = Patients with missing/invalid data."
  1.  W !?3,"""."" = Patients registered with correct data."
  1.  W !?3,"""-"" = Patients in the database not registered at ",$E(AZZDA("SITE"),1,28)
  1.  D PROMPT1 Q:QQ="^"
  1.  W !!!!?6,"* * *   SCANNING FOR PATIENTS WITH MISSING OR INVALID DATA   * * *",!,?22,"AT ",AZZDA("SITE")
  1.  Q
  1. HEADER2 ;
  1.  W @IOF,!?8,"* * *   PATIENTS WITH MISSING OR INVALID REQUIRED DATA   * * *",!,?22,"AT ",AZZDA("SITE"),!! Q
  1. HEADER3 ;
  1.  W @IOF,?6,"* * *   STATISTICS ON PATIENTS WITH MISSING OR INVALID DATA   * * *",!,?22,"AT ",AZZDA("SITE"),!! Q