Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BAREITDN

BAREITDN.m

Go to the documentation of this file. 
  1. BAREITDN ; IHS/SD/SDR - EDIT COLLECTION BATCH/ITEMS JAN 15,1997 ;04/10/2008
  1.  ;;1.8;IHS ACCOUNTS RECEIVABLE;**4,23**;OCT 26, 2005
  1.  ; New routine in bar*1.8*4 for DD item 4.1.5.4
  1.  ;
  1.  Q
  1.  ;
  1. EN ;EP
  1.  W !!,"NOTE: Do this option only when posting is not being done.  Regular"
  1.  W !,"posting locks the A/R Transactions file and doesn't allow other edits"
  1.  W !,"to A/R Transactions.",!!
  1.  ;
  1. PICK I $D(BARLIST) D CLEAR^VALM1
  1.  S DIC=$$DIC^XBDIQ1(90050.01)
  1.  S DIC(0)="AEQM"
  1.  D ^DIC
  1.  I Y'>0 G EXIT
  1.  S BARBLDA=+Y
  1.  ; -------------------------------
  1. LIST W !!!,"#",?24,"TRANS"
  1.  W !,"#",?4,"TRANSACTION DT/TM"
  1.  W ?24,"TYPE",?32,"TDN"
  1.  W ?45,"AMOUNT",?56,"BATCH/Item",!
  1.  F B=1:1:80 W "-"
  1.  ;
  1.  S BARTRDA=0,BARCNT=0
  1.  K BARLIST
  1.  F  S BARTRDA=$O(^BARTR(DUZ(2),"AC",BARBLDA,BARTRDA)) Q:'BARTRDA  D
  1.  .S BARTTYP=$$GET1^DIQ(90050.03,BARTRDA_",",101,"E")
  1.  .Q:BARTTYP'="PAYMENT"  ;only allow edit of payments
  1.  .S BARTDTTM=$$TDT^BARDUTL($P($G(^BARTR(DUZ(2),BARTRDA,0)),U))
  1.  .S BARCRD=$$GET1^DIQ(90050.03,BARTRDA_",",2,"E")
  1.  .S BARDEB=$$GET1^DIQ(90050.03,BARTRDA_",",3,"E")
  1.  .S BARBATCH=$P($G(^BARTR(DUZ(2),BARTRDA,0)),U,14)
  1.  .S BARITEM=$P($G(^BARTR(DUZ(2),BARTRDA,0)),U,15)
  1.  .;
  1.  .S BARTDN=""
  1.  .I $P($G(^BARTR(DUZ(2),BARTRDA,1)),U,11) S BARTDN=$P(^(1),U,11)
  1.  .;Transaction TDN
  1.  .I BARTDN="",$P($G(^BARTR(DUZ(2),BARTRDA,0)),U,17) S BARTDN=$P(^(0),U,17)
  1.  .;item TDN
  1.  .I BARTDN="",$P($G(^BARCOL(DUZ(2),BARBATCH,1,BARITEM,0)),U,20) S BARTDN=$P(^(0),U,20)
  1.  .;batch TDN
  1.  .I BARTDN="",$P($G(^BARCOL(DUZ(2),BARBATCH,0)),U,28) S BARTDN=$P(^(0),U,28)
  1.  .;
  1.  .S BARCNT=+$G(BARCNT)+1
  1.  .S BARLIST(BARCNT)=BARTRDA_"^"
  1.  .;
  1.  .W !,$J(BARCNT_".","3R"),?4,BARTDTTM
  1.  .W ?24,BARTTYP
  1.  .W ?32,BARTDN
  1.  .W ?45,$J($FN($S($G(BARCRD):-BARCRD,1:$G(BARDEB)),",",2),"9R")
  1.  .W:+BARBATCH'=0 ?56,$E($P($G(^BARCOL(DUZ(2),BARBATCH,0)),U)_"-"_BARITEM,1,23)
  1.  ;
  1. SELECT W !!
  1.  K DIR,DIC,DIE,DR,DA,X,Y
  1.  S DIR(0)="LO^1:"_BARCNT
  1.  S DIR("A")="Select A/R BILL TRANSACTION: "
  1.  D ^DIR K DIR
  1.  I $D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT) G PICK
  1.  S BARSEL=+Y
  1.  W !!
  1.  D EDIT
  1.  Q
  1.  ;
  1. EDIT ;
  1.  S BARENTRY=$P(BARLIST(BARSEL),U)
  1.  W !!,"Editing transaction: ",$$TDT^BARDUTL($P($G(^BARTR(DUZ(2),BARENTRY,0)),U))
  1.  S BARACCT=$$GET1^DIQ(90050.03,BARENTRY_",",6,"E")
  1.  S BARTTYP=$$GET1^DIQ(90050.03,BARENTRY_",",101,"E")
  1.  S BARCRD=$$GET1^DIQ(90050.03,BARENTRY_",",2,"E")
  1.  S BARDEB=$$GET1^DIQ(90050.03,BARENTRY_",",3,"E")
  1.  S BARBATCH=$P($G(^BARTR(DUZ(2),BARENTRY,0)),U,14)
  1.  S BARITEM=$P($G(^BARTR(DUZ(2),BARENTRY,0)),U,15)
  1.  W !?3,"A/R ACCOUNT: ",BARACCT
  1.  W !?3,BARTTYP_" for "_$J($FN($S($G(BARCRD):-BARCRD,1:$G(BARDEB)),",",2),"9R")
  1.  W !?3,"Collection Batch/Item: ",$P($G(^BARCOL(DUZ(2),BARBATCH,0)),U)_"-"_BARITEM,!!
  1.  ;
  1.  K DIC,DIE,DIR,DA,DR,X,Y
  1.  K BARREV
  1.  S BAROVAL=""
  1.  S DIR(0)="F^6:20"
  1.  I $P($G(^BARTR(DUZ(2),BARENTRY,1)),U,11)'="" D
  1.  .S DIR("A")="REV TREASURY DEP NUMBER/IPAC"
  1.  .S (DIR("B"),BAROVAL)=$P($G(^BARTR(DUZ(2),BARENTRY,1)),U,11)
  1.  I $P($G(^BARTR(DUZ(2),BARENTRY,1)),U,11)="" D
  1.  .S DIR("A")="TREASURY DEPOSIT NUMBER/IPAC"
  1.  .S:$P($G(^BARTR(DUZ(2),BARENTRY,0)),U,17)'="" (DIR("B"),BAROVAL)=$P($G(^BARTR(DUZ(2),BARENTRY,0)),U,17)
  1.  .S:'$D(DIR("B"))&($P($G(^BARCOL(DUZ(2),BARBATCH,1,BARITEM,0)),U,20)'="") (DIR("B"),BAROVAL)=$P($G(^BARCOL(DUZ(2),BARBATCH,1,BARITEM,0)),U,20)
  1.  .S:'$D(DIR("B"))&($P($G(^BARCOL(DUZ(2),BARBATCH,0)),U,28)'="") (DIR("B"),BAROVAL)=$P($G(^BARCOL(DUZ(2),BARBATCH,0)),U,28)
  1.  D ^DIR K DIR
  1.  S BARNVAL=Y
  1.  ;
  1.  I BAROVAL'=BARNVAL D
  1.  .S DIE="^BARTR(DUZ(2),"
  1.  .S DA=BARENTRY
  1.  .;reversal TDN
  1.  .I $P($G(^BARTR(DUZ(2),BARENTRY,1)),U,11)'="" S DR="111////"_BARNVAL,BARREV=""
  1.  .;Transaction TDN
  1.  .I $G(DR)="",$P($G(^BARTR(DUZ(2),BARENTRY,0)),U,17)'="" S DR="17////"_BARNVAL
  1.  .;item TDN
  1.  .I $G(DR)="",$P($G(^BARCOL(DUZ(2),BARBATCH,1,BARITEM,0)),U,20)'="" S DR="17////"_BARNVAL
  1.  .;batch TDN
  1.  .I $G(DR)="",$P($G(^BARCOL(DUZ(2),BARBATCH,0)),U,28)'="" S DR="17////"_BARNVAL
  1.  .I $G(DR)="" S DR="17////"_BARNVAL
  1.  .D ^DIE
  1.  .S DA(1)=BARENTRY
  1.  .S DIC="^BARTR(DUZ(2),"_DA(1)_",12,"
  1.  .S DIC(0)="LMQ"
  1.  .D NOW^%DTC
  1.  .S X=%
  1.  .S DIC("DR")=".02////"_$S($D(BARREV):"111",1:"20")_";.03////"_BAROVAL_";.04////"_BARNVAL_";.05////"_DUZ
  1.  .S DLAYGO=90050
  1.  .S DIC("P")=$P(^DD(90050.03,1201,0),U,2)
  1.  .D ^DIC
  1.  I BAROVAL=BARNVAL D
  1.  .W !!,"NOTHING CHANGED." H 2
  1.  G LIST
  1. EXIT ;
  1.  K BAROVAL,BARNVAL,BARREV,BARENTRY,BARLIST,BARBATCH,BARITEM,BARACCT
  1.  K BARCRD,BARDEB,BARBLDA,BARTRDA,BARCNT,BARTDN,BARSEL
  1.  Q