Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BDMD010

BDMD010.m

Go to the documentation of this file. 
  1. BDMD010 ; IHS/CMI/LAB -IHS -GETS DATA FOR DIABETES QA REPORT ;
  1.  ;;2.0;DIABETES MANAGEMENT SYSTEM;**3**;JUN 14, 2007
  1.  ;
  1.  ;
  1. EN ; - ENTRY POINT - from ^BDMASK
  1.  K ^BDMDATA("BDMEPI",$J)
  1.  S ^XTMP("BDMDM01",0)=$$FMADD^XLFDT(DT,14)_"^"_DT_"^DM AUDIT 2010"
  1.  S BDMEPIN=0
  1.  S BDMPD=0 F  S BDMPD=$O(^XTMP("BDMDM01",BDMJOB,BDMBTH,"PATS",BDMPD)) Q:'BDMPD  D
  1.  .I BDMTYPE'="P",BDMTYPE'="S" Q:$$DEMO^BDMUTL(BDMPD,$G(BDMDEMO))
  1.  .I BDMPREP=2 D EPIREC Q
  1.  .D GATHER
  1.  I BDMPREP=2 D WRITEF^BDMD01 Q
  1.  I BDMPREP=3!(BDMPREP=4) D CUML^BDMD015
  1.  Q
  1. S(P,I,V) ;
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",P,I)=V
  1.  Q
  1. REC(DFN,BDMRTYP,BDMRBD,BDMRED,BDMED,BDMDMRG,BDMBDAT) ;EP - called to send back a visit record as
  1.  NEW BDMX,BDMREC
  1.  S BDMREC=""
  1.  S BDMRTYP("IEN")=$O(^BDMRECD("B",BDMRTYP,0))
  1.  I 'BDMRTYP("IEN") Q BDMREC
  1. PROC ;
  1.  S BDMEPIX=0
  1.  F  S BDMEPIX=$O(^BDMRECD(BDMRTYP("IEN"),11,"AC",BDMEPIX)) Q:BDMEPIX'=+BDMEPIX!(BDMREC=-1)  S BDMTTT=$O(^BDMRECD(BDMRTYP("IEN"),11,"AC",BDMEPIX,0))  D
  1.  .S X="" X:$D(^BDMRECD(BDMRTYP("IEN"),11,BDMTTT,11)) ^BDMRECD(BDMRTYP("IEN"),11,BDMTTT,11)
  1.  .S $E(BDMREC,$P(^BDMRECD(BDMRTYP("IEN"),11,BDMTTT,0),U,2))=X  ;W !,BDMTTT,?5,$P(^BDMRECD(BDMRTYP("IEN"),11,BDMTTT,0),U),?40,X 
  1.  Q BDMREC
  1. EPIREC ;create epi info record in ^BDMDATA("BDMEPI",$J,n)
  1.  ;skip this patient if dodx is greater than the audit date
  1.  S X=$$DODX^BDMD016(BDMPD,BDMDMRG,"I")
  1.  I X>BDMADAT Q
  1.  S BDMEPIR="",BDMEPIR=$$REC(BDMPD,"DM AUDIT 2010 EPI REC 1",BDMRBD,BDMRED,BDMADAT,BDMDMRG,BDMBDAT),BDMEPIN=BDMEPIN+1,^BDMDATA("BDMEPI",$J,BDMEPIN)=BDMEPIR
  1.  S BDMTHER="",BDMEPIR="",BDMEPIR=$$REC(BDMPD,"DM AUDIT 2010 EPI REC 2",BDMRBD,BDMRED,BDMADAT,BDMDMRG,BDMBDAT),BDMEPIN=BDMEPIN+1,^BDMDATA("BDMEPI",$J,BDMEPIN)=BDMEPIR
  1.  S BDMEPIR="",BDMEPIR=$$REC(BDMPD,"DM AUDIT 2010 EPI REC 3",BDMRBD,BDMRED,BDMADAT,BDMDMRG,BDMBDAT),BDMEPIN=BDMEPIN+1,^BDMDATA("BDMEPI",$J,BDMEPIN)=BDMEPIR
  1.  S BDMEPIR="",BDMEPIR=$$REC(BDMPD,"DM AUDIT 2010 EPI REC 4",BDMRBD,BDMRED,BDMADAT,BDMDMRG,BDMBDAT),BDMEPIN=BDMEPIN+1,^BDMDATA("BDMEPI",$J,BDMEPIN)=BDMEPIR
  1.  Q
  1. GATHER ;gather data for 1 patient
  1.  S BDMER=0
  1.  ;set report dates
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,1)=$S($G(BDMFISC)]"":BDMFISC,1:BDMRBD_" - "_BDMRED)
  1.  ;set audit date to DT
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,2)=$$FMTE^XLFDT(DT)
  1.  ;set area, su, facility code and name
  1.  ;S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,4)=$P(^DIC(4,$S($G(BDMDUZ2):BDMDUZ2,1:DUZ(2)),0),U)
  1.  ;S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,6)=$E($P(^AUTTLOC($S($G(BDMDUZ2):BDMDUZ2,1:DUZ(2)),0),U,10),1,2)
  1.  ;S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,8)=$E($P(^AUTTLOC($S($G(BDMDUZ2):BDMDUZ2,1:DUZ(2)),0),U,10),3,4)
  1.  ;S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,10)=$E($P(^AUTTLOC($S($G(BDMDUZ2):BDMDUZ2,1:DUZ(2)),0),U,10),5,6)
  1.  ;# pats in register
  1.  ;S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,12)=$S(BDMDMRG:$$RSTAT^BDMDM6(BDMDMRG,"A"),1:"")
  1.  ;reviewer
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,14)=$P(^VA(200,DUZ,0),U,2)  ;reviewer initials
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,122)=$$COMM(BDMPD)
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,120)=$$TRIBE(BDMPD)  ;tribal enrollment code
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,121)=$S($P($G(^DPT(BDMPD,.11)),U,5):$P($G(^DIC(5,$P(^DPT(BDMPD,.11),U,5),0)),U,2),1:"")  ;state of residence
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,15)=$$VAL^XBDIQ1(9000001,BDMPD,.14)  ;primary care provider
  1. DEMO ;pat demographics
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,16)=$$HRN^AUPNPAT(BDMPD,$S($G(BDMDUZ2):BDMDUZ2,1:DUZ(2)))  ;hrn
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,18)=$$DOB^AUPNPAT(BDMPD,"E")  ;dob
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,20)=$$VAL^XBDIQ1(2,BDMPD,.02)  ;sex
  1. DXDT ;dates of and dm dxs
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,22)=$S(BDMDMRG:$$CMSFDX^BDMD013(BDMPD,BDMDMRG,"D"),1:"")
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,24)=$S(BDMDMRG:$$CMSFDX^BDMD013(BDMPD,BDMDMRG,"DX"),1:"")
  1.  S ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,23)=$$PLDMDOO^BDMD013(BDMPD)
  1.  D S(BDMPD,25,$$PLDMDXS^BDMD013(BDMPD))
  1.  D S(BDMPD,21,$$FRSTDMDX^BDMD013(BDMPD))
  1.  D S(BDMPD,26,$$LASTDMDX^BDMD013(BDMPD,BDMRED))
  1.  I $$DODX^BDMD016(BDMPD,BDMDMRG,"I")>BDMADAT D S(BDMPD,26.5,"*** Patient's Date of Onset is after the audit date.") D
  1.  .D S(BDMPD,26.6,"**** This patient will not be included in the cumulative audit.")
  1.  S BDMTYDM="" D TYPEDM,S(BDMPD,29,BDMTYDM)
  1.  D S(BDMPD,27,$$TOBACCO^BDMD01T(BDMPD,$$DOB^AUPNPAT(BDMPD),BDMADAT))
  1.  D S(BDMPD,28,$$CESS^BDMD011(BDMPD,BDMBDAT,BDMADAT))
  1.  ;
  1. VITAL ;
  1.  D S(BDMPD,30,$$LASTHT^BDMD013(BDMPD,BDMRED))
  1.  D S(BDMPD,32,$$LASTWT^BDMD013(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,112,$$BMI^BDMD018(BDMPD,BDMRBD,BDMRED))
  1.  ;htn dx
  1.  D S(BDMPD,34,$$HTNDX^BDMD013(BDMPD,BDMRED))
  1.  ;last 3 BPs
  1.  D S(BDMPD,36,$$BPS^BDMD013(BDMPD,BDMRBD,BDMRED))
  1. EXAMS ;
  1.  D S(BDMPD,38,$$DFE^BDMD017(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,40,$$EYE^BDMD017(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,42,$$DENTAL^BDMD017(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,44,$$DIETEDUC^BDMD017(BDMPD,BDMRBD,BDMRED))
  1.  D S(BDMPD,46,$$EXEDUC^BDMD017(BDMPD,BDMRBD,BDMRED))
  1.  D S(BDMPD,48,$$OTHEDUC^BDMD017(BDMPD,BDMRBD,BDMRED))
  1. MH ;
  1.  D S(BDMPD,200,$$DEPDX^BDMD012(BDMPD,BDMBDAT,BDMADAT))
  1.  S BDMDEP=$E($G(^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,200)))
  1.  D S(BDMPD,210,$S(BDMDEP="1":"",1:$$DEPSCR^BDMD012(BDMPD,BDMBDAT,BDMADAT)))
  1. THERAPY ;
  1.  S BDM6MBD=$$FMADD^XLFDT(BDMADAT,-(6*31)),BDM6MBD=$$FMTE^XLFDT(BDM6MBD)
  1.  D S(BDMPD,52,$$INSULIN^BDMD012(BDMPD,BDM6MBD,BDMRED))
  1.  D S(BDMPD,53,$$SULF^BDMD012(BDMPD,BDM6MBD,BDMRED))
  1.  D S(BDMPD,98,$$SULFLIKE^BDMD012(BDMPD,BDM6MBD,BDMRED))
  1.  D S(BDMPD,54,$$MET^BDMD012(BDMPD,BDM6MBD,BDMRED))
  1.  D S(BDMPD,55,$$ACAR^BDMD012(BDMPD,BDM6MBD,BDMRED))
  1.  D S(BDMPD,56,$$TROG^BDMD012(BDMPD,BDM6MBD,BDMRED))
  1.  D S(BDMPD,58,$$INCR^BDMD012(BDMPD,BDM6MBD,BDMRED))  ;cmi/maw 12/18/2007 DM2010
  1.  D S(BDMPD,59,$$DPP4^BDMD012(BDMPD,BDM6MBD,BDMRED))  ;cmi/maw 12/18/2010 DM2010
  1.  D S(BDMPD,99,$$AMYLIN^BDMD012(BDMPD,BDM6MBD,BDMRED))
  1.  S Z="" F X=52:1:56,58,59,98,99 I $E($G(^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,X)))="X" S Z=1  ;ANY MED AT ALL?
  1.  S Y=$$REFMED^BDMD012(BDMPD,BDMRBD,BDMRED) S Y=$S(Z:"",Y="":"",1:"X"_U_$P(Y,U,2)) D S(BDMPD,57,Y)  ;REFUSAL OF A MED
  1.  S Y="" F X=52:1:59,98,99 I $E($G(^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,X)))="X" S Y=1  ;cmi/maw 6/17/2010 per gary
  1.  D S(BDMPD,51,$S(Y:"",1:"X"))
  1.  D S(BDMPD,60,$$ACE^BDMD016(BDMPD,BDM6MBD,BDMADAT))
  1.  ;
  1. IMM ;
  1.  D S(BDMPD,62,$$ASPIRIN^BDMD016(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,300,$$STATIN^BDMD016(BDMPD,BDM6MBD,BDMADAT))
  1.  D S(BDMPD,301,$$FIBRATE^BDMD016(BDMPD,BDM6MBD,BDMADAT))
  1.  D S(BDMPD,302,$$NIACIN^BDMD016(BDMPD,BDM6MBD,BDMADAT))
  1.  D S(BDMPD,303,$$BILE^BDMD016(BDMPD,BDM6MBD,BDMADAT))
  1.  D S(BDMPD,304,$$EZET^BDMD016(BDMPD,BDM6MBD,BDMADAT))
  1.  D S(BDMPD,305,$$FISHOIL^BDMD016(BDMPD,BDM6MBD,BDMADAT))
  1.  D S(BDMPD,306,$$LOVAZA^BDMD016(BDMPD,BDM6MBD,BDMADAT))
  1.  S Z=0 F X=300:1:306 I $E($G(^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,X)))="X" S Z=1  ;has one so skip refusal and none
  1.  I Z G PPD
  1.  S Y=$$REFMEDL^BDMD016(BDMPD,BDMBDAT,BDMRED) S Y=$S(Y="":"X",1:"X"_U_$P(Y,U,2)) D S(BDMPD,307,Y)
  1. PPD ;
  1.  D S(BDMPD,70,$$PPD^BDMD018(BDMPD,BDMADAT))
  1.  D S(BDMPD,114,$$LASTNP^BDMD018(BDMPD,BDMADAT))
  1.  D S(BDMPD,72,$$TBTX^BDMD012(BDMPD))
  1.  D S(BDMPD,76,$$EKG^BDMD012(BDMPD,BDMADAT))
  1. FLU ;
  1.  D S(BDMPD,64,$$FLU^BDMD013(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,66,$$PNEU^BDMD013(BDMPD,BDMADAT))
  1.  D S(BDMPD,68,$$TD^BDMD01B(BDMPD,BDMADAT))
  1. LABS ;
  1.  D S(BDMPD,78,$$HGBA1C^BDMD018(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,79,$$GFR^BDMD01C(BDMPD,BDMBDAT,BDMADAT))  ;cmi/maw 12/17/2007 DM2010
  1.  D S(BDMPD,84,$$CREAT^BDMD018(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,86,$$CHOL^BDMD018(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,88,$$LDL^BDMD018(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,89,$$HDL^BDMD018(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,90,$$TRIG^BDMD018(BDMPD,BDMBDAT,BDMADAT))
  1.  D S(BDMPD,92,$$URIN^BDMD018(BDMPD,BDMBDAT,BDMADAT))  ;cmi/maw 12/17/2007 DM2010
  1.  ;
  1.  Q
  1. TYPEDM ;return type of DM in BDMTYDM
  1.  NEW X
  1.  I ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,24)="NIDDM" S BDMTYDM="2  Type 2" Q
  1.  I ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,24)="TYPE II" S BDMTYDM="2  Type 2" Q
  1.  I ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,24)[2 S BDMTYDM="2  Type 2" Q
  1.  I ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,24)="IDDM" S BDMTYDM="1  Type 1" Q
  1.  I ^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,24)[1 S BDMTYDM="1  Type 1" Q
  1.  S X=^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,25) ;get problem list dxs
  1.  F I=1:1 S C=$P(X,";",I) Q:C=""!(BDMTYDM]"")  I $E(C,6)=0!($E(C,6)=2) S BDMTYDM="2  Type 2"
  1.  Q:BDMTYDM]""
  1.  F I=1:1 S C=$P(X,";",I) Q:C=""!(BDMTYDM]"")  I $E(C,6)=1!($E(C,6)=3) S BDMTYDM="1  Type 1"
  1.  Q:BDMTYDM]""
  1.  S X=^XTMP("BDMDM01",BDMJOB,BDMBTH,"AUDIT",BDMPD,26) ;get pov list dxs
  1.  I X[2 S BDMTYDM="2  Type 2" Q
  1.  I X[1 S BDMTYDM="1  Type 1" Q
  1.  Q
  1. DATE(D) ;EP
  1.  I $G(D)="" Q ""
  1.  Q $E(D,4,5)_"/"_$E(D,6,7)_"/"_(1700+($E(D,1,3)))
  1. TRIBE(P) ;EP
  1.  I '$G(P) Q ""
  1.  I '$D(^AUPNPAT(P,11)) Q ""
  1.  Q $$TRIBE^AUPNPAT(P,"C")_"^"_$$TRIBE^AUPNPAT(P,"E")
  1. COMM(P) ;EP
  1.  I '$G(P) Q ""
  1.  I '$D(^AUPNPAT(P,11)) Q ""
  1.  Q $$COMMRES^AUPNPAT(P,"E")
  1. EAUDIT ;EP
  1.  K ^BDMDATA("BDMEPI",$J)
  1.  S ^XTMP("BDMDM01",0)=$$FMADD^XLFDT(DT,14)_"^"_DT_"^DM AUDIT 2010"
  1.  S BDMEPIN=0
  1.  S BDMBEGD=$$FMADD^XLFDT(BDMADAT,-365)
  1.  S BDM3YE=$$FMADD^XLFDT(BDMADAT,-1096)
  1.  I BDMACTI=1 D
  1.  .S BDMEAUT=0 F  S BDMEAUT=$O(^ACM(41,"B",BDMDMRG,BDMEAUT)) Q:BDMEAUT'=+BDMEAUT  D
  1.  ..I $P($G(^ACM(41,BDMEAUT,"DT")),U,1)'="A" Q
  1.  ..S BDMPD=$P(^ACM(41,BDMEAUT,0),U,2)
  1.  ..Q:$$DEMO^BDMUTL(BDMPD,$G(BDMDEMO))
  1.  ..S BDMX=$$ACTDMPT^BDMD01G(BDMPD,BDMBEGD,BDMADAT,BDMTAXI,BDMBEN,BDM3YE)
  1.  ..I 'BDMX Q  ;not active diabetic
  1.  ..I BDMPREP=2 D EPIREC Q
  1.  ..D GATHER
  1.  .Q
  1.  I BDMACTI=0 S BDMPD=0 F  S BDMPD=$O(^AUPNPAT(BDMPD)) Q:'BDMPD  D
  1.  .S BDMX=$$ACTDMPT^BDMD01G(BDMPD,BDMBEGD,BDMADAT,BDMTAXI,BDMBEN,BDM3YE)
  1.  .I 'BDMX Q  ;not active diabetic
  1.  .I BDMACTI,'$$ACTONREG(BDMPD,BDMDMRG) Q
  1.  .I BDMPREP=2 D EPIREC Q
  1.  .D GATHER
  1.  I BDMPREP=2 D WRITEF^BDMD01 Q
  1.  I BDMPREP=3!(BDMPREP=4) D CUML^BDMD015
  1.  Q
  1. ACTONREG(P,R) ;
  1.  I '$D(^ACM(41,"AC",P,R)) Q 0
  1.  S X=^ACM(41,"AC",P,R)
  1.  I $P($G(^ACM(41,X,"DT")),U,1)'="A" Q 0
  1.  Q 1
  1.  ;