Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BARRERL2

BARRERL2.m

Go to the documentation of this file. 
  1. BARRERL2 ; IHS/SD/LSL - Print Synch Reports ;
  1.  ;;1.8;IHS ACCOUNTS RECEIVABLE;**4,6**;OCT 26, 2005
  1.  ;
  1.  ; IHS/ASDS/LSL - 06/19/2001 - V1.5 Patch 1 - NOIS BXX-0501-150074
  1.  ;     Modified to correct the display of dollar amounts.
  1.  ;
  1.  ; IHS/SD/LSL - 12/06/02 - V1.7 - NOIS NHA-0601-180049
  1.  ;     Modified to find bill in 3PB properly
  1.  ;
  1.  ; IHS/SD/SDR - v1.8 p6 - DD 4.1.3
  1.  ;   Remove Negative Balance report and make it stand-alone report
  1.  ;
  1.  ; *********************************************************************
  1.  ;
  1. RR ;EP - re-roll
  1.  D ^BARRERL  ;BAR*1.8*4
  1.  D RCHK
  1.  Q:'$G(BAROK)
  1.  S BARHDR="RE-ROLL"
  1.  S BARXRF="ARR"
  1.  D DEV
  1.  Q
  1.  ; *********************************************************************
  1.  ;
  1. SB ;EP - small balance
  1.  D ^BARRERL  ;BAR*1.8*4
  1.  D RCHK Q:'BAROK
  1.  S BARHDR="SMALL BALANCE"
  1.  S BARXRF="ASBL"
  1.  D DEV
  1.  Q
  1.  ; *********************************************************************
  1.  ;
  1.  ;start old code bar*1.8*6 DD 4.1.3
  1. NB ;EP - negative balance      
  1.  D ^BARRERL  ;BAR*1.8*4
  1.  D RCHK
  1.  Q:'BAROK
  1.  S BARHDR="NEGATIVE BALANCE"
  1.  S BARXRF="ANEG"
  1.  D DEV
  1.  Q
  1.  ;end old code DD 4.1.3
  1.  ; *********************************************************************
  1.  ;
  1. MM ;EP - 3p - a/r mis-matches
  1.  D ^BARRERL  ;BAR*1.8*4
  1.  D RCHK
  1.  Q:'BAROK
  1.  S BARHDR="3P - A/R MISMATCH"
  1.  S BARXRF="AMM"
  1.  D DEV
  1.  Q
  1.  ; *********************************************************************
  1.  ;
  1. IEN ;EP - 3P ien wrong
  1.  D ^BARRERL  ;BAR*1.8*4
  1.  D RCHK
  1.  Q:'BAROK
  1.  S BARHDR="A/R MISSING 3P BILL"
  1.  S BARXRF="AIEN"
  1.  D DEV
  1.  Q
  1.  ; *********************************************************************
  1.  ;
  1. RCHK ;check for error run
  1.  S BAROK=0
  1.  I $G(^BARBLER(DUZ(2),"RUNNING")) D  Q
  1.  .W !!,"A/R Bill File Error Scan is currently running. The scan"
  1.  .W !,"must complete before printing lists.",!
  1.  .D EOP^BARUTL(1)
  1.  I '$G(^BARBLER(DUZ(2),"LASTRUN")) D  Q
  1.  .W !!,"You need to run the 'Bill File Error Scan' option before printing any reports.",!
  1.  .D EOP^BARUTL(1)
  1.  S BAROK=1
  1.  Q
  1.  ; *********************************************************************
  1.  ;
  1. DEV ;select device
  1.  W !
  1.  S %ZIS="NQ"
  1.  D ^%ZIS
  1.  Q:POP
  1.  I IO'=IO(0) D  Q
  1.  .S ZTRTN="LNP^BARRERL2"
  1.  .N I
  1.  .F I="BARHDR","BARXRF" S ZTSAVE(I)=""
  1.  .S ZTDESC="A/R - 3P SYNCH REPORTS"
  1.  .D ^%ZTLOAD
  1.  .W:$G(ZTSK) !,"Task # ",ZTSK," queued.",!
  1.  .D HOME^%ZIS
  1.  I $D(IO("S")) D
  1.  .S IOP=ION
  1.  .D ^%ZIS
  1.  D LNP
  1.  K BARQUIT
  1.  Q
  1.  ; *********************************************************************
  1.  ;
  1. LNP ;loop & print
  1.  K BARQUIT
  1.  S $P(BAREQ,"=",80)=""
  1.  S $P(BARDSH,"-",80)=""
  1.  S BARPG=0
  1.  D HDR
  1.  S DA=0
  1.  F  S DA=$O(^BARBLER(DUZ(2),BARXRF,1,DA)) Q:'DA!($G(BARQUIT))  D
  1.  . S Y=1
  1.  .I $Y+5>IOSL D
  1.  ..D EOP^BARUTL(0)
  1.  ..I '+Y S BARQUIT=1 Q
  1.  ..D HDR
  1.  .Q:$G(BARQUIT)
  1.  .K BAR
  1.  .S DIC="^BARBL(DUZ(2),"
  1.  .S DIQ="BAR("
  1.  .S DIQ(0)="IE"
  1.  .S DR=".01;3;13;15;17;22;101;102;108"
  1.  .D EN^DIQ1
  1.  .W !,"AR",?5,DA
  1.  .W ?11,$P(BAR(90050.01,DA,.01,"E"),"-",1)
  1.  .W ?20,$E(BAR(90050.01,DA,101,"E"),1,20)
  1.  .W ?41,$$SDT^BARDUTL(BAR(90050.01,DA,102,"I"))
  1.  .W ?52,$E(BAR(90050.01,DA,3,"E"),1,10)
  1.  .I BARXRF="ASBL"!(BARXRF="ANEG") D
  1.  ..W ?69,$J($FN(+$G(BAR(90050.01,DA,15,"I")),",",3),10)
  1.  .E  D
  1.  ..W ?69,$J($FN(BAR(90050.01,DA,13,"I"),",",2),10)
  1.  .Q:BARXRF'="AMM"
  1.  . S BAR("3P LOC")=$$FIND3PB^BARUTL(DUZ(2),DA)
  1.  . Q:BAR("3P LOC")=""
  1.  . S BAR3PDUZ=$P(BAR("3P LOC"),",")
  1.  . S BAR3PIEN=$P(BAR("3P LOC"),",",2)
  1.  . N I
  1.  . F I=0,2,7 S BAR3P(I)=$G(^ABMDBILL(BAR3PDUZ,BAR3PIEN,I))
  1.  . W !,"3P",?5,BAR3PIEN
  1.  .W ?11,$P(BAR3P(0),"^",1)
  1.  .W ?20,$E($P($G(^DPT(+$P(BAR3P(0),"^",5),0)),"^",1),1,20)
  1.  .W ?41,$$SDT^BARDUTL(+BAR3P(7))
  1.  .W ?52,$E($P($G(^AUTNINS(+$P(BAR3P(0),"^",8),0)),"^",1),1,10)
  1.  . W ?69,$J($FN(+BAR3P(2),",",2),10)
  1.  .W !
  1.  .K BAR3P
  1.  W !!,"E N D   O F   R E P O R T",!!
  1.  D EOP^BARUTL(1)
  1.  W $$EN^BARVDF("IOF")
  1.  K BARHDR,BARXRF,BAR,BAR3P
  1.  I $D(IO("S")) D ^%ZISC
  1.  Q
  1.  ; *********************************************************************
  1.  ;
  1. HDR ;report header
  1.  S BARPG=BARPG+1
  1.  W $$EN^BARVDF("IOF")
  1.  W !,$$MDT^BARDUTL(DT)
  1.  W ?30,BARHDR
  1.  W ?70,"Page: ",BARPG
  1.  W !,BAREQ
  1.  W !,?5,"IEN   BILL#",?20,"PATIENT",?41,"DOS",?52,"BILLED TO"
  1.  I BARXRF="ASBL"!(BARXRF="ANEG") D  Q
  1.  .W ?72,"BALANCE"
  1.  .W !,BARDSH
  1.  W ?69,"AMT BILLED"
  1.  W !,BARDSH
  1.  Q