Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BARUFLOG

BARUFLOG.m

Go to the documentation of this file. 
  1. BARUFLOG ; IHS/SD/TPF - SESSION LOG IN AND LOG OUT ;
  1.  ;;1.8;IHS ACCOUNTS RECEIVABLE;**3,21,23**;OCT 26, 2005
  1.  ;OCT 2012 P.OTTIS NOHEAT#01: ALLOW RE-CONNECT TO LAST OPEN SESSION AFTER LOG-OFF / OR
  1.  ;                            SWITCHING FALICITIES
  1.  Q
  1.  ;
  1. SIGNOUT ;EP - SIGN OUT AND RECONCILE
  1.  ;
  1.  I $$OUTORREC^BARUFUT(UFMSESID) Q  ;ask user if the wish to reconcile or simply get out
  1.  ;
  1.  D DISPLAYT(DUZ,UFMSESID,"OUT")  ;display counts and totals
  1.  ;
  1.  ;BAR*1.8*21 IHS/SD/TPF 8/12/2011 HEAT20490 DON'T ASK IF THEY WISH TO LOG OUT
  1.  I '$$OPENSTAT^BARUFUT(DUZ) D  Q
  1.  .;IF SESSION HAS BEEN CLOSED BY SUPER
  1.  .K UFMSESID  ;LOGOUT FLAG
  1.  .K DIR
  1.  .S DIR(0)="E"
  1.  .D ^DIR
  1.  ;
  1.  W !
  1.  K DIR
  1.  S DIR("A")="Do you wish to log out now?"
  1.  S DIR("B")="Yes"
  1.  S DIR(0)="YO"
  1.  D ^DIR
  1.  I 'Y D  Q
  1.  .W !!,"YOUR CASHIER SESSION IS STILL OPEN."
  1.  .W !,"AT SOME POINT YOU MUST LOG OUT"
  1.  .W !,"TO RECONCILE THIS SESSION"
  1.  .;S X=$$DELFLG^BARUFUT1(DUZ,UFMSESID)
  1.  .;K UFMSESID
  1.  ;
  1.  I '$O(^BARSESS(DUZ(2),DUZ,11,UFMSESID,2,0)) D  Q
  1.  .W !!,"There is no posting activity for this session. Therefore"
  1.  .W !,"it cannot be reconciled. If you log out this session will be"
  1.  .W !,"deleted. Or you can continue in cashier mode."
  1.  .W !
  1.  .K DIR
  1.  .S DIR("A")="Delete session and log out?"
  1.  .S DIR("B")="Yes"
  1.  .S DIR(0)="YO"
  1.  .D ^DIR
  1.  .Q:'Y
  1.  .S X=$$DELFLG^BARUFUT1(DUZ,UFMSESID)
  1.  .D DELETE^BARUFUT1(DUZ,UFMSESID)
  1.  .K UFMSESID
  1.  ;
  1.  ;
  1.  W !
  1.  K DIR
  1.  S DIR("A")="By logging out, you are confirming the system balances. Are you sure you wish to log out?"
  1.  S DIR("B")="Yes"
  1.  S DIR(0)="YO"
  1.  D ^DIR
  1.  I 'Y D  Q
  1.  .W !!,"YOUR CASHIER SESSION IS STILL OPEN."
  1.  .W !,"AT SOME POINT YOU MUST LOG OUT"
  1.  .W !,"TO RECONCILE THIS SESSION"
  1.  .D ASKFORRT^BARUFUT
  1.  ;
  1.  ;
  1.  W !!,"Fine, the session "_$G(UFMSESID)_" will be sent to your manager for processing."
  1.  W !,"Status for Session ",$G(UFMSESID)," has been set to RECONCILED"
  1.  D ASKFORRT^BARUFUT
  1.  ;
  1.  S X=$$DELFLG^BARUFUT1(DUZ,UFMSESID)  ;CLEAR 'ALREADY ASSIGNED' FLAG
  1.  S X=$$SETSESS^BARUFUT(DUZ,UFMSESID,"RC") ;EP - SET SESSION STATUS 'BARSTAT'
  1.  ;
  1.  K UFMSESID,MODE    ;CLEAR SESSION ID
  1.  Q
  1.  ;
  1. SIGNIN ;EP - CASHIER SIGN IN
  1.  ;
  1.  I '$$CSMENU^BARUFUT1(DUZ(2)) Q  ;P.OTT - CAS SESSION MENU DISABLED!
  1.  I $G(UFMSESID)'="",$$CURSTAT^BARUFUT(DUZ,UFMSESID,"E")="OPEN" D  Q  ;bar*1.8*21 SDR
  1.  . D SIGNOUT
  1.  . Q
  1.  ;
  1.  NEW SESSDT ;P.OTT
  1.  S SESSDT=$$OPENSTAT^BARUFUT(DUZ) I SESSDT="" G NEWSESS ; NO SESS OPEN FOR THIS USER
  1.  S UFMSESID=SESSDT
  1.  S Y=SESSDT X ^DD("DD") S SESSDT=Y
  1.  W !!,"RECONNECTING TO A OPEN SESSION IN "_$P(^DIC(4,DUZ(2),0),U)_"."
  1.  W !!,"YOU HAVE A SESSION STILL OPEN FROM "_SESSDT
  1.  W !,"YOU WILL BE ASSIGNED THIS SESSION ID TO CONTINUE"
  1.  W !!!
  1.  D ASKFORRT^BARUFUT
  1.  S MODE="CASHIER"
  1.  K SESSDT
  1.  K DIR,DIE,DR,DIC,DA
  1.  S DA(1)=DUZ
  1.  S DA=UFMSESID
  1.  S DR=".05///1"
  1.  S DIE="^BARSESS(DUZ(2),"_DA(1)_",11,"
  1.  D ^DIE
  1.  D DISPLAYT(DUZ,UFMSESID,"OUT","NO")
  1.  QUIT
  1.  ;
  1. NEWSESS ; 
  1.  W !!,"YOU ARE SIGNING *IN* FOR CASHIERING"
  1.  W !!
  1.  D SIG^XUSESIG
  1.  Q:X1=""
  1.  ;
  1.  S UFMSESID=$$GETSESID^BARUFUT(DUZ)   ;ASSIGN SESSION ID. CREATE AN ENTRY IN THE ^BARSESS FILE
  1.  ;
  1.  I UFMSESID=0 D  Q
  1.  . W !!,"COULD NOT CREATE SESSION ID IN THE 'A/R UFMS CASHIER SESSION LOG' FILE"
  1.  . W !,"MAKE SURE THE CASHIER HAS 'V' FILEMAN ACCESS. IF THEY ALREADY DO THERE MAY"
  1.  . W !,"A LOCK ON THE FILE"
  1.  . D ASKFORRT^BARUFUT
  1.  . K UFMSESID
  1.  . Q
  1.  ;AND SET STATUS = OPEN
  1.  K DIR,DIE,DR,DIC,DA
  1.  S DA(1)=DUZ
  1.  S DA=UFMSESID
  1.  S DR=".05///1"
  1.  S DIE="^BARSESS(DUZ(2),"_DA(1)_",11,"
  1.  D ^DIE
  1.  S MODE="CASHIERING"
  1.  D DISPLAYT(DUZ,UFMSESID,"NEW","NO")
  1.  Q
  1.  ;
  1. DISPLAYT(UDUZ,SESSID,MODE,ERASTAT) ;EP - DISPLAY SESSION TOTALS
  1. DISPAGAI ;EP - DO IT AGAIN
  1.  ;MODE - "NEW", "OUT", "VIEW", "CASHIER"
  1.  ;SESSID - CASHIER SESSION
  1.  N BARTR,ARCREDIT,ARDEBIT,TRANTYPE,AMT,TOTALS,IENS,CAT
  1.  D DISHDR(UDUZ,SESSID,MODE)
  1.  ;LOOP THROUGH USERS SESSION ENTRIES
  1.  S TOTALS("AAA PAYMENT")=0
  1.  S TOTALS("AAA PAYMENT","CNT")=0
  1.  S TOTALS("ADJ CO-PAY")=0
  1.  S TOTALS("ADJ CO-PAY","CNT")=0
  1.  S TOTALS("ADJ DEDUCTIBLE")=0
  1.  S TOTALS("ADJ DEDUCTIBLE","CNT")=0
  1.  S TOTALS("ADJ NON PAYMENT")=0
  1.  S TOTALS("ADJ NON PAYMENT","CNT")=0
  1.  S TOTALS("ADJ WRITE OFF")=0
  1.  S TOTALS("ADJ WRITE OFF","CNT")=0
  1.  S TOTALS("ADJ PENALTY")=0
  1.  S TOTALS("ADJ PENALTY","CNT")=0
  1.  S TOTALS("ADJ GROUPER ALLOWANCE")=0
  1.  S TOTALS("ADJ GROUPER ALLOWANCE","CNT")=0
  1.  S TOTALS("ADJ PAYMENT CREDIT")=0
  1.  S TOTALS("ADJ PAYMENT CREDIT","CNT")=0
  1.  S TOTALS("ZZZ REFUND")=0
  1.  S TOTALS("ZZZ REFUND","CNT")=0
  1.  ;
  1.  S BARTR=0
  1.  F  S BARTR=$O(^BARSESS(DUZ(2),UDUZ,11,SESSID,2,BARTR)) Q:'BARTR  D
  1.  .S IENS=BARTR_","
  1.  .S ARBILL=$$GET1^DIQ(90050.03,IENS,4,"E")      ;A/R TRANSACTIONS, BILL (A/R)
  1.  .Q:ARBILL=""
  1.  .S ARCREDIT=$$GET1^DIQ(90050.03,IENS,2,"E")    ;A/R TRANSACTIONS, CREDIT
  1.  .S ARDEBIT=$$GET1^DIQ(90050.03,IENS,3,"E")     ;A/R TRANSACTIONS, DEBIT
  1.  .S AMT=ARCREDIT-ARDEBIT
  1.  .S TRANTYPE=$$GET1^DIQ(90050.03,IENS,101,"E")  ;A/R TRANSACTIONS, ADJUSTMENT TYPE
  1.  .S ADJCAT=$$GET1^DIQ(90050.03,IENS,102,"E")    ;A/R TRANSACTIONS, ADJUSTMENT CATEGORY
  1.  .I TRANTYPE="PAYMENT" S CAT="AAA "_TRANTYPE D TOT(CAT,AMT,.TOTALS) Q
  1.  .S CAT=ADJCAT
  1.  .I CAT="REFUND" S CAT="ZZZ "_CAT D TOT(CAT,AMT,.TOTALS) Q
  1.  .I CAT="" S CAT="ADJ UNDEF" D TOT(CAT,AMT,.TOTALS) Q
  1.  .S CAT="ADJ "_CAT D TOT(CAT,AMT,.TOTALS) Q
  1.  D LIST(.TOTALS,MODE)
  1.  Q
  1.  ;
  1. TOT(CAT,AMT,TOTALS) ;
  1.  S TOTALS(CAT)=$G(TOTALS(CAT))+AMT
  1.  S TOTALS(CAT,"CNT")=$G(TOTALS(CAT,"CNT"))+1
  1.  Q
  1.  ;
  1. LIST(TOTALS,MODE) ;EP - DISPLAY CALCULATED TOTALS
  1.  N CATEGORY,ADJCAT,ADJCNT,ADJAMT
  1.  S (ADJCNT,ADJAMT,REFCNT,REFAMT)=0
  1.  S (CATEGORY,SUBHDR)=""
  1.  F  S CATEGORY=$O(TOTALS(CATEGORY)) Q:CATEGORY=""  D
  1.  .I $P(CATEGORY," ")'=SUBHDR D
  1.  ..W !!?5,"Cashiering Function - "
  1.  ..W $S($P(CATEGORY," ")="AAA":"Payments",$P(CATEGORY," ")="ZZZ":"Refunds",1:"Adjustments")
  1.  ..;
  1.  .I $P(CATEGORY," ")="ADJ" D
  1.  ..S ADJCNT=ADJCNT+TOTALS(CATEGORY,"CNT")
  1.  ..S ADJAMT=ADJAMT+TOTALS(CATEGORY)
  1.  ..;
  1.  .I $P(CATEGORY," ",2)="REFUND" D
  1.  ..S REFCNT=REFCNT+TOTALS(CATEGORY,"CNT")
  1.  ..S REFAMT=REFAMT+TOTALS(CATEGORY)
  1.  .S SUBHDR=$P(CATEGORY," ")
  1.  .I SUBHDR="ADJ" W !?10,$P(CATEGORY," ",2,3)
  1.  .E  W !?10,"Count"
  1.  .W ?28,"- ",$J(TOTALS(CATEGORY,"CNT"),4)
  1.  .W ?50,"$"_$J(TOTALS(CATEGORY),10,2)
  1.  .I $O(TOTALS(CATEGORY))[("ZZZ") D
  1.  ..W !?8,"Total Adjustments"
  1.  ..W ?28,"= ",$J(ADJCNT,4)
  1.  ..W ?50,"$"_$J(ADJAMT,10,2)
  1.  W !
  1.  ;IF THE SESSION HAS BEEN TRANSMITTED SHOW THE FILE
  1.  I $D(^BARSESS(DUZ(2),UDUZ,11,SESSID,21)) D
  1.  .W !,"TRANSMITTED ON: "
  1.  .N TRANREC,TRANTIME,IENS,TRANFILE,TRANBY,CNT
  1.  .S TRANREC=0
  1.  .F CNT=1:1 S TRANREC=$O(^BARSESS(DUZ(2),UDUZ,11,SESSID,21,TRANREC)) Q:'TRANREC  D
  1.  ..S IENS=TRANREC_","_SESSID_","_UDUZ_","
  1.  ..S TRANTIME=$$GET1^DIQ(90057.210101,IENS,.01,"E")
  1.  ..S TRANFILE=$$GET1^DIQ(90057.210101,IENS,.02,"E")
  1.  ..S TRANBY=$$GET1^DIQ(90057.210101,IENS,.03,"E")
  1.  ..W:CNT'=1 !
  1.  ..W ?16,TRANTIME," BY ",TRANBY
  1.  ..W !?16,TRANFILE
  1.  ;
  1.  S RESPONSE=""
  1.  D ASKACT^BARUFUT(UDUZ,SESSID,.RESPONSE,MODE,$G(ERASTAT))  ;ASK FOR AN ACTION TO TAKE
  1.  Q:MODE="OUT"&(RESPONSE="RC")!(RESPONSE="D")  ;CASHIER HAS RECONCILED
  1.  Q:RESPONSE[U!(RESPONSE="")!(RESPONSE="Q")
  1.  G DISPAGAI
  1.  Q
  1.  ;
  1. DISHDR(UDUZ,SESSID,MODE) ;EP - DISPLAY HEADER 
  1.  W @IOF
  1.  ;I MODE="VIEW" W !,$$CJ^XLFSTR("SUPERVISOR MODE",IOM)
  1.  W !,$$CJ^XLFSTR($S(MODE="VIEW":"SUPERVISOR MODE",MODE="CASHIER"!(MODE="NEW")!(MODE="OUT"):"CASHIERING MODE",1:"UNKNOWN MODE"),IOM)
  1.  W !,$$CJ^XLFSTR("CASHIERING DISPLAY FOR CASHIER "_$P($G(^VA(200,UDUZ,0)),U),IOM)
  1.  W !,$$CJ^XLFSTR("WITH SESSION ID "_SESSID_"     SESSION STATUS: "_$$CURSTAT^BARUFUT(UDUZ,SESSID,"E"),IOM)
  1.  Q
  1.  ;
  1. PRINTDUM(UFMSESID) ;EP - PRINT EMPTY BEGINNING COUNTS
  1.  ;W !,$$CJ^XLFSTR("CURRENTLY THERE IS NO POSTING ACTIVITY",IOM)
  1.  W !!?5,"Cashiering Function - Payments"
  1.  W !?8,"Beginning Count",?28,"- 0",?50,"$            0.00"
  1.  W !!?5,"Cashiering Function - Adjustments"
  1.  W !?8,"Beginning Counts"
  1.  W !?10,"CO-PAYS",?28,"- 0",?50,"$            0.00"
  1.  W !?10,"DEDCUTIBLES",?28,"- 0",?50,"$            0.00"
  1.  W !?10,"NON-PAYMENTS",?28,"- 0",?50,"$            0.00"
  1.  W !?10,"WRITE OFFS",?28,"- 0",?50,"$            0.00"
  1.  W !?10,"PENALTIES",?28,"- 0",?50,"$            0.00"
  1.  W !?10,"GROUPER ALLOWANCE",?28,"- 0",?50,"$            0.00"
  1.  W !?10,"PAYMENT CREDITS",?28,"- 0",?50,"$            0.00"
  1.  W !?8,"Total Adjustments",?28,"= 0",?50,"$            0.00"
  1.  W !!?5,"Cashiering Function - Refunds"
  1.  W !?8,"Beginning Count",?28,"- 0",?50,"$            0.00"
  1.  W:MODE="NEW" !!?1,"Assigning session number: ",$G(UFMSESID)
  1.  W:MODE="OUT" !!?1,"Session number: ",$G(UFMSESID)
  1.  W !
  1.  D ASKFORRT^BARUFUT
  1.  Q