Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BAREV814

BAREV814.m

Go to the documentation of this file. 
  1. BAREV814 ; IHS/SD/LSL - ENVIRONMENT CHECK V1.8 PATCH 14; 09/24/2009
  1.  ;;1.8;IHS ACCOUNTS RECEIVABLE;**14**;SEP 24,2009
  1.  ;
  1.  K XPDQUIT                       ;CLEAR FLAG
  1.  I '$G(DUZ) D  Q
  1.  . W !,"DUZ UNDEFINED OR 0"
  1.  . D SORRY(2)
  1.  ;
  1.  I '$L($G(DUZ(0))) D  Q
  1.  . W !,"DUZ(0) UNDEFINED OR NULL"
  1.  . D SORRY(2)
  1.  ;
  1.  S X=$P(^VA(200,DUZ,0),U)                ;User's name
  1.  W !!,$$CJ^XLFSTR("Hello, "_$P(X,",",2)_" "_$P(X,","),IOM)
  1.  W !!,$$CJ^XLFSTR("Checking Environment for "_$P($T(+2),";",4)_" V "_$P($T(+2),";",3),IOM)
  1.  ;
  1.  N BARXU
  1.  S BARXU=$$INSTALLD("XU","8.0",1011)     ;Find current Kernel version and patch
  1.  I $P(BARXU,"*",2)<8 S BARXU=0
  1.  I $P(BARXU,"*",3)'=1011 S BARXU=0
  1.  W !,$$CJ^XLFSTR("Need at least XU v8.0 Patch 1011..... "_$S(BARXU=0:"NOT ",1:"")_"Present",IOM)
  1.  I BARXU=0 D SORRY(2)
  1.  ;
  1.  I $$VCHK("DI","21.0",2)                 ;FileMan V21.0
  1.  ;
  1.  N BARXB
  1.  S BARXB=$$INSTALLD("XB","3.0",11)       ;Find current IHS utilities version and patch
  1.  I $P(BARXB,"*",2)<3 S BARXB=0
  1.  I $P(BARXU,"*",3)'=11 S BARXU=0
  1.  W !,$$CJ^XLFSTR("Need at least XB v3.0 Patch 11..... "_$S(BARXB=0:"NOT ",1:"")_"Present",IOM)
  1.  I BARXB=0 D SORRY(2)
  1.  ;
  1.  I $$VCHK("BAR","1.8",2)                 ;Accounts Receivable V1.8
  1.  ;
  1.  N BARABM
  1.  S BARABM=$$INSTALLD("ABM","2.5",13)
  1.  I $P(BARABM,"*",2)<2.5 S BARABM=0
  1.  I $P(BARABM,"*",3)'=13 S BARABM=0
  1.  W !,$$CJ^XLFSTR("Need at least Third Party Billing v2.5 Patch 13..... "_$S(BARABM=0:"NOT ",1:"")_"Present",IOM)
  1.  I BARABM=0 D SORRY(2)
  1.  ;
  1.  N DA,DIC
  1.  S X="BAR"
  1.  S DIC="^DIC(9.4,"
  1.  S DIC(0)=""
  1.  S D="C"
  1.  D IX^DIC
  1.  I Y<0,$D(^DIC(9.4,"C","BAR")) D
  1.  . W !!,*7,*7,$$CJ^XLFSTR("You Have More Than One Entry In The",IOM)
  1.  . W !,$$CJ^XLFSTR("PACKAGE File with an ""BAR"" prefix.",IOM)
  1.  . W !,$$CJ^XLFSTR("One entry needs to be deleted.",IOM)
  1.  . D SORRY(2)
  1.  . Q
  1.  ;
  1.  ;A/R IS NO LONGER CUMULATIVE AFTER PATCH 6
  1.  ;LAST CUMULATIVE PATCH WAS PATCH 6
  1.  N BAR,I
  1.  F I=6:1:7,9,10,11,12,13 D                           ;BAR*1.8*8 WAS REPLACED WITH BAR*1.8*9
  1.  .S BAR=$$INSTALLD("BAR","1.8",I)
  1.  .I $P(BAR,"*",3)'=I S BAR=0 D
  1.  ..W !,$$CJ^XLFSTR("Need Accounts Receivable v1.8 Patch "_I_"..... "_$S(BAR=0:"NOT ",1:"")_"Present",IOM)
  1.  I BAR=0 D SORRY(2)
  1.  ;
  1.  I $G(XPDQUIT) W !,$$CJ^XLFSTR("FIX IT! Before Proceeding.",IOM),!!,*7,*7,*7 Q
  1.  ;
  1.  W !!,$$CJ^XLFSTR("ENVIRONMENT OK.",IOM)
  1.  D HELP^XBHELP("INTROE","BAREV810")
  1.  ;
  1.  I $G(XPDENV)=1 D
  1.  . ; The following line prevents the "Disable Options..." and "Move
  1.  . ; Routines..." questions from being asked during the install.
  1.  . S (XPDDIQ("XPZ1"),XPDDIQ("XPZ2"))=0
  1.  . D HELP^XBHELP("INTROI","BAREV810")
  1.  . Q
  1.  ;
  1.  I '$$DIR^XBDIR("E","","","","","",1) D SORRY(2)
  1.  Q
  1.  ;
  1. POST ;EP - POST INSTALL
  1.  S ZTRTN="INSTALL^BARDYSV4"        ;BAR*1.8*14 auto create 12 month OMB file when patch installed
  1.  D NOW^%DTC
  1.  S BARTMP1=+%H
  1.  S BARTMP2=$P(%H,",",2)+60         ;run in 5 minutes
  1.  ;S BARTMP2=72000                  ;run off hours 8pm
  1.  S ZTDTH=BARTMP1_","_BARTMP2
  1.  S ZTDESC="OMB INSTALLATION "_%
  1.  S ZTIO=""
  1.  S ZTPRI=5
  1.  K ZTSK
  1.  D ^%ZTLOAD
  1.  ;S ZTKIL=(BARTMP1+7)_","_BARTMP2   ;first day Task File Cleanup can delete this task
  1.  W !!,?5,"*** TASK = ",ZTSK,!
  1.  Q
  1.  ;
  1. SORRY(X) ;
  1.  KILL DIFQ
  1.  S XPDQUIT=X
  1.  W *7,!,$$CJ^XLFSTR("Sorry....FIX IT!",IOM)
  1.  Q
  1.  ; ***
  1. VCHK(BARPRE,BARVER,BARQUIT)     ; Check versions needed.
  1.  ;
  1.  N BARV
  1.  S BARV=$$VERSION^XPDUTL(BARPRE)
  1.  W !,$$CJ^XLFSTR("Need at least "_BARPRE_" v "_BARVER_"....."_BARPRE_" v "_BARV_" Present",IOM)
  1.  I BARV<BARVER KILL DIFQ S XPDQUIT=BARQUIT D SORRY(BARQUIT) Q 0
  1.  Q 1
  1.  ; ***
  1. INSTALLD(BARNM,BARVR,BARPT) ;EP    ;RLT
  1.  ; RLT - 04/05/05 - Per Don Jackson, modified this tag to use
  1.  ;                  PATCH^XPDUTL.  Removed the reverse $O, problem
  1.  ;                  with XU patch numbers. VA (lower than 1000) and
  1.  ;                  IHS patch numers (1000 and higher) not loaded
  1.  ;                  in numerical order.  No longer
  1.  ;                  verifies that a lower version did not get
  1.  ;                  reinstalled over a higher version.
  1.  N BARVNUM,BARPATCH
  1.  ;1 get current version
  1.  S BARVNUM=$$VERSION^XPDUTL(BARNM)
  1.  I '+BARVNUM Q 0
  1.  ;2 is needed patch loaded
  1.  S BARPATCH=$$PATCH^XPDUTL(BARNM_"*"_BARVR_"*"_BARPT)
  1.  I '+BARPATCH Q 0
  1.  Q BARNM_"*"_BARVNUM_"*"_BARPT
  1.  ;
  1.  ; ********************************************************************
  1. INTROE ; Intro text during KIDS Environment check.
  1.  ;;This distribution Modifies Accounts Receivable and does not contain
  1.  ;;previous patch modifications for version 1.8.
  1.  ;;
  1.  ;;        This patch is **not** cumulative.
  1.  ;;
  1.  ;;###
  1.  ;;
  1.  ;
  1. INTROI ; Intro text during KIDS Install.
  1.  ;;If you run interactively, results will be displayed on your screen,
  1.  ;;and recorded in the entry in the INSTALL file.
  1.  ;;If you queue to TaskMan, remember not to Q to the HOME device.
  1.  ;;###